1 | MODULE albedo |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE albedo *** |
---|
4 | !! Ocean forcing: bulk thermohaline forcing of the ocean (or ice) |
---|
5 | !!===================================================================== |
---|
6 | !! History : 8.0 ! 01-04 (LIM 1.0) |
---|
7 | !! 8.5 ! 03-07 (C. Ethe, G. Madec) Optimization (old name:shine) |
---|
8 | !! 9.0 ! 04-11 (C. Talandier) add albedo_init |
---|
9 | !! - ! 01-06 (M. Vancoppenolle) LIM 3.0 |
---|
10 | !! - ! 06-08 (G. Madec) cleaning for surface module |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! albedo_ice : albedo for ice (clear and overcast skies) |
---|
13 | !! albedo_oce : albedo for ocean (clear and overcast skies) |
---|
14 | !! albedo_init : initialisation of albedo computation |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | USE phycst ! physical constants |
---|
17 | USE in_out_manager ! I/O manager |
---|
18 | |
---|
19 | IMPLICIT NONE |
---|
20 | PRIVATE |
---|
21 | |
---|
22 | PUBLIC albedo_ice ! routine called sbcice_lim.F90 |
---|
23 | PUBLIC albedo_oce ! routine called by ??? |
---|
24 | |
---|
25 | INTEGER :: albd_init = 0 !: control flag for initialization |
---|
26 | REAL(wp) :: zzero = 0.e0 ! constant values |
---|
27 | REAL(wp) :: zone = 1.e0 ! " " |
---|
28 | |
---|
29 | REAL(wp) :: c1 = 0.05 ! constants values |
---|
30 | REAL(wp) :: c2 = 0.10 ! " " |
---|
31 | REAL(wp) :: rmue = 0.40 ! cosine of local solar altitude |
---|
32 | |
---|
33 | !!* namelist namalb |
---|
34 | REAL(wp) :: & |
---|
35 | cgren = 0.06 , & ! cloudiness effect on snow or ice albedo (Grenfell & Perovich, 1984) |
---|
36 | #if defined key_lim3 |
---|
37 | albice = 0.53 , & ! albedo of melting ice in the arctic and antarctic (Shine & Hendersson-Sellers) |
---|
38 | #else |
---|
39 | albice = 0.50 , & ! albedo of melting ice in the arctic and antarctic (Shine & Hendersson-Sellers) |
---|
40 | #endif |
---|
41 | alphd = 0.80 , & ! coefficients for linear interpolation used to compute |
---|
42 | alphdi = 0.72 , & ! albedo between two extremes values (Pyane, 1972) |
---|
43 | alphc = 0.65 |
---|
44 | |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | !! OPA 9.0 , LOCEAN-IPSL (2006) |
---|
47 | !! $Id$ |
---|
48 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
49 | !!---------------------------------------------------------------------- |
---|
50 | |
---|
51 | CONTAINS |
---|
52 | |
---|
53 | SUBROUTINE albedo_ice( pt_ice, ph_ice, ph_snw, pa_ice_cs, pa_ice_os ) |
---|
54 | !!---------------------------------------------------------------------- |
---|
55 | !! *** ROUTINE albedo_ice *** |
---|
56 | !! |
---|
57 | !! ** Purpose : Computation of the albedo of the snow/ice system |
---|
58 | !! as well as the ocean one |
---|
59 | !! |
---|
60 | !! ** Method : - Computation of the albedo of snow or ice (choose the |
---|
61 | !! rignt one by a large number of tests |
---|
62 | !! - Computation of the albedo of the ocean |
---|
63 | !! |
---|
64 | !! References : Shine and Hendersson-Sellers 1985, JGR, 90(D1), 2243-2250. |
---|
65 | !!---------------------------------------------------------------------- |
---|
66 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: pt_ice ! ice surface temperature |
---|
67 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_ice ! sea-ice thickness |
---|
68 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_snw ! snow thickness |
---|
69 | REAL(wp), INTENT( out), DIMENSION(:,:,:) :: pa_ice_cs ! albedo of ice under clear sky |
---|
70 | REAL(wp), INTENT( out), DIMENSION(:,:,:) :: pa_ice_os ! albedo of ice under overcast sky |
---|
71 | !! |
---|
72 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
73 | INTEGER :: ijpl ! number of ice categories (3rd dim of ice input arrays) |
---|
74 | REAL(wp) :: zalbpsnm ! albedo of ice under clear sky when snow is melting |
---|
75 | REAL(wp) :: zalbpsnf ! albedo of ice under clear sky when snow is freezing |
---|
76 | REAL(wp) :: zalbpsn ! albedo of snow/ice system when ice is coverd by snow |
---|
77 | REAL(wp) :: zalbpic ! albedo of snow/ice system when ice is free of snow |
---|
78 | REAL(wp) :: zithsn ! = 1 for hsn >= 0 ( ice is cov. by snow ) ; = 0 otherwise (ice is free of snow) |
---|
79 | REAL(wp) :: zitmlsn ! = 1 freezinz snow (pt_ice >=rt0_snow) ; = 0 melting snow (pt_ice<rt0_snow) |
---|
80 | REAL(wp) :: zihsc1 ! = 1 hsn <= c1 ; = 0 hsn > c1 |
---|
81 | REAL(wp) :: zihsc2 ! = 1 hsn >= c2 ; = 0 hsn < c2 |
---|
82 | !! |
---|
83 | LOGICAL , DIMENSION(jpi,jpj,SIZE(pt_ice,3)) :: llmask |
---|
84 | REAL(wp), DIMENSION(jpi,jpj,SIZE(pt_ice,3)) :: zalbfz ! = alphdi for freezing ice ; = albice for melting ice |
---|
85 | REAL(wp), DIMENSION(jpi,jpj,SIZE(pt_ice,3)) :: zficeth ! function of ice thickness |
---|
86 | !!--------------------------------------------------------------------- |
---|
87 | |
---|
88 | ijpl = SIZE( pt_ice, 3 ) ! number of ice categories |
---|
89 | |
---|
90 | IF( albd_init == 0 ) CALL albedo_init ! initialization |
---|
91 | |
---|
92 | !--------------------------- |
---|
93 | ! Computation of zficeth |
---|
94 | !--------------------------- |
---|
95 | llmask = ( ph_snw == 0.e0 ) .AND. ( pt_ice >= rt0_ice ) |
---|
96 | ! ice free of snow and melts |
---|
97 | WHERE( llmask ) ; zalbfz = albice |
---|
98 | ELSEWHERE ; zalbfz = alphdi |
---|
99 | END WHERE |
---|
100 | |
---|
101 | DO jl = 1, ijpl |
---|
102 | DO jj = 1, jpj |
---|
103 | DO ji = 1, jpi |
---|
104 | IF( ph_ice(ji,jj,jl) > 1.5 ) THEN |
---|
105 | zficeth(ji,jj,jl) = zalbfz(ji,jj,jl) |
---|
106 | ELSEIF( ph_ice(ji,jj,jl) > 1.0 .AND. ph_ice(ji,jj,jl) <= 1.5 ) THEN |
---|
107 | zficeth(ji,jj,jl) = 0.472 + 2.0 * ( zalbfz(ji,jj,jl) - 0.472 ) * ( ph_ice(ji,jj,jl) - 1.0 ) |
---|
108 | ELSEIF( ph_ice(ji,jj,jl) > 0.05 .AND. ph_ice(ji,jj,jl) <= 1.0 ) THEN |
---|
109 | zficeth(ji,jj,jl) = 0.2467 + 0.7049 * ph_ice(ji,jj,jl) & |
---|
110 | & - 0.8608 * ph_ice(ji,jj,jl) * ph_ice(ji,jj,jl) & |
---|
111 | & + 0.3812 * ph_ice(ji,jj,jl) * ph_ice(ji,jj,jl) * ph_ice (ji,jj,jl) |
---|
112 | ELSE |
---|
113 | zficeth(ji,jj,jl) = 0.1 + 3.6 * ph_ice(ji,jj,jl) |
---|
114 | ENDIF |
---|
115 | END DO |
---|
116 | END DO |
---|
117 | END DO |
---|
118 | |
---|
119 | !----------------------------------------------- |
---|
120 | ! Computation of the snow/ice albedo system |
---|
121 | !-------------------------- --------------------- |
---|
122 | |
---|
123 | ! Albedo of snow-ice for clear sky. |
---|
124 | !----------------------------------------------- |
---|
125 | DO jl = 1, ijpl |
---|
126 | DO jj = 1, jpj |
---|
127 | DO ji = 1, jpi |
---|
128 | ! Case of ice covered by snow. |
---|
129 | ! ! freezing snow |
---|
130 | zihsc1 = 1.0 - MAX( zzero , SIGN( zone , - ( ph_snw(ji,jj,jl) - c1 ) ) ) |
---|
131 | zalbpsnf = ( 1.0 - zihsc1 ) * ( zficeth(ji,jj,jl) & |
---|
132 | & + ph_snw(ji,jj,jl) * ( alphd - zficeth(ji,jj,jl) ) / c1 ) & |
---|
133 | & + zihsc1 * alphd |
---|
134 | ! ! melting snow |
---|
135 | zihsc2 = MAX( zzero , SIGN( zone , ph_snw(ji,jj,jl) - c2 ) ) |
---|
136 | zalbpsnm = ( 1.0 - zihsc2 ) * ( albice + ph_snw(ji,jj,jl) * ( alphc - albice ) / c2 ) & |
---|
137 | & + zihsc2 * alphc |
---|
138 | ! |
---|
139 | zitmlsn = MAX( zzero , SIGN( zone , pt_ice(ji,jj,jl) - rt0_snow ) ) |
---|
140 | zalbpsn = zitmlsn * zalbpsnm + ( 1.0 - zitmlsn ) * zalbpsnf |
---|
141 | |
---|
142 | ! Case of ice free of snow. |
---|
143 | zalbpic = zficeth(ji,jj,jl) |
---|
144 | |
---|
145 | ! albedo of the system |
---|
146 | zithsn = 1.0 - MAX( zzero , SIGN( zone , - ph_snw(ji,jj,jl) ) ) |
---|
147 | pa_ice_cs(ji,jj,jl) = zithsn * zalbpsn + ( 1.0 - zithsn ) * zalbpic |
---|
148 | END DO |
---|
149 | END DO |
---|
150 | END DO |
---|
151 | |
---|
152 | ! Albedo of snow-ice for overcast sky. |
---|
153 | !---------------------------------------------- |
---|
154 | pa_ice_os(:,:,:) = pa_ice_cs(:,:,:) + cgren ! Oberhuber correction |
---|
155 | ! |
---|
156 | END SUBROUTINE albedo_ice |
---|
157 | |
---|
158 | |
---|
159 | SUBROUTINE albedo_oce( pa_oce_os , pa_oce_cs ) |
---|
160 | !!---------------------------------------------------------------------- |
---|
161 | !! *** ROUTINE albedo_oce *** |
---|
162 | !! |
---|
163 | !! ** Purpose : Computation of the albedo of the ocean |
---|
164 | !! |
---|
165 | !! ** Method : .... |
---|
166 | !!---------------------------------------------------------------------- |
---|
167 | REAL(wp), DIMENSION(jpi,jpj), INTENT(out) :: pa_oce_os ! albedo of ocean under overcast sky |
---|
168 | REAL(wp), DIMENSION(jpi,jpj), INTENT(out) :: pa_oce_cs ! albedo of ocean under clear sky |
---|
169 | !! |
---|
170 | REAL(wp) :: zcoef ! temporary scalar |
---|
171 | !!---------------------------------------------------------------------- |
---|
172 | ! |
---|
173 | zcoef = 0.05 / ( 1.1 * rmue**1.4 + 0.15 ) ! Parameterization of Briegled and Ramanathan, 1982 |
---|
174 | pa_oce_cs(:,:) = zcoef |
---|
175 | pa_oce_os(:,:) = 0.06 ! Parameterization of Kondratyev, 1969 and Payne, 1972 |
---|
176 | ! |
---|
177 | END SUBROUTINE albedo_oce |
---|
178 | |
---|
179 | |
---|
180 | SUBROUTINE albedo_init |
---|
181 | !!---------------------------------------------------------------------- |
---|
182 | !! *** ROUTINE albedo_init *** |
---|
183 | !! |
---|
184 | !! ** Purpose : initializations for the albedo parameters |
---|
185 | !! |
---|
186 | !! ** Method : Read the namelist namalb |
---|
187 | !!---------------------------------------------------------------------- |
---|
188 | NAMELIST/namalb/ cgren, albice, alphd, alphdi, alphc |
---|
189 | !!---------------------------------------------------------------------- |
---|
190 | |
---|
191 | ! set the initialization flag to 1 |
---|
192 | albd_init = 1 ! indicate that the initialization has been done |
---|
193 | |
---|
194 | ! Read Namelist namalb : albedo parameters |
---|
195 | REWIND( numnam ) |
---|
196 | READ ( numnam, namalb ) |
---|
197 | |
---|
198 | IF(lwp) THEN ! Control print |
---|
199 | WRITE(numout,*) |
---|
200 | WRITE(numout,*) 'albedo_init : set albedo parameters from namelist namalb' |
---|
201 | WRITE(numout,*) '~~~~~~~~~~~' |
---|
202 | WRITE(numout,*) ' correction for snow and ice albedo cgren = ', cgren |
---|
203 | WRITE(numout,*) ' albedo of melting ice in the arctic and antarctic albice = ', albice |
---|
204 | WRITE(numout,*) ' coefficients for linear alphd = ', alphd |
---|
205 | WRITE(numout,*) ' interpolation used to compute albedo alphdi = ', alphdi |
---|
206 | WRITE(numout,*) ' between two extremes values (Pyane, 1972) alphc = ', alphc |
---|
207 | ENDIF |
---|
208 | ! |
---|
209 | END SUBROUTINE albedo_init |
---|
210 | |
---|
211 | !!====================================================================== |
---|
212 | END MODULE albedo |
---|