| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | #if defined key_lim3 |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! lim_sbc : flux at the ice / ocean interface |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | USE oce |
|---|
| 17 | USE par_oce ! ocean parameters |
|---|
| 18 | USE par_ice ! ice parameters |
|---|
| 19 | USE dom_oce ! ocean domain |
|---|
| 20 | USE sbc_ice ! Surface boundary condition: sea-ice fields |
|---|
| 21 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 22 | USE phycst ! physical constants |
|---|
| 23 | USE ice ! LIM sea-ice variables |
|---|
| 24 | |
|---|
| 25 | USE lbclnk ! ocean lateral boundary condition |
|---|
| 26 | USE in_out_manager ! I/O manager |
|---|
| 27 | USE albedo ! albedo parameters |
|---|
| 28 | USE prtctl ! Print control |
|---|
| 29 | |
|---|
| 30 | IMPLICIT NONE |
|---|
| 31 | PRIVATE |
|---|
| 32 | |
|---|
| 33 | PUBLIC lim_sbc_flx ! called by sbc_ice_lim |
|---|
| 34 | PUBLIC lim_sbc_tau ! called by sbc_ice_lim |
|---|
| 35 | |
|---|
| 36 | REAL(wp) :: epsi16 = 1.e-16 ! constant values |
|---|
| 37 | REAL(wp) :: rzero = 0.e0 |
|---|
| 38 | REAL(wp) :: rone = 1.e0 |
|---|
| 39 | |
|---|
| 40 | REAL(wp), DIMENSION(jpi,jpj) :: utau_oce, vtau_oce !: air-ocean surface i- & j-stress [N/m2] |
|---|
| 41 | REAL(wp), DIMENSION(jpi,jpj) :: tmod_io !: modulus of the ice-ocean relative velocity [m/s] |
|---|
| 42 | REAL(wp), DIMENSION(jpi,jpj) :: ssu_mb , ssv_mb !: before mean ocean surface currents [m/s] |
|---|
| 43 | |
|---|
| 44 | !! * Substitutions |
|---|
| 45 | # include "vectopt_loop_substitute.h90" |
|---|
| 46 | !!---------------------------------------------------------------------- |
|---|
| 47 | !! NEMO/LIM 3.2 , UCL-LOCEAN-IPSL (2009) |
|---|
| 48 | !! $Id$ |
|---|
| 49 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 50 | !!---------------------------------------------------------------------- |
|---|
| 51 | |
|---|
| 52 | CONTAINS |
|---|
| 53 | |
|---|
| 54 | SUBROUTINE lim_sbc_tau( kt, kcpl ) |
|---|
| 55 | !!------------------------------------------------------------------- |
|---|
| 56 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 57 | !! |
|---|
| 58 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 59 | !! |
|---|
| 60 | !! ** Action : - compute the ice-ocean stress depending on kcpl: |
|---|
| 61 | !! fluxes at the ice-ocean interface. |
|---|
| 62 | !! Case 0 : old LIM-3 way, computed at ice time-step only |
|---|
| 63 | !! Case 1 : at each ocean time step the stresses are computed |
|---|
| 64 | !! using the current ocean velocity (now) |
|---|
| 65 | !! Case 2 : combination of half case 0 + half case 1 |
|---|
| 66 | !! |
|---|
| 67 | !! ** Outputs : - utau : sea surface i-stress (ocean referential) |
|---|
| 68 | !! - vtau : sea surface j-stress (ocean referential) |
|---|
| 69 | !! |
|---|
| 70 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 71 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 72 | !!--------------------------------------------------------------------- |
|---|
| 73 | INTEGER :: kt ! number of ocean iteration |
|---|
| 74 | INTEGER :: kcpl ! ice-ocean coupling indicator: =0 LIM-3 old case |
|---|
| 75 | ! ! =1 stresses computed using now ocean velocity |
|---|
| 76 | ! ! =2 combination of 0 and 1 cases |
|---|
| 77 | !! |
|---|
| 78 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 79 | REAL(wp) :: zfrldu, zat_u, zu_ico, zutaui, zu_u, zu_ij, zu_im1j ! temporary scalar |
|---|
| 80 | REAL(wp) :: zfrldv, zat_v, zv_ico, zvtaui, zv_v, zv_ij, zv_ijm1 ! - - |
|---|
| 81 | REAL(wp) :: zsang, zztmp ! - - |
|---|
| 82 | REAL(wp), DIMENSION(jpi,jpj) :: ztio_u, ztio_v ! ocean stress below sea-ice |
|---|
| 83 | #if defined key_coupled |
|---|
| 84 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zalb ! albedo of ice under overcast sky |
|---|
| 85 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zalbp ! albedo of ice under clear sky |
|---|
| 86 | #endif |
|---|
| 87 | !!--------------------------------------------------------------------- |
|---|
| 88 | |
|---|
| 89 | IF( kt == nit000 ) THEN |
|---|
| 90 | IF(lwp) WRITE(numout,*) |
|---|
| 91 | IF(lwp) WRITE(numout,*) 'lim_sbc_tau : LIM 3.0 sea-ice - surface ocean momentum fluxes' |
|---|
| 92 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ ' |
|---|
| 93 | ENDIF |
|---|
| 94 | |
|---|
| 95 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 96 | !CDIR NOVERRCHK |
|---|
| 97 | DO jj = 2, jpjm1 !* modulus of the ice-ocean velocity |
|---|
| 98 | !CDIR NOVERRCHK |
|---|
| 99 | DO ji = fs_2, fs_jpim1 |
|---|
| 100 | zu_ij = u_ice(ji ,jj) - ssu_m(ji ,jj) ! (i ,j) |
|---|
| 101 | zu_im1j = u_ice(ji-1,jj) - ssu_m(ji-1,jj) ! (i-1,j) |
|---|
| 102 | zv_ij = v_ice(ji,jj ) - ssv_m(ji,jj ) ! (i,j ) |
|---|
| 103 | zv_ijm1 = v_ice(ji,jj-1) - ssv_m(ji,jj-1) ! (i,j-1) |
|---|
| 104 | zztmp = 0.5 * ( zu_ij * zu_ij + zu_im1j * zu_im1j & ! mean of the square values instead |
|---|
| 105 | & + zv_ij * zv_ij + zv_ijm1 * zv_ijm1 ) ! of the square of the mean values... |
|---|
| 106 | ! WARNING, here we make an approximation for case 1 and 2: taum is not computed at each time |
|---|
| 107 | ! step but only every nn_fsbc time step. This avoid mutiple avarage to pass from T -> U,V grids |
|---|
| 108 | ! and next from U,V grids to T grid. Taum is used in tke, which should not be too sensitive to |
|---|
| 109 | ! this approximaton... |
|---|
| 110 | taum(ji,jj) = ( 1. - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zztmp |
|---|
| 111 | tmod_io(ji,jj) = SQRT( zztmp ) |
|---|
| 112 | END DO |
|---|
| 113 | END DO |
|---|
| 114 | CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. ) |
|---|
| 115 | ENDIF |
|---|
| 116 | |
|---|
| 117 | SELECT CASE( kcpl ) |
|---|
| 118 | ! !--------------------------------! |
|---|
| 119 | CASE( 0 ) ! LIM 3 old stress computation ! (at ice timestep only) |
|---|
| 120 | ! !--------------------------------! |
|---|
| 121 | ! !* ice stress over ocean with a ice-ocean rotation angle |
|---|
| 122 | DO jj = 1, jpjm1 |
|---|
| 123 | zsang = SIGN( 1.e0, gphif(1,jj) ) * sangvg ! change the sinus angle sign in the south hemisphere |
|---|
| 124 | DO ji = 1, fs_jpim1 |
|---|
| 125 | zu_u = u_ice(ji,jj) - u_oce(ji,jj) ! ice velocity relative to the ocean |
|---|
| 126 | zv_v = v_ice(ji,jj) - v_oce(ji,jj) |
|---|
| 127 | ! ! quadratic drag formulation with rotation |
|---|
| 128 | !!gm still an error in the rotation, but usually the angle is zero (zsang=0, cangvg=1) |
|---|
| 129 | zutaui = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * rhoco * ( cangvg * zu_u - zsang * zv_v ) |
|---|
| 130 | zvtaui = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * rhoco * ( cangvg * zv_v + zsang * zu_u ) |
|---|
| 131 | ! ! bound for too large stress values |
|---|
| 132 | ! IMPORTANT: the exponential below prevents numerical oscillations in the ice-ocean stress |
|---|
| 133 | ! This is not physically based. A cleaner solution is offer in CASE kcpl=2 |
|---|
| 134 | ztio_u(ji,jj) = zutaui * EXP( - ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) ) |
|---|
| 135 | ztio_v(ji,jj) = zvtaui * EXP( - ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) ) |
|---|
| 136 | END DO |
|---|
| 137 | END DO |
|---|
| 138 | DO jj = 2, jpjm1 ! stress at the surface of the ocean |
|---|
| 139 | DO ji = fs_2, fs_jpim1 ! vertor opt. |
|---|
| 140 | zfrldu = 0.5 * ( ato_i(ji,jj) + ato_i(ji+1,jj ) ) ! open-ocean fraction at U- & V-points (from T-point values) |
|---|
| 141 | zfrldv = 0.5 * ( ato_i(ji,jj) + ato_i(ji ,jj+1) ) |
|---|
| 142 | ! ! update surface ocean stress |
|---|
| 143 | utau(ji,jj) = zfrldu * utau(ji,jj) + ( 1. - zfrldu ) * ztio_u(ji,jj) |
|---|
| 144 | vtau(ji,jj) = zfrldv * vtau(ji,jj) + ( 1. - zfrldv ) * ztio_v(ji,jj) |
|---|
| 145 | END DO |
|---|
| 146 | END DO |
|---|
| 147 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 148 | |
|---|
| 149 | ! |
|---|
| 150 | ! !--------------------------------! |
|---|
| 151 | CASE( 1 ) ! Use the now velocity ! (at each ocean timestep) |
|---|
| 152 | ! !--------------------------------! |
|---|
| 153 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 154 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 155 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 156 | ENDIF |
|---|
| 157 | ! |
|---|
| 158 | DO jj = 2, jpjm1 !* ice stress over ocean with a ice-ocean rotation angle |
|---|
| 159 | zsang = SIGN(1.e0, gphif(1,jj-1) ) * sangvg ! change the sinus angle sign in the south hemisphere |
|---|
| 160 | DO ji = fs_2, fs_jpim1 |
|---|
| 161 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5 ! ice area at u and V-points |
|---|
| 162 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5 |
|---|
| 163 | ! ! (u,v) ice-ocean velocity at (U,V)-point, resp. |
|---|
| 164 | zu_u = u_ice(ji,jj) - ub(ji,jj,1) |
|---|
| 165 | zv_v = v_ice(ji,jj) - vb(ji,jj,1) |
|---|
| 166 | ! ! quadratic drag formulation with rotation |
|---|
| 167 | !!gm still an error in the rotation, but usually the angle is zero (zsang=0, cangvg=1) |
|---|
| 168 | zutaui = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * rhoco * ( cangvg * zu_u - zsang * zv_v ) |
|---|
| 169 | zvtaui = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * rhoco * ( cangvg * zv_v + zsang * zu_u ) |
|---|
| 170 | ! ! stress at the ocean surface |
|---|
| 171 | utau(ji,jj) = ( 1.- zat_u ) * utau_oce(ji,jj) + zat_u * zutaui |
|---|
| 172 | vtau(ji,jj) = ( 1.- zat_v ) * vtau_oce(ji,jj) + zat_v * zvtaui |
|---|
| 173 | END DO |
|---|
| 174 | END DO |
|---|
| 175 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 176 | |
|---|
| 177 | ! |
|---|
| 178 | ! !--------------------------------! |
|---|
| 179 | CASE( 2 ) ! mixed 0 and 2 cases ! (at each ocean timestep) |
|---|
| 180 | ! !--------------------------------! |
|---|
| 181 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 182 | utau_oce(:,:) = utau (:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 183 | vtau_oce(:,:) = vtau (:,:) |
|---|
| 184 | ssu_mb (:,:) = ssu_m(:,:) !* save the ice-ocean velocity at ice time-step |
|---|
| 185 | ssv_mb (:,:) = ssv_m(:,:) |
|---|
| 186 | ENDIF |
|---|
| 187 | DO jj = 2, jpjm1 !* ice stress over ocean with a ice-ocean rotation angle |
|---|
| 188 | zsang = SIGN(1.e0, gphif(1,jj-1) ) * sangvg |
|---|
| 189 | DO ji = fs_2, fs_jpim1 |
|---|
| 190 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5 ! ice area at u and V-points |
|---|
| 191 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5 |
|---|
| 192 | ! |
|---|
| 193 | zu_ico = u_ice(ji,jj) - 0.5 * ( ub(ji,jj,1) + ssu_mb(ji,jj) ) ! ice-oce velocity using ub and ssu_mb |
|---|
| 194 | zv_ico = v_ice(ji,jj) - 0.5 * ( vb(ji,jj,1) + ssv_mb(ji,jj) ) |
|---|
| 195 | ! ! quadratic drag formulation with rotation |
|---|
| 196 | !!gm still an error in the rotation, but usually the angle is zero (zsang=0, cangvg=1) |
|---|
| 197 | zutaui = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * rhoco * ( cangvg * zu_ico - zsang * zv_ico ) |
|---|
| 198 | zvtaui = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * rhoco * ( cangvg * zv_ico + zsang * zu_ico ) |
|---|
| 199 | ! |
|---|
| 200 | utau(ji,jj) = ( 1.-zat_u ) * utau_oce(ji,jj) + zat_u * zutaui ! stress at the ocean surface |
|---|
| 201 | vtau(ji,jj) = ( 1.-zat_v ) * vtau_oce(ji,jj) + zat_v * zvtaui |
|---|
| 202 | END DO |
|---|
| 203 | END DO |
|---|
| 204 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 205 | ! |
|---|
| 206 | END SELECT |
|---|
| 207 | |
|---|
| 208 | IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 209 | & tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 210 | ! |
|---|
| 211 | END SUBROUTINE lim_sbc_tau |
|---|
| 212 | |
|---|
| 213 | |
|---|
| 214 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 215 | !!------------------------------------------------------------------- |
|---|
| 216 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 217 | !! |
|---|
| 218 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 219 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 220 | !! |
|---|
| 221 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 222 | !! at the ice-ocean interface. |
|---|
| 223 | !! - Update the ocean sbc |
|---|
| 224 | !! |
|---|
| 225 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 226 | !! - qns : sea heat flux: non solar |
|---|
| 227 | !! - emp : freshwater budget: volume flux |
|---|
| 228 | !! - emps : freshwater budget: concentration/dillution |
|---|
| 229 | !! - fr_i : ice fraction |
|---|
| 230 | !! - tn_ice : sea-ice surface temperature |
|---|
| 231 | !! - alb_ice : sea-ice alberdo (lk_cpl=T) |
|---|
| 232 | !! |
|---|
| 233 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 234 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 235 | !!--------------------------------------------------------------------- |
|---|
| 236 | INTEGER :: kt ! number of iteration |
|---|
| 237 | !! |
|---|
| 238 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 239 | INTEGER :: ifvt, i1mfr, idfr ! some switches |
|---|
| 240 | INTEGER :: iflt, ial, iadv, ifral, ifrdv |
|---|
| 241 | REAL(wp) :: zinda ! switch for testing the values of ice concentration |
|---|
| 242 | REAL(wp) :: zfons ! salt exchanges at the ice/ocean interface |
|---|
| 243 | REAL(wp) :: zpme ! freshwater exchanges at the ice/ocean interface |
|---|
| 244 | REAL(wp), DIMENSION(jpi,jpj) :: zfcm1 , zfcm2 ! solar/non solar heat fluxes |
|---|
| 245 | #if defined key_coupled |
|---|
| 246 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zalb ! albedo of ice under overcast sky |
|---|
| 247 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zalbp ! albedo of ice under clear sky |
|---|
| 248 | #endif |
|---|
| 249 | !!--------------------------------------------------------------------- |
|---|
| 250 | |
|---|
| 251 | IF( kt == nit000 ) THEN |
|---|
| 252 | IF(lwp) WRITE(numout,*) |
|---|
| 253 | IF(lwp) WRITE(numout,*) 'lim_sbc_flx : LIM 3.0 sea-ice - heat salt and mass ocean surface fluxes' |
|---|
| 254 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ ' |
|---|
| 255 | ENDIF |
|---|
| 256 | |
|---|
| 257 | !------------------------------------------! |
|---|
| 258 | ! heat flux at the ocean surface ! |
|---|
| 259 | !------------------------------------------! |
|---|
| 260 | ! pfrld is the lead fraction at the previous time step (actually between TRP and THD) |
|---|
| 261 | ! changed to old_frld and old ht_i |
|---|
| 262 | |
|---|
| 263 | DO jj = 1, jpj |
|---|
| 264 | DO ji = 1, jpi |
|---|
| 265 | zinda = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) ) |
|---|
| 266 | ifvt = zinda * MAX( rzero , SIGN( rone, -phicif (ji,jj) ) ) !subscripts are bad here |
|---|
| 267 | i1mfr = 1.0 - MAX( rzero , SIGN( rone , - ( at_i(ji,jj) ) ) ) |
|---|
| 268 | idfr = 1.0 - MAX( rzero , SIGN( rone , ( 1.0 - at_i(ji,jj) ) - pfrld(ji,jj) ) ) |
|---|
| 269 | iflt = zinda * (1 - i1mfr) * (1 - ifvt ) |
|---|
| 270 | ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 271 | iadv = ( 1 - i1mfr ) * zinda |
|---|
| 272 | ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 273 | ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 274 | |
|---|
| 275 | ! switch --- 1.0 ---------------- 0.0 -------------------- |
|---|
| 276 | ! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ |
|---|
| 277 | ! zinda | if pfrld = 1 | if pfrld < 1 | |
|---|
| 278 | ! -> ifvt| if pfrld old_ht_i |
|---|
| 279 | ! i1mfr | if frld = 1 | if frld < 1 | |
|---|
| 280 | ! idfr | if frld <= pfrld | if frld > pfrld | |
|---|
| 281 | ! iflt | |
|---|
| 282 | ! ial | |
|---|
| 283 | ! iadv | |
|---|
| 284 | ! ifral |
|---|
| 285 | ! ifrdv |
|---|
| 286 | |
|---|
| 287 | ! computation the solar flux at ocean surface |
|---|
| 288 | zfcm1(ji,jj) = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 289 | ! fstric Solar flux transmitted trough the ice |
|---|
| 290 | ! qsr Net short wave heat flux on free ocean |
|---|
| 291 | ! new line |
|---|
| 292 | fscmbq(ji,jj) = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 293 | |
|---|
| 294 | ! computation the non solar heat flux at ocean surface |
|---|
| 295 | zfcm2(ji,jj) = - zfcm1(ji,jj) & |
|---|
| 296 | & + iflt * ( fscmbq(ji,jj) ) & ! total abl -> fscmbq is given to the ocean |
|---|
| 297 | ! fscmbq and ffltbif are obsolete |
|---|
| 298 | ! & + iflt * ffltbif(ji,jj) !!! only if one category is used |
|---|
| 299 | & + ifral * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) / rdt_ice & |
|---|
| 300 | & + ifrdv * ( qfvbq(ji,jj) + qdtcn(ji,jj) ) / rdt_ice & |
|---|
| 301 | & + fhmec(ji,jj) & ! new contribution due to snow melt in ridging!! |
|---|
| 302 | & + fheat_rpo(ji,jj) & ! contribution from ridge formation |
|---|
| 303 | & + fheat_res(ji,jj) |
|---|
| 304 | ! fscmbq Part of the solar radiation transmitted through the ice and going to the ocean |
|---|
| 305 | ! computed in limthd_zdf.F90 |
|---|
| 306 | ! ffltbif Total heat content of the ice (brine pockets+ice) / delta_t |
|---|
| 307 | ! qcmif Energy needed to bring the ocean surface layer until its freezing (ok) |
|---|
| 308 | ! qldif heat balance of the lead (or of the open ocean) |
|---|
| 309 | ! qfvbq i think this is wrong! |
|---|
| 310 | ! ---> Array used to store energy in case of total lateral ablation |
|---|
| 311 | ! qfvbq latent heat uptake/release after accretion/ablation |
|---|
| 312 | ! qdtcn Energy from the turbulent oceanic heat flux heat flux coming in the lead |
|---|
| 313 | |
|---|
| 314 | IF ( num_sal .EQ. 2 ) zfcm2(ji,jj) = zfcm2(ji,jj) + & |
|---|
| 315 | fhbri(ji,jj) ! new contribution due to brine drainage |
|---|
| 316 | |
|---|
| 317 | ! bottom radiative component is sent to the computation of the |
|---|
| 318 | ! oceanic heat flux |
|---|
| 319 | fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj) |
|---|
| 320 | |
|---|
| 321 | ! used to compute the oceanic heat flux at the next time step |
|---|
| 322 | qsr(ji,jj) = zfcm1(ji,jj) ! solar heat flux |
|---|
| 323 | qns(ji,jj) = zfcm2(ji,jj) - fdtcn(ji,jj) ! non solar heat flux |
|---|
| 324 | ! ! fdtcn : turbulent oceanic heat flux |
|---|
| 325 | |
|---|
| 326 | !!gm this IF prevents the vertorisation of the whole loop |
|---|
| 327 | IF ( ( ji .EQ. jiindx ) .AND. ( jj .EQ. jjindx) ) THEN |
|---|
| 328 | WRITE(numout,*) ' lim_sbc : heat fluxes ' |
|---|
| 329 | WRITE(numout,*) ' qsr : ', qsr(jiindx,jjindx) |
|---|
| 330 | WRITE(numout,*) ' zfcm1 : ', zfcm1(jiindx,jjindx) |
|---|
| 331 | WRITE(numout,*) ' pfrld : ', pfrld(jiindx,jjindx) |
|---|
| 332 | WRITE(numout,*) ' fstric : ', fstric (jiindx,jjindx) |
|---|
| 333 | WRITE(numout,*) |
|---|
| 334 | WRITE(numout,*) ' qns : ', qns(jiindx,jjindx) |
|---|
| 335 | WRITE(numout,*) ' zfcm2 : ', zfcm2(jiindx,jjindx) |
|---|
| 336 | WRITE(numout,*) ' zfcm1 : ', zfcm1(jiindx,jjindx) |
|---|
| 337 | WRITE(numout,*) ' ifral : ', ifral |
|---|
| 338 | WRITE(numout,*) ' ial : ', ial |
|---|
| 339 | WRITE(numout,*) ' qcmif : ', qcmif(jiindx,jjindx) |
|---|
| 340 | WRITE(numout,*) ' qldif : ', qldif(jiindx,jjindx) |
|---|
| 341 | WRITE(numout,*) ' qcmif / dt: ', qcmif(jiindx,jjindx) / rdt_ice |
|---|
| 342 | WRITE(numout,*) ' qldif / dt: ', qldif(jiindx,jjindx) / rdt_ice |
|---|
| 343 | WRITE(numout,*) ' ifrdv : ', ifrdv |
|---|
| 344 | WRITE(numout,*) ' qfvbq : ', qfvbq(jiindx,jjindx) |
|---|
| 345 | WRITE(numout,*) ' qdtcn : ', qdtcn(jiindx,jjindx) |
|---|
| 346 | WRITE(numout,*) ' qfvbq / dt: ', qfvbq(jiindx,jjindx) / rdt_ice |
|---|
| 347 | WRITE(numout,*) ' qdtcn / dt: ', qdtcn(jiindx,jjindx) / rdt_ice |
|---|
| 348 | WRITE(numout,*) ' ' |
|---|
| 349 | WRITE(numout,*) ' fdtcn : ', fdtcn(jiindx,jjindx) |
|---|
| 350 | WRITE(numout,*) ' fhmec : ', fhmec(jiindx,jjindx) |
|---|
| 351 | WRITE(numout,*) ' fheat_rpo : ', fheat_rpo(jiindx,jjindx) |
|---|
| 352 | WRITE(numout,*) ' fhbri : ', fhbri(jiindx,jjindx) |
|---|
| 353 | WRITE(numout,*) ' fheat_res : ', fheat_res(jiindx,jjindx) |
|---|
| 354 | ENDIF |
|---|
| 355 | !!gm end |
|---|
| 356 | END DO |
|---|
| 357 | END DO |
|---|
| 358 | |
|---|
| 359 | !------------------------------------------! |
|---|
| 360 | ! mass flux at the ocean surface ! |
|---|
| 361 | !------------------------------------------! |
|---|
| 362 | |
|---|
| 363 | !!gm optimisation: this loop have to be merged with the previous one |
|---|
| 364 | DO jj = 1, jpj |
|---|
| 365 | DO ji = 1, jpi |
|---|
| 366 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 367 | ! ------------------------------------------------------------------------------------- |
|---|
| 368 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 369 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 370 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 371 | ! Associated to Ice formation AND Ice melting |
|---|
| 372 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 373 | ! |
|---|
| 374 | |
|---|
| 375 | ! computing freshwater exchanges at the ice/ocean interface |
|---|
| 376 | zpme = - emp(ji,jj) * ( 1.0 - at_i(ji,jj) ) & ! evaporation over oceanic fraction |
|---|
| 377 | & + tprecip(ji,jj) * at_i(ji,jj) & ! total precipitation |
|---|
| 378 | ! old fashioned way |
|---|
| 379 | ! & - sprecip(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! remov. snow precip over ice |
|---|
| 380 | & - sprecip(ji,jj) * ( 1. - (pfrld(ji,jj)**betas) ) & ! remov. snow precip over ice |
|---|
| 381 | & - rdmsnif(ji,jj) / rdt_ice & ! freshwaterflux due to snow melting |
|---|
| 382 | ! new contribution from snow falling when ridging |
|---|
| 383 | & + fmmec(ji,jj) |
|---|
| 384 | |
|---|
| 385 | ! computing salt exchanges at the ice/ocean interface |
|---|
| 386 | ! sice should be the same as computed with the ice model |
|---|
| 387 | zfons = ( soce - sice ) * ( rdmicif(ji,jj) / rdt_ice ) |
|---|
| 388 | ! SOCE |
|---|
| 389 | zfons = ( sss_m(ji,jj) - sice ) * ( rdmicif(ji,jj) / rdt_ice ) |
|---|
| 390 | |
|---|
| 391 | !CT useless ! salt flux for constant salinity |
|---|
| 392 | !CT useless fsalt(ji,jj) = zfons / ( sss_m(ji,jj) + epsi16 ) + fsalt_res(ji,jj) |
|---|
| 393 | ! salt flux for variable salinity |
|---|
| 394 | zinda = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) ) |
|---|
| 395 | ! correcting brine and salt fluxes |
|---|
| 396 | fsbri(ji,jj) = zinda*fsbri(ji,jj) |
|---|
| 397 | ! converting the salt fluxes from ice to a freshwater flux from ocean |
|---|
| 398 | fsalt_res(ji,jj) = fsalt_res(ji,jj) / ( sss_m(ji,jj) + epsi16 ) |
|---|
| 399 | fseqv(ji,jj) = fseqv(ji,jj) / ( sss_m(ji,jj) + epsi16 ) |
|---|
| 400 | fsbri(ji,jj) = fsbri(ji,jj) / ( sss_m(ji,jj) + epsi16 ) |
|---|
| 401 | fsalt_rpo(ji,jj) = fsalt_rpo(ji,jj) / ( sss_m(ji,jj) + epsi16 ) |
|---|
| 402 | |
|---|
| 403 | ! freshwater mass exchange (positive to the ice, negative for the ocean ?) |
|---|
| 404 | ! actually it's a salt flux (so it's minus freshwater flux) |
|---|
| 405 | ! if sea ice grows, zfons is positive, fsalt also |
|---|
| 406 | ! POSITIVE SALT FLUX FROM THE ICE TO THE OCEAN |
|---|
| 407 | ! POSITIVE FRESHWATER FLUX FROM THE OCEAN TO THE ICE [kg.m-2.s-1] |
|---|
| 408 | |
|---|
| 409 | emp(ji,jj) = - zpme |
|---|
| 410 | END DO |
|---|
| 411 | END DO |
|---|
| 412 | |
|---|
| 413 | IF( num_sal == 2 ) THEN ! variable ice salinity: brine drainage included in the salt flux |
|---|
| 414 | emps(:,:) = fsbri(:,:) + fseqv(:,:) + fsalt_res(:,:) + fsalt_rpo(:,:) + emp(:,:) |
|---|
| 415 | ELSE ! constant ice salinity: |
|---|
| 416 | emps(:,:) = fseqv(:,:) + fsalt_res(:,:) + fsalt_rpo(:,:) + emp(:,:) |
|---|
| 417 | ENDIF |
|---|
| 418 | |
|---|
| 419 | !-----------------------------------------------! |
|---|
| 420 | ! Storing the transmitted variables ! |
|---|
| 421 | !-----------------------------------------------! |
|---|
| 422 | |
|---|
| 423 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 424 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 425 | |
|---|
| 426 | #if defined key_coupled |
|---|
| 427 | !------------------------------------------------! |
|---|
| 428 | ! Computation of snow/ice and ocean albedo ! |
|---|
| 429 | !------------------------------------------------! |
|---|
| 430 | zalb (:,:,:) = 0.e0 |
|---|
| 431 | zalbp (:,:,:) = 0.e0 |
|---|
| 432 | |
|---|
| 433 | CALL albedo_ice( t_su, ht_i, ht_s, zalbp, zalb ) |
|---|
| 434 | |
|---|
| 435 | alb_ice(:,:,:) = 0.5 * zalbp(:,:,:) + 0.5 * zalb (:,:,:) ! Ice albedo (mean clear and overcast skys) |
|---|
| 436 | #endif |
|---|
| 437 | |
|---|
| 438 | IF(ln_ctl) THEN |
|---|
| 439 | CALL prt_ctl( tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ' ) |
|---|
| 440 | CALL prt_ctl( tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=emps, clinfo2=' emps : ' ) |
|---|
| 441 | CALL prt_ctl( tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ' ) |
|---|
| 442 | CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl ) |
|---|
| 443 | ENDIF |
|---|
| 444 | ! |
|---|
| 445 | END SUBROUTINE lim_sbc_flx |
|---|
| 446 | |
|---|
| 447 | #else |
|---|
| 448 | !!---------------------------------------------------------------------- |
|---|
| 449 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 450 | !!---------------------------------------------------------------------- |
|---|
| 451 | CONTAINS |
|---|
| 452 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 453 | END SUBROUTINE lim_sbc |
|---|
| 454 | #endif |
|---|
| 455 | |
|---|
| 456 | !!====================================================================== |
|---|
| 457 | END MODULE limsbc |
|---|
