New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_bilap.F90 in trunk/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMO/OPA_SRC/DYN/dynldf_bilap.F90 @ 235

Last change on this file since 235 was 235, checked in by opalod, 19 years ago

CT : BUGFIX166 : no sign change on the on the curl and div fields (zuf(:,:) & zut(:,:) fields) at the North fold boundary
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 10.2 KB
Line 
1MODULE dynldf_bilap
2   !!======================================================================
3   !!                     ***  MODULE  dynldf_bilap  ***
4   !! Ocean dynamics:  lateral viscosity trend
5   !!======================================================================
6
7   !!----------------------------------------------------------------------
8   !!   dyn_ldf_bilap : update the momentum trend with the lateral diffusion
9   !!                   using an iso-level bilaplacian operator
10   !!----------------------------------------------------------------------
11   !! * Modules used
12   USE oce             ! ocean dynamics and tracers
13   USE dom_oce         ! ocean space and time domain
14   USE ldfdyn_oce      ! ocean dynamics: lateral physics
15   USE in_out_manager  ! I/O manager
16   USE trdmod          ! ocean dynamics trends
17   USE trdmod_oce      ! ocean variables trends
18   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
19
20   IMPLICIT NONE
21   PRIVATE
22
23   !! * Routine accessibility
24   PUBLIC dyn_ldf_bilap  ! called by step.F90
25
26   !! * Substitutions
27#  include "domzgr_substitute.h90"
28#  include "ldfdyn_substitute.h90"
29#  include "vectopt_loop_substitute.h90"
30   !!----------------------------------------------------------------------
31   !!   OPA 9.0 , LODYC-IPSL   (2003)
32   !!----------------------------------------------------------------------
33
34CONTAINS
35
36   SUBROUTINE dyn_ldf_bilap( kt )
37      !!----------------------------------------------------------------------
38      !!                     ***  ROUTINE dyn_ldf_bilap  ***
39      !!
40      !! ** Purpose :   Compute the before trend of the lateral momentum
41      !!      diffusion and add it to the general trend of momentum equation.
42      !!
43      !! ** Method  :   The before horizontal momentum diffusion trend is a
44      !!      bi-harmonic operator (bilaplacian type) which separates the
45      !!      divergent and rotational parts of the flow.
46      !!      Its horizontal components are computed as follow:
47      !!      laplacian:
48      !!          zlu = 1/e1u di[ hdivb ] - 1/(e2u*e3u) dj-1[ e3f rotb ]
49      !!          zlv = 1/e2v dj[ hdivb ] + 1/(e1v*e3v) di-1[ e3f rotb ]
50      !!      third derivative:
51      !!       * multiply by the eddy viscosity coef. at u-, v-point, resp.
52      !!          zlu = ahmu * zlu
53      !!          zlv = ahmv * zlv
54      !!       * curl and divergence of the laplacian
55      !!          zuf = 1/(e1f*e2f) ( di[e2v zlv] - dj[e1u zlu] )
56      !!          zut = 1/(e1t*e2t*e3t) ( di[e2u*e3u zlu] + dj[e1v*e3v zlv] )
57      !!      bilaplacian:
58      !!              diffu = 1/e1u di[ zut ] - 1/(e2u*e3u) dj-1[ e3f zuf ]
59      !!              diffv = 1/e2v dj[ zut ] + 1/(e1v*e3v) di-1[ e3f zuf ]
60      !!      If lk_sco=F and lk_zps=F, the vertical scale factors in the
61      !!      rotational part of the diffusion are simplified
62      !!      Add this before trend to the general trend (ua,va):
63      !!            (ua,va) = (ua,va) + (diffu,diffv)
64      !!      'key_trddyn' defined: the two components of the horizontal
65      !!                               diffusion trend are saved.
66      !!
67      !! ** Action : - Update (ua,va) with the before iso-level biharmonic
68      !!               mixing trend.
69      !!             - Save in (ztdua,ztdva) the trends ('key_trddyn')
70      !!
71      !! History :
72      !!        !  90-09  (G. Madec)  Original code
73      !!        !  91-11  (G. Madec)
74      !!        !  93-03  (M. Guyon)  symetrical conditions (M. Guyon)
75      !!        !  96-01  (G. Madec)  statement function for e3
76      !!        !  97-07  (G. Madec)  lbc calls
77      !!   8.5  !  02-08  (G. Madec)  F90: Free form and module
78      !!   9.0  !  04-08  (C. Talandier) New trends organization
79      !!----------------------------------------------------------------------
80      !! * Modules used     
81      USE oce, ONLY :    ztdua => ta,      & ! use ta as 3D workspace   
82                         ztdva => sa         ! use sa as 3D workspace   
83
84      !! * Arguments
85      INTEGER, INTENT( in ) ::   kt           ! ocean time-step index
86
87      !! * Local declarations
88      INTEGER  ::   ji, jj, jk                ! dummy loop indices
89      REAL(wp) ::   zua, zva, zbt, ze2u, ze2v ! temporary scalar
90      REAL(wp), DIMENSION(jpi,jpj) ::   &
91         zuf, zut, zlu, zlv, zcu, zcv         ! temporary workspace
92      !!----------------------------------------------------------------------
93      !!  OPA 8.5, LODYC-IPSL (2002)
94      !!----------------------------------------------------------------------
95
96      IF( kt == nit000 ) THEN
97         IF(lwp) WRITE(numout,*)
98         IF(lwp) WRITE(numout,*) 'dyn_ldf_bilap : iso-level bilaplacian operator'
99         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
100      ENDIF
101      zuf(:,:) = 0.e0
102      zut(:,:) = 0.e0
103      zlu(:,:) = 0.e0
104      zlv(:,:) = 0.e0
105
106      ! Save ua and va trends
107      IF( l_trddyn )   THEN
108         ztdua(:,:,:) = ua(:,:,:) 
109         ztdva(:,:,:) = va(:,:,:) 
110      ENDIF
111      !                                                ! ===============
112      DO jk = 1, jpkm1                                 ! Horizontal slab
113         !                                             ! ===============
114         ! Laplacian
115         ! ---------
116
117         IF( lk_sco .OR. lk_zps ) THEN   ! s-coordinate or z-coordinate with partial steps
118            zuf(:,:) = rotb(:,:,jk) * fse3f(:,:,jk)
119            DO jj = 2, jpjm1
120               DO ji = fs_2, fs_jpim1   ! vector opt.
121                  zlu(ji,jj) = - ( zuf(ji,jj) - zuf(ji,jj-1) ) / ( e2u(ji,jj) * fse3u(ji,jj,jk) )   &
122                     &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj,jk) ) / e1u(ji,jj)
123   
124                  zlv(ji,jj) = + ( zuf(ji,jj) - zuf(ji-1,jj) ) / ( e1v(ji,jj) * fse3v(ji,jj,jk) )   &
125                     &         + ( hdivb(ji,jj+1,jk) - hdivb(ji,jj,jk) ) / e2v(ji,jj)
126               END DO
127            END DO
128         ELSE                            ! z-coordinate
129            DO jj = 2, jpjm1
130               DO ji = fs_2, fs_jpim1   ! vector opt.
131                  zlu(ji,jj) = - ( rotb (ji  ,jj,jk) - rotb (ji,jj-1,jk) ) / e2u(ji,jj)   &
132                     &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj  ,jk) ) / e1u(ji,jj)
133   
134                  zlv(ji,jj) = + ( rotb (ji,jj  ,jk) - rotb (ji-1,jj,jk) ) / e1v(ji,jj)   &
135                     &         + ( hdivb(ji,jj+1,jk) - hdivb(ji  ,jj,jk) ) / e2v(ji,jj)
136               END DO 
137            END DO 
138         ENDIF
139
140         ! Boundary conditions on the laplacian  (zlu,zlv)
141         CALL lbc_lnk( zlu, 'U', -1. )
142         CALL lbc_lnk( zlv, 'V', -1. )
143         
144         
145         ! Third derivative
146         ! ----------------
147         
148         ! Multiply by the eddy viscosity coef. (at u- and v-points)
149         zlu(:,:) = zlu(:,:) * fsahmu(:,:,jk)
150         zlv(:,:) = zlv(:,:) * fsahmv(:,:,jk)
151         
152         ! Contravariant "laplacian"
153         zcu(:,:) = e1u(:,:) * zlu(:,:)
154         zcv(:,:) = e2v(:,:) * zlv(:,:)
155         
156         ! Laplacian curl ( * e3f if s-coordinates or z-coordinate with partial steps)
157         DO jj = 1, jpjm1
158            DO ji = 1, fs_jpim1   ! vector opt.
159               zuf(ji,jj) = fmask(ji,jj,jk) * (  zcv(ji+1,jj  ) - zcv(ji,jj)      &
160                  &                            - zcu(ji  ,jj+1) + zcu(ji,jj)  )   &
161#if defined key_s_coord || defined key_partial_steps
162                  &       * fse3f(ji,jj,jk) / ( e1f(ji,jj)*e2f(ji,jj) )
163#else
164                  &                         / ( e1f(ji,jj)*e2f(ji,jj) )
165#endif
166            END DO 
167         END DO 
168
169         ! Laplacian Horizontal fluxes
170         DO jj = 1, jpjm1
171            DO ji = 1, fs_jpim1   ! vector opt.
172#if defined key_s_coord || defined key_partial_steps
173               zlu(ji,jj) = e2u(ji,jj) * fse3u(ji,jj,jk) * zlu(ji,jj)
174               zlv(ji,jj) = e1v(ji,jj) * fse3v(ji,jj,jk) * zlv(ji,jj)
175#else
176               zlu(ji,jj) = e2u(ji,jj) * zlu(ji,jj)
177               zlv(ji,jj) = e1v(ji,jj) * zlv(ji,jj)
178#endif
179            END DO
180         END DO
181
182         ! Laplacian divergence
183         DO jj = 2, jpj
184            DO ji = fs_2, jpi   ! vector opt.
185#if defined key_s_coord || defined key_partial_steps
186               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk)
187#else
188               zbt = e1t(ji,jj) * e2t(ji,jj)
189#endif
190               zut(ji,jj) = (  zlu(ji,jj) - zlu(ji-1,jj  )   &
191                  &          + zlv(ji,jj) - zlv(ji  ,jj-1)  ) / zbt
192            END DO
193         END DO
194
195
196      ! boundary conditions on the laplacian curl and div (zuf,zut)
197      CALL lbc_lnk( zuf, 'F', 1. )
198      CALL lbc_lnk( zut, 'T', 1. )
199
200         
201         ! Bilaplacian
202         ! -----------
203
204         DO jj = 2, jpjm1
205            DO ji = fs_2, fs_jpim1   ! vector opt.
206#if defined key_s_coord || defined key_partial_steps
207               ze2u = e2u(ji,jj) * fse3u(ji,jj,jk)
208               ze2v = e1v(ji,jj) * fse3v(ji,jj,jk)
209#else
210               ze2u = e2u(ji,jj)
211               ze2v = e1v(ji,jj)
212#endif
213               ! horizontal biharmonic diffusive trends
214               zua = - ( zuf(ji  ,jj) - zuf(ji,jj-1) ) / ze2u   &
215                  &  + ( zut(ji+1,jj) - zut(ji,jj  ) ) / e1u(ji,jj)
216
217               zva = + ( zuf(ji,jj  ) - zuf(ji-1,jj) ) / ze2v   &
218                  &  + ( zut(ji,jj+1) - zut(ji  ,jj) ) / e2v(ji,jj)
219               ! add it to the general momentum trends
220               ua(ji,jj,jk) = ua(ji,jj,jk) + zua
221               va(ji,jj,jk) = va(ji,jj,jk) + zva
222            END DO
223         END DO
224
225         !                                             ! ===============
226      END DO                                           !   End of slab
227      !                                                ! ===============
228      ! save the lateral diffusion trends for diagnostic
229      ! momentum trends
230      IF( l_trddyn )   THEN
231         ztdua(:,:,:) = ua(:,:,:) - ztdua(:,:,:)
232         ztdva(:,:,:) = va(:,:,:) - ztdva(:,:,:)
233
234         CALL trd_mod(ztdua, ztdva, jpdtdldf, 'DYN', kt)
235      ENDIF
236
237      IF(l_ctl) THEN         ! print sum trends (used for debugging)
238         zua = SUM( ua(2:nictl,2:njctl,1:jpkm1) * umask(2:nictl,2:njctl,1:jpkm1) )
239         zva = SUM( va(2:nictl,2:njctl,1:jpkm1) * vmask(2:nictl,2:njctl,1:jpkm1) )
240         WRITE(numout,*) ' ldf  - Ua: ', zua-u_ctl, ' Va: ', zva-v_ctl
241         u_ctl = zua   ;   v_ctl = zva
242      ENDIF
243
244   END SUBROUTINE dyn_ldf_bilap
245
246   !!======================================================================
247END MODULE dynldf_bilap
Note: See TracBrowser for help on using the repository browser.