New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in trunk/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 456

Last change on this file since 456 was 455, checked in by opalod, 18 years ago

nemo_v1_update_048:RB: reorganization of dynamics part, in addition change atsk to jki, suppress dynhpg_atsk.F90 dynzdf_imp_atsk.F90 dynzdf_iso.F90
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 54.5 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6
7   !!----------------------------------------------------------------------
8   !!   dyn_hpg      : update the momentum trend with the now horizontal
9   !!                  gradient of the hydrostatic pressure
10   !!                  default case : k-j-i loops (vector opt. available)
11   !!       hpg_ctl  : initialisation and control of options
12   !!       hpg_zco  : z-coordinate scheme
13   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
14   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
15   !!       hpg_hel  : s-coordinate (helsinki modification)
16   !!       hpg_wdj  : s-coordinate (weighted density jacobian)
17   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
18   !!       hpg_rot  : s-coordinate (ROTated axes scheme)
19   !!----------------------------------------------------------------------
20   !! * Modules used
21   USE oce             ! ocean dynamics and tracers
22   USE dom_oce         ! ocean space and time domain
23   USE dynhpg_jki      !
24   USE phycst          ! physical constants
25   USE in_out_manager  ! I/O manager
26   USE trdmod          ! ocean dynamics trends
27   USE trdmod_oce      ! ocean variables trends
28   USE prtctl          ! Print control
29   USE lbclnk          ! lateral boundary condition
30
31   IMPLICIT NONE
32   PRIVATE
33
34   !! * Accessibility
35   PUBLIC dyn_hpg                ! routine called by step.F90
36
37#if defined key_mpp_omp
38   !!----------------------------------------------------------------------
39   !!   'key_mpp_omp' :                                 j-k-i loop (j-slab)
40   !!----------------------------------------------------------------------
41   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg_jki = .TRUE.    !: OpenMP hpg flag
42   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg     = .FALSE.   !: vector hpg flag
43#else
44   !!----------------------------------------------------------------------
45   !!   default case :                             k-j-i loop (vector opt.)
46   !!----------------------------------------------------------------------   
47   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg_jki = .FALSE.   !: OpenMP hpg flag
48   LOGICAL, PUBLIC, PARAMETER ::   lk_dynhpg     = .TRUE.    !: vector hpg flag
49#endif
50
51   !! * Share module variables
52   LOGICAL  ::               & !!! ** nam_dynhpg **   hpg flags
53      ln_hpg_zco = .TRUE. ,  &  ! z-coordinate - full steps
54      ln_hpg_zps = .FALSE.,  &  ! z-coordinate - partial steps (interpolation)
55      ln_hpg_sco = .FALSE.,  &  ! s-coordinate (standard jacobian formulation)
56      ln_hpg_hel = .FALSE.,  &  ! s-coordinate (helsinki modification)
57      ln_hpg_wdj = .FALSE.,  &  ! s-coordinate (weighted density jacobian)
58      ln_hpg_djc = .FALSE.,  &  ! s-coordinate (Density Jacobian with Cubic polynomial)
59      ln_hpg_rot = .FALSE.      ! s-coordinate (ROTated axes scheme)
60
61   REAL(wp) ::               & !!! ** nam_dynhpg **
62      gamm = 0.e0               ! weighting coefficient
63
64   INTEGER  ::               &  !
65      nhpg  =  0                 ! = 0 to 6, type of pressure gradient scheme used
66      !                         ! (deduced from ln_hpg_... flags)
67
68   !! * Substitutions
69#  include "domzgr_substitute.h90"
70#  include "vectopt_loop_substitute.h90"
71   !!----------------------------------------------------------------------
72   !!   OPA 9.0 , LOCEAN-IPSL (2005)
73   !! $Header$
74   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
75   !!----------------------------------------------------------------------
76
77CONTAINS
78
79   SUBROUTINE dyn_hpg( kt )
80      !!---------------------------------------------------------------------
81      !!                  ***  ROUTINE dyn_hpg  ***
82      !!
83      !! ** Method  :   Call the hydrostatic pressure gradient routine
84      !!      using the scheme defined in the namelist (nhpg parameter)
85      !!   
86      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
87      !!             - Save the trend (l_trddyn=T)
88      !!             - Control print  (ln_ctl)
89      !!
90      !! History :
91      !!   9.0  !  05-10  (A. Beckmann, G. Madec) various s-coordinate options
92      !!----------------------------------------------------------------------
93      !! * Arguments
94      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
95
96      !! * local declarations
97      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
98         ztrdu, ztrdv                         ! 3D temporary workspace
99      !!----------------------------------------------------------------------
100   
101      IF( kt == nit000 )   CALL hpg_ctl      ! initialisation & control of options
102
103      ! Temporary saving of ua and va trends (l_trddyn)
104      IF( l_trddyn )   THEN
105         ztrdu(:,:,:) = ua(:,:,:) 
106         ztrdv(:,:,:) = va(:,:,:) 
107      ENDIF     
108
109      SELECT CASE ( nhpg )      ! Hydrastatic pressure gradient computation
110      CASE ( 0 )                  ! z-coordinate
111         CALL hpg_zco( kt )
112      CASE ( 1 )                  ! z-coordinate plus partial steps (interpolation)
113         CALL hpg_zps( kt )
114      CASE ( 2 )                  ! s-coordinate (standard jacobian formulation)
115         CALL hpg_sco( kt )
116      CASE ( 3 )                  ! s-coordinate (helsinki modification)
117         CALL hpg_hel( kt )
118      CASE ( 4 )                  ! s-coordinate (weighted density jacobian)
119         CALL hpg_wdj( kt )
120      CASE ( 5 )                  ! s-coordinate (Density Jacobian with Cubic polynomial)
121         CALL hpg_djc( kt )
122      CASE ( 6 )                  ! s-coordinate (ROTated axes scheme)
123         CALL hpg_rot( kt )
124      CASE ( 10 )                  ! z-coordinate
125         CALL hpg_zco_jki( kt )
126      CASE ( 11 )                  ! z-coordinate plus partial steps (interpolation)
127         CALL hpg_zps_jki( kt )
128      CASE ( 12 )                  ! s-coordinate (standard jacobian formulation)
129         CALL hpg_sco_jki( kt )
130      END SELECT
131
132      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
133      IF( l_trddyn )   THEN
134         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
135         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
136         CALL trd_mod( ztrdu, ztrdv, jpdtdhpg, 'DYN', kt )
137      ENDIF         
138     
139      IF(ln_ctl) THEN         ! print sum trends (used for debugging)
140         CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask, &
141            &          tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
142      ENDIF
143     
144   END SUBROUTINE dyn_hpg
145
146
147   SUBROUTINE hpg_ctl
148      !!----------------------------------------------------------------------
149      !!                 ***  ROUTINE hpg_ctl  ***
150      !!
151      !! ** Purpose :   initializations for the hydrostatic pressure gradient
152      !!              computation and consistency control
153      !!
154      !! ** Action  :   Read the namelist namdynhpg and check the consistency
155      !!      with the type of vertical coordinate used (zco, zps, sco)
156      !!
157      !! History :
158      !!   9.0  !  05-10  (A. Beckmann)  Original code
159      !!----------------------------------------------------------------------
160      INTEGER ::   ioptio = 0      ! temporary integer
161
162      NAMELIST/nam_dynhpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,               &
163         &                 ln_hpg_hel, ln_hpg_wdj, ln_hpg_djc, ln_hpg_rot,   &
164         &                 gamm
165      !!----------------------------------------------------------------------
166
167      ! Read Namelist nam_dynhpg : pressure gradient calculation options
168      REWIND ( numnam )
169      READ   ( numnam, nam_dynhpg )
170
171      ! Control print
172      IF(lwp) THEN
173         WRITE(numout,*)
174         WRITE(numout,*) 'dyn:hpg_ctl : hydrostatic pressure gradient control'
175         WRITE(numout,*) '~~~~~~~~~~~'
176         WRITE(numout,*) '       Namelist nam_dynhpg : choice of hpg scheme'
177         WRITE(numout,*) '          z-coord. - full steps                          ln_hpg_zco = ', ln_hpg_zco
178         WRITE(numout,*) '          z-coord. - partial steps (interpolation)       ln_hpg_zps = ', ln_hpg_zps
179         WRITE(numout,*) '          s-coord. (standard jacobian formulation)       ln_hpg_sco = ', ln_hpg_sco
180         WRITE(numout,*) '          s-coord. (helsinki modification)               ln_hpg_hel = ', ln_hpg_hel
181         WRITE(numout,*) '          s-coord. (weighted density jacobian)           ln_hpg_wdj = ', ln_hpg_wdj
182         WRITE(numout,*) '          s-coord. (Density Jacobian: Cubic polynomial)  ln_hpg_djc = ', ln_hpg_djc
183         WRITE(numout,*) '          s-coord. (ROTated axes scheme)                 ln_hpg_rot = ', ln_hpg_rot
184         WRITE(numout,*) '          weighting coeff. (wdj scheme)                     gamm       = ', gamm
185      ENDIF
186
187      ! set nhpg from ln_hpg_... flags
188      IF( ln_hpg_zco )   nhpg = 0
189      IF( ln_hpg_zps )   nhpg = 1
190      IF( ln_hpg_sco )   nhpg = 2
191      IF( ln_hpg_hel )   nhpg = 3
192      IF( ln_hpg_wdj )   nhpg = 4
193      IF( ln_hpg_djc )   nhpg = 5
194      IF( ln_hpg_rot )   nhpg = 6
195
196      ! Consitency check
197      ioptio = 0 
198      IF( ln_hpg_zco )   ioptio = ioptio + 1
199      IF( ln_hpg_zps )   ioptio = ioptio + 1
200      IF( ln_hpg_sco )   ioptio = ioptio + 1
201      IF( ln_hpg_hel )   ioptio = ioptio + 1
202      IF( ln_hpg_wdj )   ioptio = ioptio + 1
203      IF( ln_hpg_djc )   ioptio = ioptio + 1
204      IF( ln_hpg_rot )   ioptio = ioptio + 1
205      IF ( ioptio > 1 ) THEN
206          IF(lwp) WRITE(numout,cform_err)
207          IF(lwp) WRITE(numout,*) ' several hydrostatic pressure gradient options used'
208          nstop = nstop + 1
209      ENDIF
210
211      IF( lk_dynhpg_jki ) THEN
212         nhpg = nhpg + 10
213         IF(lwp) WRITE(numout,*)
214         IF(lwp) WRITE(numout,*) '          Autotasking or OPENMP: use j-k-i loops (i.e. _jki routines)'
215      ENDIF
216
217   END SUBROUTINE hpg_ctl
218
219
220   SUBROUTINE hpg_zco( kt )
221      !!---------------------------------------------------------------------
222      !!                  ***  ROUTINE hpg_zco  ***
223      !!
224      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
225      !!      The now hydrostatic pressure gradient at a given level, jk,
226      !!      is computed by taking the vertical integral of the in-situ
227      !!      density gradient along the model level from the suface to that
228      !!      level:    zhpi = grav .....
229      !!                zhpj = grav .....
230      !!      add it to the general momentum trend (ua,va).
231      !!            ua = ua - 1/e1u * zhpi
232      !!            va = va - 1/e2v * zhpj
233      !!
234      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
235      !!
236      !! History :
237      !!   1.0  !  87-09  (P. Andrich, M.-A. Foujols)  Original code
238      !!   5.0  !  91-11  (G. Madec)
239      !!   7.0  !  96-01  (G. Madec)
240      !!   8.0  !  97-05  (G. Madec)  split dynber into dynkeg and dynhpg
241      !!   8.5  !  02-07  (G. Madec)  F90: Free form and module
242      !!----------------------------------------------------------------------
243      !! * modules used
244      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
245         &              zhpj => sa      ! use sa as 3D workspace
246     
247      !! * Arguments
248      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
249     
250      !! * local declarations
251      INTEGER ::   ji, jj, jk           ! dummy loop indices
252      REAL(wp) ::   &   
253         zcoef0, zcoef1                 ! temporary scalars
254      !!----------------------------------------------------------------------
255     
256      IF( kt == nit000 ) THEN
257         IF(lwp) WRITE(numout,*)
258         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
259         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
260      ENDIF
261     
262     
263      ! Local constant initialization
264      ! -----------------------------
265      zcoef0 = - grav * 0.5
266
267      ! Surface value
268      ! -------------
269      DO jj = 2, jpjm1
270         DO ji = fs_2, fs_jpim1   ! vector opt.
271            zcoef1 = zcoef0 * fse3w(ji,jj,1)
272            ! hydrostatic pressure gradient
273            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
274            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
275            ! add to the general momentum trend
276            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
277            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
278         END DO
279      END DO
280
281      ! interior value (2=<jk=<jpkm1)
282      ! --------------
283      DO jk = 2, jpkm1
284         DO jj = 2, jpjm1
285            DO ji = fs_2, fs_jpim1   ! vector opt.
286               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
287               ! hydrostatic pressure gradient
288               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
289                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
290                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
291
292               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
293                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
294                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
295               ! add to the general momentum trend
296               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
297               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
298            END DO
299         END DO
300      END DO
301
302   END SUBROUTINE hpg_zco
303
304
305   SUBROUTINE hpg_zps( kt )
306      !!---------------------------------------------------------------------
307      !!                 ***  ROUTINE hpg_zps  ***
308      !!                   
309      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
310      !!
311      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
312      !!   
313      !! History :
314      !!   8.5  !  02-08  (A. Bozec)  Original code
315      !!   9.0  !  04-08  (G. Madec)  F90
316      !!----------------------------------------------------------------------
317      !! * modules used                                 
318      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
319         &              zhpj => sa      ! use sa as 3D workspace
320               
321      !! * Arguments
322      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
323
324      !! * local declarations
325      INTEGER ::   ji, jj, jk           ! dummy loop indices
326      INTEGER ::   iku, ikv             ! temporary integers
327      REAL(wp) ::   &
328         zcoef0, zcoef1,             &  ! temporary scalars
329         zcoef2, zcoef3                 !    "         "
330      !!----------------------------------------------------------------------
331
332      IF( kt == nit000 ) THEN
333         IF(lwp) WRITE(numout,*)
334         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
335         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps'
336         IF(lwp) WRITE(numout,*) '              vector optimization'
337      ENDIF
338
339
340      ! 0. Local constant initialization
341      ! --------------------------------
342      zcoef0 = - grav * 0.5
343
344      ! 1. Surface value
345      ! ----------------
346      DO jj = 2, jpjm1
347         DO ji = fs_2, fs_jpim1   ! vector opt.
348            zcoef1 = zcoef0 * fse3w(ji,jj,1)
349            ! hydrostatic pressure gradient
350            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
351            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
352            ! add to the general momentum trend
353            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
354            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
355         END DO
356      END DO
357
358      ! 2. interior value (2=<jk=<jpkm1)
359      ! -----------------
360      DO jk = 2, jpkm1
361         DO jj = 2, jpjm1
362            DO ji = fs_2, fs_jpim1   ! vector opt.
363               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
364               ! hydrostatic pressure gradient
365               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
366                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
367                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
368
369               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
370                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
371                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
372               ! add to the general momentum trend
373               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
374               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
375            END DO
376         END DO
377      END DO
378
379      ! partial steps correction at the last level  (new gradient with  intgrd.F)
380# if defined key_vectopt_loop
381         jj = 1
382         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
383# else
384      DO jj = 2, jpjm1
385         DO ji = 2, jpim1
386# endif
387            iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj) ) - 1
388            ikv = MIN ( mbathy(ji,jj), mbathy(ji,jj+1) ) - 1
389            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
390            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
391            ! on i-direction
392            IF ( iku > 2 ) THEN
393               ! subtract old value
394               ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)
395               ! compute the new one
396               zhpi (ji,jj,iku) = zhpi(ji,jj,iku-1)   &
397                  + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
398               ! add the new one to the general momentum trend
399               ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)
400            ENDIF
401            ! on j-direction
402            IF ( ikv > 2 ) THEN
403               ! subtract old value
404               va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)
405               ! compute the new one
406               zhpj (ji,jj,ikv) = zhpj(ji,jj,ikv-1)   &
407                  + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
408               ! add the new one to the general momentum trend
409               va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)
410            ENDIF
411# if ! defined key_vectopt_loop
412         END DO
413# endif
414      END DO
415
416   END SUBROUTINE hpg_zps
417
418
419   SUBROUTINE hpg_sco( kt )
420      !!---------------------------------------------------------------------
421      !!                  ***  ROUTINE hpg_sco  ***
422      !!
423      !! ** Method  :   s-coordinate case. Jacobian scheme.
424      !!      The now hydrostatic pressure gradient at a given level, jk,
425      !!      is computed by taking the vertical integral of the in-situ
426      !!      density gradient along the model level from the suface to that
427      !!      level. s-coordinates (ln_sco): a corrective term is added
428      !!      to the horizontal pressure gradient :
429      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
430      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
431      !!      add it to the general momentum trend (ua,va).
432      !!         ua = ua - 1/e1u * zhpi
433      !!         va = va - 1/e2v * zhpj
434      !!
435      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
436      !!
437      !! History :
438      !!   7.0  !  96-01  (G. Madec)  s-coordinates
439      !!        !  97-05  (G. Madec)  split dynber into dynkeg and dynhpg
440      !!   8.5  !  02-08  (G. Madec)  F90: Free form and module, vector opt.
441      !!   9.0  !  04-08  (C. Talandier) New trends organization
442      !!   9.0  !  05-10  (A. Beckmann) various s-coordinate options
443      !!----------------------------------------------------------------------
444      !! * modules used
445      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
446         &              zhpj => sa      ! use sa as 3D workspace
447
448      !! * Arguments
449      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
450
451      !! * Local declarations
452      INTEGER ::   ji, jj, jk           ! dummy loop indices
453      REAL(wp) ::   &
454         zcoef0, zuap, zvap             ! temporary scalars
455      !!----------------------------------------------------------------------
456
457      IF( kt == nit000 ) THEN
458         IF(lwp) WRITE(numout,*)
459         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
460         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
461      ENDIF
462
463
464      ! 0. Local constant initialization
465      ! --------------------------------
466      zcoef0 = - grav * 0.5
467
468
469      ! 1. Surface value
470      ! ----------------                         
471      DO jj = 2, jpjm1
472         DO ji = fs_2, fs_jpim1   ! vector opt.   
473            ! hydrostatic pressure gradient along s-surfaces
474            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)   &
475               &                                  - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
476            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
477               &                                  - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
478            ! s-coordinate pressure gradient correction
479            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
480               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
481            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
482               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
483            ! add to the general momentum trend
484            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
485            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
486         END DO 
487      END DO   
488           
489               
490      ! 2. interior value (2=<jk=<jpkm1)
491      ! -----------------     
492      DO jk = 2, jpkm1                                 
493         DO jj = 2, jpjm1     
494            DO ji = fs_2, fs_jpim1   ! vector opt.     
495               ! hydrostatic pressure gradient along s-surfaces
496               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
497                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   & 
498                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  )
499               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
500                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
501                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  )
502               ! s-coordinate pressure gradient correction
503               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
504                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
505               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
506                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
507               ! add to the general momentum trend
508               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
509               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
510            END DO
511         END DO
512      END DO
513
514   END SUBROUTINE hpg_sco
515
516
517   SUBROUTINE hpg_hel( kt )
518      !!---------------------------------------------------------------------
519      !!                  ***  ROUTINE hpg_hel  ***
520      !!
521      !! ** Method  :   s-coordinate case.
522      !!      The now hydrostatic pressure gradient at a given level
523      !!      jk is computed by taking the vertical integral of the in-situ
524      !!      density gradient along the model level from the suface to that
525      !!      level. s-coordinates (ln_sco): a corrective term is added
526      !!      to the horizontal pressure gradient :
527      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
528      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
529      !!      add it to the general momentum trend (ua,va).
530      !!         ua = ua - 1/e1u * zhpi
531      !!         va = va - 1/e2v * zhpj
532      !!
533      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
534      !!             - Save the trend (l_trddyn=T)
535      !!
536      !! History :
537      !!   9.0  !  05-10  (A. Beckmann)  Original code
538      !!----------------------------------------------------------------------
539      !! * modules used
540      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
541         &              zhpj => sa      ! use sa as 3D workspace
542
543      !! * Arguments
544      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
545     
546      !! * Local declarations
547      INTEGER ::   ji, jj, jk           ! dummy loop indices
548      REAL(wp) ::   &
549         zcoef0, zuap, zvap             ! temporary scalars
550      !!----------------------------------------------------------------------
551
552      IF( kt == nit000 ) THEN
553         IF(lwp) WRITE(numout,*)
554         IF(lwp) WRITE(numout,*) 'dyn:hpg_hel : hydrostatic pressure gradient trend'
555         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, helsinki modified scheme'
556      ENDIF
557
558
559      ! 0. Local constant initialization
560      ! --------------------------------
561      zcoef0 = - grav * 0.5
562
563 
564      ! 1. Surface value
565      ! ----------------
566      DO jj = 2, jpjm1
567         DO ji = fs_2, fs_jpim1   ! vector opt.
568            ! hydrostatic pressure gradient along s-surfaces
569            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  &
570               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
571            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)  &
572               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
573            ! s-coordinate pressure gradient correction
574            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
575               &           * ( fsdept(ji+1,jj,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
576            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
577               &           * ( fsdept(ji,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
578            ! add to the general momentum trend
579            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
580            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
581         END DO
582      END DO
583
584      ! 2. interior value (2=<jk=<jpkm1)
585      ! -----------------
586      DO jk = 2, jpkm1
587         DO jj = 2, jpjm1
588            DO ji = fs_2, fs_jpim1   ! vector opt.
589               ! hydrostatic pressure gradient along s-surfaces
590               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
591                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk)     &
592                  &                                     -fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk)   ) &
593                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
594                  &                                     -fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1) )
595               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
596                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk)   &
597                  &                                     -fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk)   ) &
598                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1) &
599                  &                                     -fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1) )
600               ! s-coordinate pressure gradient correction
601               zuap = - zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )   &
602                  &            * ( fsdept(ji+1,jj,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
603               zvap = - zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )   &
604                  &            * ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
605               ! add to the general momentum trend
606               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
607               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
608            END DO
609         END DO
610      END DO
611
612   END SUBROUTINE hpg_hel
613
614
615   SUBROUTINE hpg_wdj( kt )
616      !!---------------------------------------------------------------------
617      !!                  ***  ROUTINE hpg_wdj  ***
618      !!
619      !! ** Method  :   Weighted Density Jacobian (wdj) scheme (song 1998)
620      !!      The weighting coefficients from the namelist parameter gamm
621      !!      (alpha=0.5-gamm ; beta=1-alpha=0.5+gamm)
622      !!
623      !! Reference : Song, Mon. Wea. Rev., 126, 3213-3230, 1998.
624      !!
625      !! History :
626      !!   9.0  !  05-05  (B.W. An)  Original code
627      !!        !  05-10  (G. Madec) style & small optimisation
628      !!----------------------------------------------------------------------
629      !! * modules used
630      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
631         &              zhpj => sa      ! use sa as 3D workspace
632
633      !! * Arguments
634      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
635
636      !! * Local declarations
637      INTEGER ::   ji, jj, jk           ! dummy loop indices
638      REAL(wp) ::   &
639         zcoef0, zuap, zvap,         &  ! temporary scalars
640         zalph , zbeta                  !    "         "
641      !!----------------------------------------------------------------------
642
643      IF( kt == nit000 ) THEN
644         IF(lwp) WRITE(numout,*)
645         IF(lwp) WRITE(numout,*) 'dyn:hpg_wdj : hydrostatic pressure gradient trend'
646         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   Weighted Density Jacobian'
647      ENDIF
648
649
650      ! Local constant initialization
651      ! -----------------------------
652      zcoef0 = - grav * 0.5
653      zalph  = 0.5 - gamm        ! weighting coefficients (alpha=0.5-gamm)
654      zbeta  = 0.5 + gamm        !                        (beta =1-alpha=0.5+gamm)
655
656      ! Surface value (no ponderation)
657      ! -------------
658      DO jj = 2, jpjm1
659         DO ji = fs_2, fs_jpim1   ! vector opt.
660            ! hydrostatic pressure gradient along s-surfaces
661            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3w(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)   &
662               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
663            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3w(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
664               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji,  jj  ,1)  )
665            ! s-coordinate pressure gradient correction
666            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
667               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
668            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
669               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
670            ! add to the general momentum trend
671            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
672            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
673         END DO
674      END DO
675
676      ! Interior value (2=<jk=<jpkm1) (weighted with zalph & zbeta)
677      ! --------------
678      DO jk = 2, jpkm1
679         DO jj = 2, jpjm1
680            DO ji = fs_2, fs_jpim1   ! vector opt.
681               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)                            &
682                  &           * (   (            fsde3w(ji+1,jj,jk  ) + fsde3w(ji,jj,jk  )        &
683                  &                            - fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1)    )   &
684                  &               * (  zalph * ( rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1) )      &
685                  &                  + zbeta * ( rhd   (ji+1,jj,jk  ) - rhd   (ji,jj,jk  ) )  )   &
686                  &             -   (            rhd   (ji+1,jj,jk  ) + rhd   (ji,jj,jk  )        &
687                  &                           - rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1)     )   &
688                  &               * (  zalph * ( fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1) )      &
689                  &                  + zbeta * ( fsde3w(ji+1,jj,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
690               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)                            &
691                  &           * (   (           fsde3w(ji,jj+1,jk  ) + fsde3w(ji,jj,jk  )         &
692                  &                           - fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1)     )   &
693                  &               * (  zalph * ( rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1) )      &
694                  &                  + zbeta * ( rhd   (ji,jj+1,jk  ) - rhd   (ji,jj,jk  ) )  )   &
695                  &             -   (            rhd   (ji,jj+1,jk  ) + rhd   (ji,jj,jk  )        &
696                  &                            - rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1)    )   &
697                  &               * (  zalph * ( fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1) )      &
698                  &                  + zbeta * ( fsde3w(ji,jj+1,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
699               ! add to the general momentum trend
700               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
701               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
702            END DO
703         END DO
704      END DO
705
706   END SUBROUTINE hpg_wdj
707
708
709   SUBROUTINE hpg_djc( kt )
710      !!---------------------------------------------------------------------
711      !!                  ***  ROUTINE hpg_djc  ***
712      !!
713      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
714      !!
715      !! Reference: Shchepetkin, A.F. & J.C. McWilliams, J. Geophys. Res.,
716      !!            108(C3), 3090, 2003
717      !! History :
718      !!   9.0  !  05-05  (B.W. An)  Original code
719      !!----------------------------------------------------------------------
720      !! * modules used
721      USE oce, ONLY :   zhpi => ta,  &  ! use ta as 3D workspace
722         &              zhpj => sa      ! use sa as 3D workspace
723
724      !! * Arguments
725      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
726     
727      !! * Local declarations
728      INTEGER ::   ji, jj, jk           ! dummy loop indices
729      REAL(wp) ::   &
730         zcoef0, z1_10, cffu, cffx,  &  ! temporary scalars
731                 z1_12, cffv, cffy,  &  !    "         "
732         zep   , cffw                   !    "         "
733      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &  ! 3D workspace
734         drhox, dzx, drhou, dzu, rho_i,     &
735         drhoy, dzy, drhov, dzv, rho_j,     &
736         drhoz, dzz, drhow, dzw, rho_k
737      !!----------------------------------------------------------------------
738
739      IF( kt == nit000 ) THEN
740         IF(lwp) WRITE(numout,*)
741         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
742         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
743      ENDIF
744
745
746      ! 0. Local constant initialization
747      ! --------------------------------
748      zcoef0 = - grav * 0.5
749      z1_10  = 1.0 / 10.0
750      z1_12  = 1.0 / 12.0
751
752      !----------------------------------------------------------------------------------------
753      !  compute and store in provisional arrays elementary vertical and horizontal differences
754      !----------------------------------------------------------------------------------------
755
756!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
757
758      DO jk = 2, jpkm1
759         DO jj = 2, jpjm1
760            DO ji = fs_2, fs_jpim1   ! vector opt.
761               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
762               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
763               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
764               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
765               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
766               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
767            END DO
768         END DO
769      END DO
770
771      !-------------------------------------------------------------------------
772      ! compute harmonic averages using eq. 5.18
773      !-------------------------------------------------------------------------
774      zep = 1.e-15
775
776      !!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
777      !!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
778
779      DO jk = 2, jpkm1
780         DO jj = 2, jpjm1
781            DO ji = fs_2, fs_jpim1   ! vector opt.
782               cffw = 2.0 * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
783
784               cffu = 2.0 * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
785               cffx = 2.0 * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
786 
787               cffv = 2.0 * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
788               cffy = 2.0 * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
789
790               IF( cffw > zep) THEN
791                  drhow(ji,jj,jk) = 2.0 *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
792                     &                  / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
793               ELSE
794                  drhow(ji,jj,jk) = 0.e0
795               ENDIF
796
797               dzw(ji,jj,jk) = 2.0 *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
798                  &                / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
799
800               IF( cffu > zep ) THEN
801                  drhou(ji,jj,jk) = 2.0 *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
802                     &                  / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
803               ELSE
804                  drhou(ji,jj,jk ) = 0.e0
805               ENDIF
806
807               IF( cffx > zep ) THEN
808                  dzu(ji,jj,jk) = 2.0*dzx(ji+1,jj,jk)*dzx(ji,jj,jk)   &
809                     &            /(dzx(ji+1,jj,jk)+dzx(ji,jj,jk))
810               ELSE
811                  dzu(ji,jj,jk) = 0.e0
812               ENDIF
813
814               IF( cffv > zep ) THEN
815                  drhov(ji,jj,jk) = 2.0 *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
816                     &                  / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
817               ELSE
818                  drhov(ji,jj,jk) = 0.e0
819               ENDIF
820
821               IF( cffy > zep ) THEN
822                  dzv(ji,jj,jk) = 2.0 *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
823                     &                / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
824               ELSE
825                  dzv(ji,jj,jk) = 0.e0
826               ENDIF
827
828            END DO
829         END DO
830      END DO
831
832      !----------------------------------------------------------------------------------
833      ! apply boundary conditions at top and bottom using 5.36-5.37
834      !----------------------------------------------------------------------------------
835      drhow(:,:, 1 ) = 1.5 * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5 * drhow(:,:,  2  )
836      drhou(:,:, 1 ) = 1.5 * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5 * drhou(:,:,  2  )
837      drhov(:,:, 1 ) = 1.5 * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5 * drhov(:,:,  2  )
838
839      drhow(:,:,jpk) = 1.5 * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5 * drhow(:,:,jpkm1)
840      drhou(:,:,jpk) = 1.5 * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5 * drhou(:,:,jpkm1)
841      drhov(:,:,jpk) = 1.5 * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5 * drhov(:,:,jpkm1)
842
843
844      !--------------------------------------------------------------
845      ! Upper half of top-most grid box, compute and store
846      !-------------------------------------------------------------
847
848!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
849!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
850
851      DO jj = 2, jpjm1
852         DO ji = fs_2, fs_jpim1   ! vector opt.
853            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )            &
854               &                   * (  rhd(ji,jj,1)                                 &
855               &                     + 0.5 * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
856               &                           * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
857               &                           / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
858         END DO
859      END DO
860
861!!bug gm    : here also, simplification is possible
862!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
863
864      DO jk = 2, jpkm1
865         DO jj = 2, jpjm1
866            DO ji = fs_2, fs_jpim1   ! vector opt.
867
868               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
869                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
870                  &            - grav * z1_10 * (                                                                     &
871                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
872                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
873                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
874                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
875                  &                             )
876
877               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
878                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
879                  &            - grav* z1_10 * (                                                                      &
880                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
881                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
882                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
883                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
884                  &                            )
885
886               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
887                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
888                  &            - grav* z1_10 * (                                                                      &
889                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
890                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
891                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
892                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
893                  &                            )
894
895            END DO
896         END DO
897      END DO
898      CALL lbc_lnk(rho_k,'W',1.)
899      CALL lbc_lnk(rho_i,'U',1.)
900      CALL lbc_lnk(rho_j,'V',1.)
901
902
903      ! ---------------
904      !  Surface value
905      ! ---------------
906      DO jj = 2, jpjm1
907         DO ji = fs_2, fs_jpim1   ! vector opt.
908            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
909            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
910            ! add to the general momentum trend
911            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
912            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
913         END DO
914      END DO
915
916      ! ----------------
917      !  interior value   (2=<jk=<jpkm1)
918      ! ----------------
919      DO jk = 2, jpkm1
920         DO jj = 2, jpjm1 
921            DO ji = fs_2, fs_jpim1   ! vector opt.
922               ! hydrostatic pressure gradient along s-surfaces
923               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
924                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
925                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
926               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
927                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
928                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
929               ! add to the general momentum trend
930               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
931               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
932            END DO
933         END DO
934      END DO
935
936   END SUBROUTINE hpg_djc
937
938
939   SUBROUTINE hpg_rot( kt )
940      !!---------------------------------------------------------------------
941      !!                  ***  ROUTINE hpg_rot  ***
942      !!
943      !! ** Method  :   rotated axes scheme (Thiem and Berntsen 2005)
944      !!
945      !! Reference: Thiem & Berntsen, Ocean Modelling, In press, 2005.
946      !! History :
947      !!   9.0  !  05-07 (B.W. An)
948      !!   9.0  !  05-10 (A. Beckmann) adapted to non-equidistant and masked grids
949      !!----------------------------------------------------------------------
950      !! * modules used
951      USE oce, ONLY :   zhpi => ta,         &  ! use ta as 3D workspace
952         &              zhpj => sa             ! use sa as 3D workspace
953
954      !! * Arguments
955      INTEGER, INTENT( in ) ::   kt            ! ocean time-step index
956     
957      !! * Local declarations
958      INTEGER ::   ji, jj, jk                  ! dummy loop indices
959      REAL(wp) ::   &
960         zforg, zcoef0, zuap, zmskd1, zmskd1m,                             &
961         zfrot        , zvap, zmskd2, zmskd2m
962      REAL(wp), DIMENSION(jpi,jpj) ::       &  ! 2D temporary workspace
963         zdistr, zsina, zcosa             
964      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &  ! 3D temporary workspace
965         zhpiorg, zhpirot, zhpitra, zhpine, & 
966         zhpjorg, zhpjrot, zhpjtra, zhpjne
967      !!----------------------------------------------------------------------
968
969      IF( kt == nit000 ) THEN
970         IF(lwp) WRITE(numout,*)
971         IF(lwp) WRITE(numout,*) 'dyn:hpg_rot : hydrostatic pressure gradient trend'
972         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, rotated axes scheme used'
973      ENDIF
974
975      ! -------------------------------
976      !  Local constant initialization
977      ! -------------------------------
978      zcoef0 = - grav * 0.5
979      zforg  = 0.95e0
980      zfrot  = 1.e0 - zforg
981
982      ! inverse of the distance between 2 diagonal T-points (defined at F-point) (here zcoef0/distance)
983      zdistr(:,:) = zcoef0 / SQRT( e1f(:,:)*e1f(:,:) + e2f(:,:)*e1f(:,:) )
984
985      ! sinus and cosinus of diagonal angle at F-point
986      zsina(:,:) = ATAN2( e2f(:,:), e1f(:,:) )
987      zcosa(:,:) = COS( zsina(:,:) )
988      zsina(:,:) = SIN( zsina(:,:) )
989
990      ! ---------------
991      !  Surface value
992      ! ---------------
993      ! compute and add to the general trend the pressure gradients along the axes
994      DO jj = 2, jpjm1
995         DO ji = fs_2, fs_jpim1   ! vector opt.
996            ! hydrostatic pressure gradient along s-surfaces
997            zhpiorg(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,1) * rhd(ji+1,jj,1)   &
998               &                                      - fse3t(ji  ,jj,1) * rhd(ji  ,jj,1)  )
999            zhpjorg(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,1) * rhd(ji,jj+1,1)   &
1000               &                                      - fse3t(ji,jj  ,1) * rhd(ji,jj  ,1)  )
1001            ! s-coordinate pressure gradient correction
1002            zuap = -zcoef0 * ( rhd   (ji+1,jj  ,1) + rhd   (ji,jj,1) )   &
1003               &           * ( fsdept(ji+1,jj  ,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
1004            zvap = -zcoef0 * ( rhd   (ji  ,jj+1,1) + rhd   (ji,jj,1) )   &
1005               &           * ( fsdept(ji  ,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
1006            ! add to the general momentum trend
1007            ua(ji,jj,1) = ua(ji,jj,1) + zforg * ( zhpiorg(ji,jj,1) + zuap )
1008            va(ji,jj,1) = va(ji,jj,1) + zforg * ( zhpjorg(ji,jj,1) + zvap )
1009         END DO
1010      END DO
1011
1012      ! compute the pressure gradients in the diagonal directions
1013      DO jj = 1, jpjm1
1014         DO ji = 1, fs_jpim1   ! vector opt.
1015            zmskd1 = tmask(ji+1,jj+1,1) * tmask(ji  ,jj,1)      ! mask in the 1st diagnonal
1016            zmskd2 = tmask(ji  ,jj+1,1) * tmask(ji+1,jj,1)      ! mask in the 2nd diagnonal
1017            ! hydrostatic pressure gradient along s-surfaces
1018            zhpitra(ji,jj,1) = zdistr(ji,jj) * zmskd1 * (  fse3t(ji+1,jj+1,1) * rhd(ji+1,jj+1,1)   &
1019               &                                         - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
1020            zhpjtra(ji,jj,1) = zdistr(ji,jj) * zmskd2 * (  fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
1021               &                                         - fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  )
1022            ! s-coordinate pressure gradient correction
1023            zuap = -zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,1) + rhd   (ji  ,jj,1) )   &
1024               &                           * ( fsdept(ji+1,jj+1,1) - fsdept(ji  ,jj,1) )
1025            zvap = -zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,1) + rhd   (ji+1,jj,1) )   &
1026               &                           * ( fsdept(ji  ,jj+1,1) - fsdept(ji+1,jj,1) )
1027            ! back rotation
1028            zhpine(ji,jj,1) = zcosa(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
1029               &            - zsina(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
1030            zhpjne(ji,jj,1) = zsina(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
1031               &            + zcosa(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
1032         END DO
1033      END DO
1034
1035      ! interpolate and add to the general trend the diagonal gradient
1036      DO jj = 2, jpjm1
1037         DO ji = fs_2, fs_jpim1   ! vector opt.
1038            ! averaging
1039            zhpirot(ji,jj,1) = 0.5 * ( zhpine(ji,jj,1) + zhpine(ji  ,jj-1,1) )
1040            zhpjrot(ji,jj,1) = 0.5 * ( zhpjne(ji,jj,1) + zhpjne(ji-1,jj  ,1) )
1041            ! add to the general momentum trend
1042            ua(ji,jj,1) = ua(ji,jj,1) + zfrot * zhpirot(ji,jj,1) 
1043            va(ji,jj,1) = va(ji,jj,1) + zfrot * zhpjrot(ji,jj,1) 
1044         END DO
1045      END DO
1046
1047      ! -----------------
1048      ! 2. interior value (2=<jk=<jpkm1)
1049      ! -----------------
1050      ! compute and add to the general trend the pressure gradients along the axes
1051      DO jk = 2, jpkm1
1052         DO jj = 2, jpjm1
1053            DO ji = fs_2, fs_jpim1   ! vector opt.
1054               ! hydrostatic pressure gradient along s-surfaces
1055               zhpiorg(ji,jj,jk) = zhpiorg(ji,jj,jk-1)                                                 &
1056                  &              +  zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk  )   &
1057                  &                                        - fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk  )   &
1058                  &                                        + fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
1059                  &                                        - fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1)  )
1060               zhpjorg(ji,jj,jk) = zhpjorg(ji,jj,jk-1)                                                 &
1061                  &              +  zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk  )   &
1062                  &                                        - fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk  )   &
1063                  &                                        + fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1)   &
1064                  &                                        - fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1)  )
1065               ! s-coordinate pressure gradient correction
1066               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
1067                  &            * ( fsdept(ji+1,jj  ,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
1068               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
1069                  &            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
1070               ! add to the general momentum trend
1071               ua(ji,jj,jk) = ua(ji,jj,jk) + zforg*( zhpiorg(ji,jj,jk) + zuap )
1072               va(ji,jj,jk) = va(ji,jj,jk) + zforg*( zhpjorg(ji,jj,jk) + zvap )
1073            END DO
1074         END DO
1075      END DO
1076
1077      ! compute the pressure gradients in the diagonal directions
1078      DO jk = 2, jpkm1
1079         DO jj = 1, jpjm1
1080            DO ji = 1, fs_jpim1   ! vector opt.
1081               zmskd1  = tmask(ji+1,jj+1,jk  ) * tmask(ji  ,jj,jk  )      ! level jk   mask in the 1st diagnonal
1082               zmskd1m = tmask(ji+1,jj+1,jk-1) * tmask(ji  ,jj,jk-1)      ! level jk-1    "               "     
1083               zmskd2  = tmask(ji  ,jj+1,jk  ) * tmask(ji+1,jj,jk  )      ! level jk   mask in the 2nd diagnonal
1084               zmskd2m = tmask(ji  ,jj+1,jk-1) * tmask(ji+1,jj,jk-1)      ! level jk-1    "               "     
1085               ! hydrostatic pressure gradient along s-surfaces
1086               zhpitra(ji,jj,jk) = zhpitra(ji,jj,jk-1)                                                       &
1087                  &              + zdistr(ji,jj) * zmskd1  * ( fse3t(ji+1,jj+1,jk  ) * rhd(ji+1,jj+1,jk)     &
1088                  &                                           -fse3t(ji  ,jj  ,jk  ) * rhd(ji  ,jj  ,jk) )   &
1089                  &              + zdistr(ji,jj) * zmskd1m * ( fse3t(ji+1,jj+1,jk-1) * rhd(ji+1,jj+1,jk-1)   &
1090                  &                                           -fse3t(ji  ,jj  ,jk-1) * rhd(ji  ,jj  ,jk-1) )
1091               zhpjtra(ji,jj,jk) = zhpjtra(ji,jj,jk-1)                                                       &
1092                  &              + zdistr(ji,jj) * zmskd2  * ( fse3t(ji  ,jj+1,jk  ) * rhd(ji  ,jj+1,jk)     &
1093                  &                                           -fse3t(ji+1,jj  ,jk  ) * rhd(ji+1,jj,  jk) )   &
1094                  &              + zdistr(ji,jj) * zmskd2m * ( fse3t(ji  ,jj+1,jk-1) * rhd(ji  ,jj+1,jk-1)   &
1095                  &                                           -fse3t(ji+1,jj  ,jk-1) * rhd(ji+1,jj,  jk-1) )
1096               ! s-coordinate pressure gradient correction
1097               zuap = - zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,jk) + rhd   (ji  ,jj,jk) )   &
1098                  &                            * ( fsdept(ji+1,jj+1,jk) - fsdept(ji  ,jj,jk) )
1099               zvap = - zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji+1,jj,jk) )   &
1100                  &                            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji+1,jj,jk) )
1101               ! back rotation
1102               zhpine(ji,jj,jk) = zcosa(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
1103                  &             - zsina(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
1104               zhpjne(ji,jj,jk) = zsina(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
1105                  &             + zcosa(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
1106            END DO
1107         END DO
1108      END DO
1109
1110      ! interpolate and add to the general trend
1111      DO jk = 2, jpkm1
1112         DO jj = 2, jpjm1
1113            DO ji = fs_2, fs_jpim1   ! vector opt.
1114               ! averaging
1115               zhpirot(ji,jj,jk) = 0.5 * ( zhpine(ji,jj,jk) + zhpine(ji  ,jj-1,jk) )
1116               zhpjrot(ji,jj,jk) = 0.5 * ( zhpjne(ji,jj,jk) + zhpjne(ji-1,jj  ,jk) )
1117               ! add to the general momentum trend
1118               ua(ji,jj,jk) = ua(ji,jj,jk) + zfrot * zhpirot(ji,jj,jk) 
1119               va(ji,jj,jk) = va(ji,jj,jk) + zfrot * zhpjrot(ji,jj,jk) 
1120            END DO
1121         END DO
1122      END DO
1123
1124   END SUBROUTINE hpg_rot
1125
1126   !!======================================================================
1127END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.