New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_bilap.F90 in trunk/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMO/OPA_SRC/DYN/dynldf_bilap.F90 @ 247

Last change on this file since 247 was 247, checked in by opalod, 19 years ago

CL : Add CVS Header and CeCILL licence information
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 10.3 KB
Line 
1MODULE dynldf_bilap
2   !!======================================================================
3   !!                     ***  MODULE  dynldf_bilap  ***
4   !! Ocean dynamics:  lateral viscosity trend
5   !!======================================================================
6
7   !!----------------------------------------------------------------------
8   !!   dyn_ldf_bilap : update the momentum trend with the lateral diffusion
9   !!                   using an iso-level bilaplacian operator
10   !!----------------------------------------------------------------------
11   !! * Modules used
12   USE oce             ! ocean dynamics and tracers
13   USE dom_oce         ! ocean space and time domain
14   USE ldfdyn_oce      ! ocean dynamics: lateral physics
15   USE in_out_manager  ! I/O manager
16   USE trdmod          ! ocean dynamics trends
17   USE trdmod_oce      ! ocean variables trends
18   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
19
20   IMPLICIT NONE
21   PRIVATE
22
23   !! * Routine accessibility
24   PUBLIC dyn_ldf_bilap  ! called by step.F90
25
26   !! * Substitutions
27#  include "domzgr_substitute.h90"
28#  include "ldfdyn_substitute.h90"
29#  include "vectopt_loop_substitute.h90"
30   !!----------------------------------------------------------------------
31   !!   OPA 9.0 , LOCEAN-IPSL (2005)
32   !! $Header$
33   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
34   !!----------------------------------------------------------------------
35
36CONTAINS
37
38   SUBROUTINE dyn_ldf_bilap( kt )
39      !!----------------------------------------------------------------------
40      !!                     ***  ROUTINE dyn_ldf_bilap  ***
41      !!
42      !! ** Purpose :   Compute the before trend of the lateral momentum
43      !!      diffusion and add it to the general trend of momentum equation.
44      !!
45      !! ** Method  :   The before horizontal momentum diffusion trend is a
46      !!      bi-harmonic operator (bilaplacian type) which separates the
47      !!      divergent and rotational parts of the flow.
48      !!      Its horizontal components are computed as follow:
49      !!      laplacian:
50      !!          zlu = 1/e1u di[ hdivb ] - 1/(e2u*e3u) dj-1[ e3f rotb ]
51      !!          zlv = 1/e2v dj[ hdivb ] + 1/(e1v*e3v) di-1[ e3f rotb ]
52      !!      third derivative:
53      !!       * multiply by the eddy viscosity coef. at u-, v-point, resp.
54      !!          zlu = ahmu * zlu
55      !!          zlv = ahmv * zlv
56      !!       * curl and divergence of the laplacian
57      !!          zuf = 1/(e1f*e2f) ( di[e2v zlv] - dj[e1u zlu] )
58      !!          zut = 1/(e1t*e2t*e3t) ( di[e2u*e3u zlu] + dj[e1v*e3v zlv] )
59      !!      bilaplacian:
60      !!              diffu = 1/e1u di[ zut ] - 1/(e2u*e3u) dj-1[ e3f zuf ]
61      !!              diffv = 1/e2v dj[ zut ] + 1/(e1v*e3v) di-1[ e3f zuf ]
62      !!      If lk_sco=F and lk_zps=F, the vertical scale factors in the
63      !!      rotational part of the diffusion are simplified
64      !!      Add this before trend to the general trend (ua,va):
65      !!            (ua,va) = (ua,va) + (diffu,diffv)
66      !!      'key_trddyn' defined: the two components of the horizontal
67      !!                               diffusion trend are saved.
68      !!
69      !! ** Action : - Update (ua,va) with the before iso-level biharmonic
70      !!               mixing trend.
71      !!             - Save in (ztdua,ztdva) the trends ('key_trddyn')
72      !!
73      !! History :
74      !!        !  90-09  (G. Madec)  Original code
75      !!        !  91-11  (G. Madec)
76      !!        !  93-03  (M. Guyon)  symetrical conditions (M. Guyon)
77      !!        !  96-01  (G. Madec)  statement function for e3
78      !!        !  97-07  (G. Madec)  lbc calls
79      !!   8.5  !  02-08  (G. Madec)  F90: Free form and module
80      !!   9.0  !  04-08  (C. Talandier) New trends organization
81      !!----------------------------------------------------------------------
82      !! * Modules used     
83      USE oce, ONLY :    ztdua => ta,      & ! use ta as 3D workspace   
84                         ztdva => sa         ! use sa as 3D workspace   
85
86      !! * Arguments
87      INTEGER, INTENT( in ) ::   kt           ! ocean time-step index
88
89      !! * Local declarations
90      INTEGER  ::   ji, jj, jk                ! dummy loop indices
91      REAL(wp) ::   zua, zva, zbt, ze2u, ze2v ! temporary scalar
92      REAL(wp), DIMENSION(jpi,jpj) ::   &
93         zuf, zut, zlu, zlv, zcu, zcv         ! temporary workspace
94      !!----------------------------------------------------------------------
95      !!  OPA 8.5, LODYC-IPSL (2002)
96      !!----------------------------------------------------------------------
97
98      IF( kt == nit000 ) THEN
99         IF(lwp) WRITE(numout,*)
100         IF(lwp) WRITE(numout,*) 'dyn_ldf_bilap : iso-level bilaplacian operator'
101         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
102      ENDIF
103      zuf(:,:) = 0.e0
104      zut(:,:) = 0.e0
105      zlu(:,:) = 0.e0
106      zlv(:,:) = 0.e0
107
108      ! Save ua and va trends
109      IF( l_trddyn )   THEN
110         ztdua(:,:,:) = ua(:,:,:) 
111         ztdva(:,:,:) = va(:,:,:) 
112      ENDIF
113      !                                                ! ===============
114      DO jk = 1, jpkm1                                 ! Horizontal slab
115         !                                             ! ===============
116         ! Laplacian
117         ! ---------
118
119         IF( lk_sco .OR. lk_zps ) THEN   ! s-coordinate or z-coordinate with partial steps
120            zuf(:,:) = rotb(:,:,jk) * fse3f(:,:,jk)
121            DO jj = 2, jpjm1
122               DO ji = fs_2, fs_jpim1   ! vector opt.
123                  zlu(ji,jj) = - ( zuf(ji,jj) - zuf(ji,jj-1) ) / ( e2u(ji,jj) * fse3u(ji,jj,jk) )   &
124                     &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj,jk) ) / e1u(ji,jj)
125   
126                  zlv(ji,jj) = + ( zuf(ji,jj) - zuf(ji-1,jj) ) / ( e1v(ji,jj) * fse3v(ji,jj,jk) )   &
127                     &         + ( hdivb(ji,jj+1,jk) - hdivb(ji,jj,jk) ) / e2v(ji,jj)
128               END DO
129            END DO
130         ELSE                            ! z-coordinate
131            DO jj = 2, jpjm1
132               DO ji = fs_2, fs_jpim1   ! vector opt.
133                  zlu(ji,jj) = - ( rotb (ji  ,jj,jk) - rotb (ji,jj-1,jk) ) / e2u(ji,jj)   &
134                     &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj  ,jk) ) / e1u(ji,jj)
135   
136                  zlv(ji,jj) = + ( rotb (ji,jj  ,jk) - rotb (ji-1,jj,jk) ) / e1v(ji,jj)   &
137                     &         + ( hdivb(ji,jj+1,jk) - hdivb(ji  ,jj,jk) ) / e2v(ji,jj)
138               END DO 
139            END DO 
140         ENDIF
141
142         ! Boundary conditions on the laplacian  (zlu,zlv)
143         CALL lbc_lnk( zlu, 'U', -1. )
144         CALL lbc_lnk( zlv, 'V', -1. )
145         
146         
147         ! Third derivative
148         ! ----------------
149         
150         ! Multiply by the eddy viscosity coef. (at u- and v-points)
151         zlu(:,:) = zlu(:,:) * fsahmu(:,:,jk)
152         zlv(:,:) = zlv(:,:) * fsahmv(:,:,jk)
153         
154         ! Contravariant "laplacian"
155         zcu(:,:) = e1u(:,:) * zlu(:,:)
156         zcv(:,:) = e2v(:,:) * zlv(:,:)
157         
158         ! Laplacian curl ( * e3f if s-coordinates or z-coordinate with partial steps)
159         DO jj = 1, jpjm1
160            DO ji = 1, fs_jpim1   ! vector opt.
161               zuf(ji,jj) = fmask(ji,jj,jk) * (  zcv(ji+1,jj  ) - zcv(ji,jj)      &
162                  &                            - zcu(ji  ,jj+1) + zcu(ji,jj)  )   &
163#if defined key_s_coord || defined key_partial_steps
164                  &       * fse3f(ji,jj,jk) / ( e1f(ji,jj)*e2f(ji,jj) )
165#else
166                  &                         / ( e1f(ji,jj)*e2f(ji,jj) )
167#endif
168            END DO 
169         END DO 
170
171         ! Laplacian Horizontal fluxes
172         DO jj = 1, jpjm1
173            DO ji = 1, fs_jpim1   ! vector opt.
174#if defined key_s_coord || defined key_partial_steps
175               zlu(ji,jj) = e2u(ji,jj) * fse3u(ji,jj,jk) * zlu(ji,jj)
176               zlv(ji,jj) = e1v(ji,jj) * fse3v(ji,jj,jk) * zlv(ji,jj)
177#else
178               zlu(ji,jj) = e2u(ji,jj) * zlu(ji,jj)
179               zlv(ji,jj) = e1v(ji,jj) * zlv(ji,jj)
180#endif
181            END DO
182         END DO
183
184         ! Laplacian divergence
185         DO jj = 2, jpj
186            DO ji = fs_2, jpi   ! vector opt.
187#if defined key_s_coord || defined key_partial_steps
188               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk)
189#else
190               zbt = e1t(ji,jj) * e2t(ji,jj)
191#endif
192               zut(ji,jj) = (  zlu(ji,jj) - zlu(ji-1,jj  )   &
193                  &          + zlv(ji,jj) - zlv(ji  ,jj-1)  ) / zbt
194            END DO
195         END DO
196
197
198      ! boundary conditions on the laplacian curl and div (zuf,zut)
199      CALL lbc_lnk( zuf, 'F', 1. )
200      CALL lbc_lnk( zut, 'T', 1. )
201
202         
203         ! Bilaplacian
204         ! -----------
205
206         DO jj = 2, jpjm1
207            DO ji = fs_2, fs_jpim1   ! vector opt.
208#if defined key_s_coord || defined key_partial_steps
209               ze2u = e2u(ji,jj) * fse3u(ji,jj,jk)
210               ze2v = e1v(ji,jj) * fse3v(ji,jj,jk)
211#else
212               ze2u = e2u(ji,jj)
213               ze2v = e1v(ji,jj)
214#endif
215               ! horizontal biharmonic diffusive trends
216               zua = - ( zuf(ji  ,jj) - zuf(ji,jj-1) ) / ze2u   &
217                  &  + ( zut(ji+1,jj) - zut(ji,jj  ) ) / e1u(ji,jj)
218
219               zva = + ( zuf(ji,jj  ) - zuf(ji-1,jj) ) / ze2v   &
220                  &  + ( zut(ji,jj+1) - zut(ji  ,jj) ) / e2v(ji,jj)
221               ! add it to the general momentum trends
222               ua(ji,jj,jk) = ua(ji,jj,jk) + zua
223               va(ji,jj,jk) = va(ji,jj,jk) + zva
224            END DO
225         END DO
226
227         !                                             ! ===============
228      END DO                                           !   End of slab
229      !                                                ! ===============
230      ! save the lateral diffusion trends for diagnostic
231      ! momentum trends
232      IF( l_trddyn )   THEN
233         ztdua(:,:,:) = ua(:,:,:) - ztdua(:,:,:)
234         ztdva(:,:,:) = va(:,:,:) - ztdva(:,:,:)
235
236         CALL trd_mod(ztdua, ztdva, jpdtdldf, 'DYN', kt)
237      ENDIF
238
239      IF(l_ctl) THEN         ! print sum trends (used for debugging)
240         zua = SUM( ua(2:nictl,2:njctl,1:jpkm1) * umask(2:nictl,2:njctl,1:jpkm1) )
241         zva = SUM( va(2:nictl,2:njctl,1:jpkm1) * vmask(2:nictl,2:njctl,1:jpkm1) )
242         WRITE(numout,*) ' ldf  - Ua: ', zua-u_ctl, ' Va: ', zva-v_ctl
243         u_ctl = zua   ;   v_ctl = zva
244      ENDIF
245
246   END SUBROUTINE dyn_ldf_bilap
247
248   !!======================================================================
249END MODULE dynldf_bilap
Note: See TracBrowser for help on using the repository browser.