New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in tags/nemo_v3_2_beta/NEMO/TOP_SRC/PISCES – NEMO

source: tags/nemo_v3_2_beta/NEMO/TOP_SRC/PISCES/p4zlys.F90 @ 7039

Last change on this file since 7039 was 1457, checked in by cetlod, 15 years ago

distribution of iom_put in TOP routines, see ticket:437
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 8.3 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!----------------------------------------------------------------------
12#if defined key_pisces
13   !!----------------------------------------------------------------------
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_lys        :   Compute the CaCO3 dissolution
17   !!   p4z_lys_init   :   Read the namelist parameters
18   !!----------------------------------------------------------------------
19   USE trc
20   USE oce_trc         !
21   USE trc
22   USE sms_pisces
23   USE prtctl_trc
24   USE iom
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_lys    ! called in p4zprg.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::   &
33     kdca = 0.327e3_wp   ,  &  !:
34     nca  = 1.0_wp             !:
35
36   !! * Module variables
37   REAL(wp) :: &
38      calcon = 1.03E-2        ! mean calcite concentration [Ca2+] in sea water [mole/kg solution]
39
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
42   !! $Id$
43   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45
46CONTAINS
47
48   SUBROUTINE p4z_lys( kt )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p4z_lys  ***
51      !!
52      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
53      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
54      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
55      !!
56      !! ** Method  : - ???
57      !!---------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt ! ocean time step
59      INTEGER  ::   ji, jj, jk, jn
60      REAL(wp) ::   zbot, zalk, zdic, zph, zremco3, zah2
61      REAL(wp) ::   zdispot, zfact, zalka
62      REAL(wp) ::   zomegaca, zexcess, zexcess0
63      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zco3
64#if defined key_trc_dia3d && defined key_iomput
65      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zw3d
66#endif
67      CHARACTER (len=25) :: charout
68      !!---------------------------------------------------------------------
69
70      IF( kt == nittrc000  )   CALL p4z_lys_init      ! Initialization (first time-step only)
71
72      zco3(:,:,:) = 0.
73
74      !     -------------------------------------------
75      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
76      !     -------------------------------------------
77     
78      DO jn = 1, 5                               !  BEGIN OF ITERATION
79         !
80!CDIR NOVERRCHK
81         DO jk = 1, jpkm1
82!CDIR NOVERRCHK
83            DO jj = 1, jpj
84!CDIR NOVERRCHK
85               DO ji = 1, jpi
86
87                  ! SET DUMMY VARIABLE FOR TOTAL BORATE
88                  zbot  = borat(ji,jj,jk)
89                  zfact = rhop (ji,jj,jk) / 1000. + rtrn
90
91                  ! SET DUMMY VARIABLE FOR [H+]
92                  zph   = hi(ji,jj,jk) * tmask(ji,jj,jk) / zfact + ( 1.-tmask(ji,jj,jk) ) * 1.e-9
93
94                  ! SET DUMMY VARIABLE FOR [SUM(CO2)]GIVEN
95                  zdic  = trn(ji,jj,jk,jpdic) / zfact
96                  zalka = trn(ji,jj,jk,jptal) / zfact
97
98                  ! CALCULATE [ALK]([CO3--], [HCO3-])
99                  zalk  = zalka - (  akw3(ji,jj,jk) / zph - zph   &
100                     &             + zbot / (1.+ zph / akb3(ji,jj,jk) )  )
101
102                  ! CALCULATE [H+] and [CO3--]
103                  zah2 = SQRT( (zdic-zalk)*(zdic-zalk)+   &
104                     &     4.*(zalk*ak23(ji,jj,jk)/ak13(ji,jj,jk))   &
105                     &     *(2*zdic-zalk))
106
107                  zah2=0.5*ak13(ji,jj,jk)/zalk*((zdic-zalk)+zah2)
108                  zco3(ji,jj,jk) = zalk/(2.+zah2/ak23(ji,jj,jk))*zfact
109
110                  hi(ji,jj,jk)  = zah2*zfact
111
112               END DO
113            END DO
114         END DO
115         !
116      END DO 
117
118      !     ---------------------------------------------------------
119      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
120      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
121      !        MGCO3)
122      !     ---------------------------------------------------------
123
124      DO jk = 1, jpkm1
125         DO jj = 1, jpj
126            DO ji = 1, jpi
127
128               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
129               zomegaca = ( calcon * zco3(ji,jj,jk) ) / aksp(ji,jj,jk)
130
131               ! SET DEGREE OF UNDER-/SUPERSATURATION
132               zexcess0 = MAX( 0., ( 1.- zomegaca ) )
133               zexcess  = zexcess0**nca
134
135               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
136               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
137               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
138# if defined key_off_degrad
139              zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal) * facvol(ji,jj,jk)
140# else
141              zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal)
142# endif
143
144              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
145              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
146              zremco3 = zdispot / rmoss
147              zco3(ji,jj,jk) = zco3(ji,jj,jk) + zremco3 * rfact
148              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2.*zremco3
149              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -    zremco3
150              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +    zremco3
151
152            END DO
153         END DO
154      END DO
155
156# if defined key_trc_diaadd &&  defined key_trc_dia3d
157#  if ! defined key_iomput
158      trc3d(:,:,:,jp_pcs0_3d    ) = hi  (:,:,:)          * tmask(:,:,:)
159      trc3d(:,:,:,jp_pcs0_3d + 1) = zco3(:,:,:)          * tmask(:,:,:)
160      trc3d(:,:,:,jp_pcs0_3d + 2) = aksp(:,:,:) / calcon * tmask(:,:,:)
161#  else
162      zw3d(:,:,:) = hi  (:,:,:)          * tmask(:,:,:)
163      CALL iom_put( "PH", zw3d )
164      zw3d(:,:,:) = zco3(:,:,:)          * tmask(:,:,:)
165      CALL iom_put( "CO3", zw3d )
166      zw3d(:,:,:) = aksp(:,:,:) / calcon * tmask(:,:,:)
167      CALL iom_put( "CO3sat", zw3d )
168#  endif
169# endif
170      !
171       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
172         WRITE(charout, FMT="('lys ')")
173         CALL prt_ctl_trc_info(charout)
174         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
175       ENDIF
176
177   END SUBROUTINE p4z_lys
178
179   SUBROUTINE p4z_lys_init
180
181      !!----------------------------------------------------------------------
182      !!                  ***  ROUTINE p4z_lys_init  ***
183      !!
184      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
185      !!
186      !! ** Method  :   Read the nampiscal namelist and check the parameters
187      !!      called at the first timestep (nittrc000)
188      !!
189      !! ** input   :   Namelist nampiscal
190      !!
191      !!----------------------------------------------------------------------
192
193      NAMELIST/nampiscal/ kdca, nca
194
195      REWIND( numnat )                     ! read numnat
196      READ  ( numnat, nampiscal )
197
198      IF(lwp) THEN                         ! control print
199         WRITE(numout,*) ' '
200         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
201         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
202         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
203         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
204      ENDIF
205
206   END SUBROUTINE p4z_lys_init
207
208#else
209   !!======================================================================
210   !!  Dummy module :                                   No PISCES bio-model
211   !!======================================================================
212CONTAINS
213   SUBROUTINE p4z_lys( kt )                   ! Empty routine
214      INTEGER, INTENT( in ) ::   kt
215      WRITE(*,*) 'p4z_lys: You should not have seen this print! error?', kt
216   END SUBROUTINE p4z_lys
217#endif 
218
219   !!======================================================================
220END MODULE  p4zlys
Note: See TracBrowser for help on using the repository browser.