New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcblk_core.F90 in trunk/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMO/OPA_SRC/SBC/sbcblk_core.F90 @ 1695

Last change on this file since 1695 was 1695, checked in by smasson, 14 years ago

wind stress module directly at T-point, see ticket:577
  • Property svn:keywords set to Id
File size: 45.6 KB
Line 
1MODULE sbcblk_core
2   !!======================================================================
3   !!                       ***  MODULE  sbcblk_core  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  1.0  !  2004-08  (U. Schweckendiek)  Original code
7   !!            2.0  !  2005-04  (L. Brodeau, A.M. Treguier) additions:
8   !!                           -  new bulk routine for efficiency
9   !!                           -  WINDS ARE NOW ASSUMED TO BE AT T POINTS in input files !!!!
10   !!                           -  file names and file characteristics in namelist
11   !!                           -  Implement reading of 6-hourly fields   
12   !!            3.0  !  2006-06  (G. Madec) sbc rewritting   
13   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   sbc_blk_core  : bulk formulation as ocean surface boundary condition
18   !!                   (forced mode, CORE bulk formulea)
19   !!   blk_oce_core  : ocean: computes momentum, heat and freshwater fluxes
20   !!   blk_ice_core  : ice  : computes momentum, heat and freshwater fluxes
21   !!   turb_core     : computes the CORE turbulent transfer coefficients
22   !!----------------------------------------------------------------------
23   USE oce             ! ocean dynamics and tracers
24   USE dom_oce         ! ocean space and time domain
25   USE phycst          ! physical constants
26   USE daymod          ! calendar
27   USE fldread         ! read input fields
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE iom             ! I/O manager library
30   USE in_out_manager  ! I/O manager
31   USE lib_mpp         ! distribued memory computing library
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33   USE prtctl          ! Print control
34#if defined key_lim3
35   USE sbc_ice         ! Surface boundary condition: ice fields
36#endif
37
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   sbc_blk_core       ! routine called in sbcmod module
43   PUBLIC   blk_ice_core       ! routine called in sbc_ice_lim module
44     
45   INTEGER , PARAMETER ::   jpfld   = 8           ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_wndi = 1           ! index of 10m wind velocity (i-component) (m/s)    at T-point
47   INTEGER , PARAMETER ::   jp_wndj = 2           ! index of 10m wind velocity (j-component) (m/s)    at T-point
48   INTEGER , PARAMETER ::   jp_humi = 3           ! index of specific humidity               ( - )
49   INTEGER , PARAMETER ::   jp_qsr  = 4           ! index of solar heat                      (W/m2)
50   INTEGER , PARAMETER ::   jp_qlw  = 5           ! index of Long wave                       (W/m2)
51   INTEGER , PARAMETER ::   jp_tair = 6           ! index of 10m air temperature             (Kelvin)
52   INTEGER , PARAMETER ::   jp_prec = 7           ! index of total precipitation (rain+snow) (Kg/m2/s)
53   INTEGER , PARAMETER ::   jp_snow = 8           ! index of snow (solid prcipitation)       (kg/m2/s)
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf   ! structure of input fields (file informations, fields read)
55         
56   !                                             !!! CORE bulk parameters
57   REAL(wp), PARAMETER ::   rhoa =    1.22        ! air density
58   REAL(wp), PARAMETER ::   cpa  = 1000.5         ! specific heat of air
59   REAL(wp), PARAMETER ::   Lv   =    2.5e6       ! latent heat of vaporization
60   REAL(wp), PARAMETER ::   Ls   =    2.839e6     ! latent heat of sublimation
61   REAL(wp), PARAMETER ::   Stef =    5.67e-8     ! Stefan Boltzmann constant
62   REAL(wp), PARAMETER ::   Cice =    1.63e-3     ! transfer coefficient over ice
63
64   !                                !!* Namelist namsbc_core : CORE bulk parameters
65   LOGICAL  ::   ln_2m = .FALSE.     ! logical flag for height of air temp. and hum
66   REAL(wp) ::   rn_pfac = 1.        ! multiplication factor for precipitation
67
68   !! * Substitutions
69#  include "domzgr_substitute.h90"
70#  include "vectopt_loop_substitute.h90"
71   !!----------------------------------------------------------------------
72   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
73   !! $Id$
74   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
75   !!----------------------------------------------------------------------
76
77CONTAINS
78
79   SUBROUTINE sbc_blk_core( kt )
80      !!---------------------------------------------------------------------
81      !!                    ***  ROUTINE sbc_blk_core  ***
82      !!                   
83      !! ** Purpose :   provide at each time step the surface ocean fluxes
84      !!      (momentum, heat, freshwater and runoff)
85      !!
86      !! ** Method  : (1) READ each fluxes in NetCDF files:
87      !!      the 10m wind velocity (i-component) (m/s)    at T-point
88      !!      the 10m wind velocity (j-component) (m/s)    at T-point
89      !!      the specific humidity               ( - )
90      !!      the solar heat                      (W/m2)
91      !!      the Long wave                       (W/m2)
92      !!      the 10m air temperature             (Kelvin)
93      !!      the total precipitation (rain+snow) (Kg/m2/s)
94      !!      the snow (solid prcipitation)       (kg/m2/s)
95      !!              (2) CALL blk_oce_core
96      !!
97      !!      C A U T I O N : never mask the surface stress fields
98      !!                      the stress is assumed to be in the mesh referential
99      !!                      i.e. the (i,j) referential
100      !!
101      !! ** Action  :   defined at each time-step at the air-sea interface
102      !!              - utau, vtau  i- and j-component of the wind stress
103      !!              - taum        wind stress module at T-point
104      !!              - wndm        10m wind module at T-point
105      !!              - qns, qsr    non-slor and solar heat flux
106      !!              - emp, emps   evaporation minus precipitation
107      !!----------------------------------------------------------------------
108      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
109      !!
110      INTEGER  ::   ierror   ! return error code
111      INTEGER  ::   ifpr     ! dummy loop indice
112      !!
113      CHARACTER(len=100) ::  cn_dir   !   Root directory for location of core files
114      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i     ! array of namelist informations on the fields to read
115      TYPE(FLD_N) ::   sn_wndi, sn_wndj, sn_humi, sn_qsr       ! informations about the fields to be read
116      TYPE(FLD_N) ::   sn_qlw , sn_tair, sn_prec, sn_snow      !   "                                 "
117      NAMELIST/namsbc_core/ cn_dir, ln_2m, rn_pfac, sn_wndi, sn_wndj, sn_humi, sn_qsr,   &
118         &                                                sn_qlw , sn_tair, sn_prec, sn_snow
119      !!---------------------------------------------------------------------
120
121      !                                         ! ====================== !
122      IF( kt == nit000 ) THEN                   !  First call kt=nit000  !
123         !                                      ! ====================== !
124         ! set file information (default values)
125         cn_dir = './'       ! directory in which the model is executed
126         !
127         ! (NB: frequency positive => hours, negative => months)
128         !            !    file     ! frequency !  variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation   !
129         !            !    name     !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs      !
130         sn_wndi = FLD_N( 'uwnd10m' ,    24.    ,  'u_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
131         sn_wndj = FLD_N( 'vwnd10m' ,    24.    ,  'v_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
132         sn_qsr  = FLD_N( 'qsw'     ,    24.    ,  'qsw'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
133         sn_qlw  = FLD_N( 'qlw'     ,    24.    ,  'qlw'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
134         sn_tair = FLD_N( 'tair10m' ,    24.    ,  't_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
135         sn_humi = FLD_N( 'humi10m' ,    24.    ,  'q_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
136         sn_prec = FLD_N( 'precip'  ,    -1.    ,  'precip'  ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
137         sn_snow = FLD_N( 'snow'    ,    -1.    ,  'snow'    ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
138         !
139         REWIND( numnam )                    ! ... read in namlist namsbc_core
140         READ  ( numnam, namsbc_core )
141         !
142         ! store namelist information in an array
143         slf_i(jp_wndi) = sn_wndi   ;   slf_i(jp_wndj) = sn_wndj
144         slf_i(jp_qsr ) = sn_qsr    ;   slf_i(jp_qlw ) = sn_qlw
145         slf_i(jp_tair) = sn_tair   ;   slf_i(jp_humi) = sn_humi
146         slf_i(jp_prec) = sn_prec   ;   slf_i(jp_snow) = sn_snow
147         !
148         ! set sf structure
149         ALLOCATE( sf(jpfld), STAT=ierror )
150         IF( ierror > 0 ) THEN
151            CALL ctl_stop( 'sbc_blk_core: unable to allocate sf structure' )   ;   RETURN
152         ENDIF
153         DO ifpr= 1, jpfld
154            ALLOCATE( sf(ifpr)%fnow(jpi,jpj) )
155            ALLOCATE( sf(ifpr)%fdta(jpi,jpj,2) )
156         END DO
157         !
158         ! fill sf with slf_i and control print
159         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_blk_core', 'flux formulattion for ocean surface boundary condition', 'namsbc_core' )
160         !
161      ENDIF
162
163      CALL fld_read( kt, nn_fsbc, sf )                   ! input fields provided at the current time-step
164
165#if defined key_lim3
166      tatm_ice(:,:) = sf(jp_tair)%fnow(:,:)
167#endif
168
169      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
170          CALL blk_oce_core( sf, sst_m, ssu_m, ssv_m )   ! compute the surface ocean fluxes using CLIO bulk formulea
171      ENDIF
172      !                                                  ! using CORE bulk formulea
173   END SUBROUTINE sbc_blk_core
174   
175   
176   SUBROUTINE blk_oce_core( sf, pst, pu, pv )
177      !!---------------------------------------------------------------------
178      !!                     ***  ROUTINE blk_core  ***
179      !!
180      !! ** Purpose :   provide the momentum, heat and freshwater fluxes at
181      !!      the ocean surface at each time step
182      !!
183      !! ** Method  :   CORE bulk formulea for the ocean using atmospheric
184      !!      fields read in sbc_read
185      !!
186      !! ** Outputs : - utau    : i-component of the stress at U-point  (N/m2)
187      !!              - vtau    : j-component of the stress at V-point  (N/m2)
188      !!              - taum    : Wind stress module at T-point         (N/m2)
189      !!              - wndm    : Wind speed module at T-point          (m/s)
190      !!              - qsr     : Solar heat flux over the ocean        (W/m2)
191      !!              - qns     : Non Solar heat flux over the ocean    (W/m2)
192      !!              - evap    : Evaporation over the ocean            (kg/m2/s)
193      !!              - emp(s)  : evaporation minus precipitation       (kg/m2/s)
194      !!
195      !!  ** Nota  :   sf has to be a dummy argument for AGRIF on NEC
196      !!---------------------------------------------------------------------
197      TYPE(fld), INTENT(in), DIMENSION(:)       ::   sf    ! input data
198      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pst   ! surface temperature                      [Celcius]
199      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pu    ! surface current at U-point (i-component) [m/s]
200      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pv    ! surface current at V-point (j-component) [m/s]
201
202      INTEGER  ::   ji, jj     ! dummy loop indices
203      REAL(wp) ::   zcoef_qsatw
204      REAL(wp) ::   zztmp                                 ! temporary variable
205      REAL(wp), DIMENSION(jpi,jpj) ::   zwnd_i, zwnd_j    ! wind speed components at T-point
206      REAL(wp), DIMENSION(jpi,jpj) ::   zqsatw            ! specific humidity at pst
207      REAL(wp), DIMENSION(jpi,jpj) ::   zqlw, zqsb        ! long wave and sensible heat fluxes
208      REAL(wp), DIMENSION(jpi,jpj) ::   zqla, zevap       ! latent heat fluxes and evaporation
209      REAL(wp), DIMENSION(jpi,jpj) ::   Cd                ! transfer coefficient for momentum      (tau)
210      REAL(wp), DIMENSION(jpi,jpj) ::   Ch                ! transfer coefficient for sensible heat (Q_sens)
211      REAL(wp), DIMENSION(jpi,jpj) ::   Ce                ! tansfert coefficient for evaporation   (Q_lat)
212      REAL(wp), DIMENSION(jpi,jpj) ::   zst               ! surface temperature in Kelvin
213      REAL(wp), DIMENSION(jpi,jpj) ::   zt_zu             ! air temperature at wind speed height
214      REAL(wp), DIMENSION(jpi,jpj) ::   zq_zu             ! air spec. hum.  at wind speed height
215      !!---------------------------------------------------------------------
216
217      ! local scalars ( place there for vector optimisation purposes)
218      zcoef_qsatw = 0.98 * 640380. / rhoa
219     
220      zst(:,:) = pst(:,:) + rt0      ! converte Celcius to Kelvin (and set minimum value far above 0 K)
221
222      ! ----------------------------------------------------------------------------- !
223      !      0   Wind components and module at T-point relative to the moving ocean   !
224      ! ----------------------------------------------------------------------------- !
225
226      ! ... components ( U10m - U_oce ) at T-point (unmasked)
227      zwnd_i(:,:) = 0.e0 
228      zwnd_j(:,:) = 0.e0
229#if defined key_vectopt_loop
230!CDIR COLLAPSE
231#endif
232      DO jj = 2, jpjm1
233         DO ji = fs_2, fs_jpim1   ! vect. opt.
234            zwnd_i(ji,jj) = (  sf(jp_wndi)%fnow(ji,jj) - 0.5 * ( pu(ji-1,jj  ) + pu(ji,jj) )  )
235            zwnd_j(ji,jj) = (  sf(jp_wndj)%fnow(ji,jj) - 0.5 * ( pv(ji  ,jj-1) + pv(ji,jj) )  )
236         END DO
237      END DO
238      CALL lbc_lnk( zwnd_i(:,:) , 'T', -1. )
239      CALL lbc_lnk( zwnd_j(:,:) , 'T', -1. )
240      ! ... scalar wind ( = | U10m - U_oce | ) at T-point (masked)
241!CDIR NOVERRCHK
242!CDIR COLLAPSE
243      wndm(:,:) = SQRT(  zwnd_i(:,:) * zwnd_i(:,:)   &
244         &             + zwnd_j(:,:) * zwnd_j(:,:)  ) * tmask(:,:,1)
245
246      ! ----------------------------------------------------------------------------- !
247      !      I   Radiative FLUXES                                                     !
248      ! ----------------------------------------------------------------------------- !
249   
250      ! ocean albedo assumed to be 0.066
251!CDIR COLLAPSE
252      qsr (:,:) = ( 1. - 0.066 ) * sf(jp_qsr)%fnow(:,:) * tmask(:,:,1)                                 ! Short Wave
253!CDIR COLLAPSE
254      zqlw(:,:) = (  sf(jp_qlw)%fnow(:,:) - Stef * zst(:,:)*zst(:,:)*zst(:,:)*zst(:,:)  ) * tmask(:,:,1)   ! Long  Wave
255                     
256      ! ----------------------------------------------------------------------------- !
257      !     II    Turbulent FLUXES                                                    !
258      ! ----------------------------------------------------------------------------- !
259
260      ! ... specific humidity at SST and IST
261!CDIR NOVERRCHK
262!CDIR COLLAPSE
263      zqsatw(:,:) = zcoef_qsatw * EXP( -5107.4 / zst(:,:) ) 
264
265      ! ... NCAR Bulk formulae, computation of Cd, Ch, Ce at T-point :
266      IF( ln_2m ) THEN
267         !! If air temp. and spec. hum. are given at different height (2m) than wind (10m) :
268         CALL TURB_CORE_2Z(2.,10., zst   , sf(jp_tair)%fnow,         &
269            &                      zqsatw, sf(jp_humi)%fnow, wndm,   &
270            &                      Cd    , Ch              , Ce  ,   &
271            &                      zt_zu , zq_zu                   )
272      ELSE
273         !! If air temp. and spec. hum. are given at same height than wind (10m) :
274!gm bug?  at the compiling phase, add a copy in temporary arrays...  ==> check perf
275!         CALL TURB_CORE_1Z( 10., zst   (:,:), sf(jp_tair)%fnow(:,:),              &
276!            &                    zqsatw(:,:), sf(jp_humi)%fnow(:,:), wndm(:,:),   &
277!            &                    Cd    (:,:),             Ch  (:,:), Ce  (:,:)  )
278!gm bug
279         CALL TURB_CORE_1Z( 10., zst   , sf(jp_tair)%fnow,         &
280            &                    zqsatw, sf(jp_humi)%fnow, wndm,   &
281            &                    Cd    , Ch              , Ce    )
282      ENDIF
283
284      ! ... tau module, i and j component
285      DO jj = 1, jpj
286         DO ji = 1, jpi
287            zztmp = rhoa * wndm(ji,jj) * Cd(ji,jj)
288            taum  (ji,jj) = zztmp * wndm  (ji,jj)
289            zwnd_i(ji,jj) = zztmp * zwnd_i(ji,jj)
290            zwnd_j(ji,jj) = zztmp * zwnd_j(ji,jj)
291         END DO
292      END DO
293      ! ... utau, vtau at U- and V_points, resp.
294      !     Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines
295      DO jj = 1, jpjm1
296         DO ji = 1, fs_jpim1
297            utau(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zwnd_i(ji,jj) + zwnd_i(ji+1,jj  ) )
298            vtau(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zwnd_j(ji,jj) + zwnd_j(ji  ,jj+1) )
299         END DO
300      END DO
301      CALL lbc_lnk( utau(:,:), 'U', -1. )
302      CALL lbc_lnk( vtau(:,:), 'V', -1. )
303
304      !  Turbulent fluxes over ocean
305      ! -----------------------------
306      IF( ln_2m ) THEN
307         ! Values of temp. and hum. adjusted to 10m must be used instead of 2m values
308         zevap(:,:) = MAX( 0.e0, rhoa    *Ce(:,:)*( zqsatw(:,:) - zq_zu(:,:) ) * wndm(:,:) )   ! Evaporation
309         zqsb (:,:) =            rhoa*cpa*Ch(:,:)*( zst   (:,:) - zt_zu(:,:) ) * wndm(:,:)     ! Sensible Heat
310      ELSE
311!CDIR COLLAPSE
312         zevap(:,:) = MAX( 0.e0, rhoa    *Ce(:,:)*( zqsatw(:,:) - sf(jp_humi)%fnow(:,:) ) * wndm(:,:) )   ! Evaporation
313!CDIR COLLAPSE
314         zqsb (:,:) =            rhoa*cpa*Ch(:,:)*( zst   (:,:) - sf(jp_tair)%fnow(:,:) ) * wndm(:,:)     ! Sensible Heat
315      ENDIF
316!CDIR COLLAPSE
317      zqla (:,:) = Lv * zevap(:,:)                                                              ! Latent Heat
318
319      IF(ln_ctl) THEN
320         CALL prt_ctl( tab2d_1=zqla  , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=Ce , clinfo2=' Ce  : ' )
321         CALL prt_ctl( tab2d_1=zqsb  , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=Ch , clinfo2=' Ch  : ' )
322         CALL prt_ctl( tab2d_1=zqlw  , clinfo1=' blk_oce_core: zqlw   : ', tab2d_2=qsr, clinfo2=' qsr : ' )
323         CALL prt_ctl( tab2d_1=zqsatw, clinfo1=' blk_oce_core: zqsatw : ', tab2d_2=zst, clinfo2=' zst : ' )
324         CALL prt_ctl( tab2d_1=utau  , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
325            &          tab2d_2=vtau  , clinfo2=              ' vtau : '  , mask2=vmask )
326         CALL prt_ctl( tab2d_1=wndm  , clinfo1=' blk_oce_core: wndm   : ')
327         CALL prt_ctl( tab2d_1=zst   , clinfo1=' blk_oce_core: zst    : ')
328      ENDIF
329       
330      ! ----------------------------------------------------------------------------- !
331      !     III    Total FLUXES                                                       !
332      ! ----------------------------------------------------------------------------- !
333     
334!CDIR COLLAPSE
335      qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:)      ! Downward Non Solar flux
336!CDIR COLLAPSE
337      emp (:,:) = zevap(:,:) - sf(jp_prec)%fnow(:,:) * rn_pfac * tmask(:,:,1)
338!CDIR COLLAPSE
339      emps(:,:) = emp(:,:)
340      !
341      CALL iom_put( "qlw_oce",   zqlw )                 ! output downward longwave heat over the ocean
342      CALL iom_put( "qsb_oce", - zqsb )                 ! output downward sensible heat over the ocean
343      CALL iom_put( "qla_oce", - zqla )                 ! output downward latent   heat over the ocean
344      CALL iom_put( "qns_oce",   qns  )                 ! output downward non solar heat over the ocean
345      !
346      IF(ln_ctl) THEN
347         CALL prt_ctl(tab2d_1=zqsb , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=zqlw , clinfo2=' zqlw  : ')
348         CALL prt_ctl(tab2d_1=zqla , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=qsr  , clinfo2=' qsr   : ')
349         CALL prt_ctl(tab2d_1=pst  , clinfo1=' blk_oce_core: pst    : ', tab2d_2=emp  , clinfo2=' emp   : ')
350         CALL prt_ctl(tab2d_1=utau , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
351            &         tab2d_2=vtau , clinfo2=              ' vtau  : ' , mask2=vmask )
352      ENDIF
353      !
354   END SUBROUTINE blk_oce_core
355   
356   
357   SUBROUTINE blk_ice_core(  pst   , pui   , pvi   , palb ,   &
358      &                      p_taui, p_tauj, p_qns , p_qsr,   &
359      &                      p_qla , p_dqns, p_dqla,          &
360      &                      p_tpr , p_spr ,                  &
361      &                      p_fr1 , p_fr2 , cd_grid, pdim  ) 
362      !!---------------------------------------------------------------------
363      !!                     ***  ROUTINE blk_ice_core  ***
364      !!
365      !! ** Purpose :   provide the surface boundary condition over sea-ice
366      !!
367      !! ** Method  :   compute momentum, heat and freshwater exchanged
368      !!                between atmosphere and sea-ice using CORE bulk
369      !!                formulea, ice variables and read atmmospheric fields.
370      !!                NB: ice drag coefficient is assumed to be a constant
371      !!
372      !! caution : the net upward water flux has with mm/day unit
373      !!---------------------------------------------------------------------
374      REAL(wp), INTENT(in   ), DIMENSION(:,:,:)      ::   pst      ! ice surface temperature (>0, =rt0 over land) [Kelvin]
375      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)    ::   pui      ! ice surface velocity (i- and i- components      [m/s]
376      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)    ::   pvi      !    at I-point (B-grid) or U & V-point (C-grid)
377      REAL(wp), INTENT(in   ), DIMENSION(:,:,:)      ::   palb     ! ice albedo (clear sky) (alb_ice_cs)               [%]
378      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_taui   ! i- & j-components of surface ice stress        [N/m2]
379      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_tauj   !   at I-point (B-grid) or U & V-point (C-grid)
380      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qns    ! non solar heat flux over ice (T-point)         [W/m2]
381      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qsr    !     solar heat flux over ice (T-point)         [W/m2]
382      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qla    ! latent    heat flux over ice (T-point)         [W/m2]
383      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_dqns   ! non solar heat sensistivity  (T-point)         [W/m2]
384      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_dqla   ! latent    heat sensistivity  (T-point)         [W/m2]
385      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_tpr    ! total precipitation          (T-point)      [Kg/m2/s]
386      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_spr    ! solid precipitation          (T-point)      [Kg/m2/s]
387      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_fr1    ! 1sr fraction of qsr penetration in ice (T-point)  [%]
388      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_fr2    ! 2nd fraction of qsr penetration in ice (T-point)  [%]
389      CHARACTER(len=1), INTENT(in   )                ::   cd_grid  ! ice grid ( C or B-grid)
390      INTEGER, INTENT(in   )                         ::   pdim     ! number of ice categories
391      !!
392      INTEGER  ::   ji, jj, jl    ! dummy loop indices
393      INTEGER  ::   ijpl          ! number of ice categories (size of 3rd dim of input arrays)
394      REAL(wp) ::   zst2, zst3
395      REAL(wp) ::   zcoef_wnorm, zcoef_wnorm2, zcoef_dqlw, zcoef_dqla, zcoef_dqsb
396      REAL(wp) ::   zcoef_frca                                   ! fractional cloud amount
397      REAL(wp) ::   zwnorm_f, zwndi_f , zwndj_f                  ! relative wind module and components at F-point
398      REAL(wp) ::             zwndi_t , zwndj_t                  ! relative wind components at T-point
399      REAL(wp), DIMENSION(jpi,jpj) ::   z_wnds_t                 ! wind speed ( = | U10m - U_ice | ) at T-point
400      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_qlw               ! long wave heat flux over ice
401      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_qsb               ! sensible  heat flux over ice
402      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_dqlw              ! long wave heat sensitivity over ice
403      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_dqsb              ! sensible  heat sensitivity over ice
404      !!---------------------------------------------------------------------
405
406      ijpl  = pdim                            ! number of ice categories
407
408      ! local scalars ( place there for vector optimisation purposes)
409      zcoef_wnorm = rhoa * Cice
410      zcoef_wnorm2 = rhoa * Cice * 0.5
411      zcoef_dqlw = 4.0 * 0.95 * Stef
412      zcoef_dqla = -Ls * Cice * 11637800. * (-5897.8)
413      zcoef_dqsb = rhoa * cpa * Cice
414      zcoef_frca = 1.0  - 0.3
415
416!!gm brutal....
417      z_wnds_t(:,:) = 0.e0
418      p_taui  (:,:) = 0.e0
419      p_tauj  (:,:) = 0.e0
420!!gm end
421
422      ! ----------------------------------------------------------------------------- !
423      !    Wind components and module relative to the moving ocean ( U10m - U_ice )   !
424      ! ----------------------------------------------------------------------------- !
425      SELECT CASE( cd_grid )
426      CASE( 'B' )                  ! B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
427         !                           and scalar wind at T-point ( = | U10m - U_ice | ) (masked)
428#if defined key_vectopt_loop
429!CDIR COLLAPSE
430#endif
431!CDIR NOVERRCHK
432         DO jj = 2, jpjm1
433            DO ji = 2, jpim1   ! B grid : no vector opt
434               ! ... scalar wind at I-point (fld being at T-point)
435               zwndi_f = 0.25 * (  sf(jp_wndi)%fnow(ji-1,jj  ) + sf(jp_wndi)%fnow(ji  ,jj  )   &
436                  &              + sf(jp_wndi)%fnow(ji-1,jj-1) + sf(jp_wndi)%fnow(ji  ,jj-1)  ) - pui(ji,jj)
437               zwndj_f = 0.25 * (  sf(jp_wndj)%fnow(ji-1,jj  ) + sf(jp_wndj)%fnow(ji  ,jj  )   &
438                  &              + sf(jp_wndj)%fnow(ji-1,jj-1) + sf(jp_wndj)%fnow(ji  ,jj-1)  ) - pvi(ji,jj)
439               zwnorm_f = zcoef_wnorm * SQRT( zwndi_f * zwndi_f + zwndj_f * zwndj_f )
440               ! ... ice stress at I-point
441               p_taui(ji,jj) = zwnorm_f * zwndi_f
442               p_tauj(ji,jj) = zwnorm_f * zwndj_f
443               ! ... scalar wind at T-point (fld being at T-point)
444               zwndi_t = sf(jp_wndi)%fnow(ji,jj) - 0.25 * (  pui(ji,jj+1) + pui(ji+1,jj+1)   &
445                  &                                        + pui(ji,jj  ) + pui(ji+1,jj  )  )
446               zwndj_t = sf(jp_wndj)%fnow(ji,jj) - 0.25 * (  pvi(ji,jj+1) + pvi(ji+1,jj+1)   &
447                  &                                        + pvi(ji,jj  ) + pvi(ji+1,jj  )  )
448               z_wnds_t(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
449            END DO
450         END DO
451         CALL lbc_lnk( p_taui  , 'I', -1. )
452         CALL lbc_lnk( p_tauj  , 'I', -1. )
453         CALL lbc_lnk( z_wnds_t, 'T',  1. )
454         !
455      CASE( 'C' )                  ! C-grid ice dynamics :   U & V-points (same as ocean)
456#if defined key_vectopt_loop
457!CDIR COLLAPSE
458#endif
459         DO jj = 2, jpj
460            DO ji = fs_2, jpi   ! vect. opt.
461               zwndi_t = (  sf(jp_wndi)%fnow(ji,jj) - 0.5 * ( pui(ji-1,jj  ) + pui(ji,jj) )  )
462               zwndj_t = (  sf(jp_wndj)%fnow(ji,jj) - 0.5 * ( pvi(ji  ,jj-1) + pvi(ji,jj) )  )
463               z_wnds_t(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
464            END DO
465         END DO
466#if defined key_vectopt_loop
467!CDIR COLLAPSE
468#endif
469         DO jj = 2, jpjm1
470            DO ji = fs_2, fs_jpim1   ! vect. opt.
471               p_taui(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji+1,jj) + z_wnds_t(ji,jj) )                          &
472                  &          * ( 0.5 * (sf(jp_wndi)%fnow(ji+1,jj) + sf(jp_wndi)%fnow(ji,jj) ) - pui(ji,jj) )
473               p_tauj(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji,jj+1) + z_wnds_t(ji,jj) )                          &
474                  &          * ( 0.5 * (sf(jp_wndj)%fnow(ji,jj+1) + sf(jp_wndj)%fnow(ji,jj) ) - pvi(ji,jj) )
475            END DO
476         END DO
477         CALL lbc_lnk( p_taui  , 'U', -1. )
478         CALL lbc_lnk( p_tauj  , 'V', -1. )
479         CALL lbc_lnk( z_wnds_t, 'T',  1. )
480         !
481      END SELECT
482
483      !                                     ! ========================== !
484      DO jl = 1, ijpl                       !  Loop over ice categories  !
485         !                                  ! ========================== !
486!CDIR NOVERRCHK
487!CDIR COLLAPSE
488         DO jj = 1 , jpj
489!CDIR NOVERRCHK
490            DO ji = 1, jpi
491               ! ----------------------------!
492               !      I   Radiative FLUXES   !
493               ! ----------------------------!
494               zst2 = pst(ji,jj,jl) * pst(ji,jj,jl)
495               zst3 = pst(ji,jj,jl) * zst2
496               ! Short Wave (sw)
497               p_qsr(ji,jj,jl) = ( 1. - palb(ji,jj,jl) ) * sf(jp_qsr)%fnow(ji,jj) * tmask(ji,jj,1)
498               ! Long  Wave (lw)
499               z_qlw(ji,jj,jl) = 0.95 * (  sf(jp_qlw)%fnow(ji,jj)       &                         
500                  &                   - Stef * pst(ji,jj,jl) * zst3  ) * tmask(ji,jj,1)
501               ! lw sensitivity
502               z_dqlw(ji,jj,jl) = zcoef_dqlw * zst3                                               
503
504               ! ----------------------------!
505               !     II    Turbulent FLUXES  !
506               ! ----------------------------!
507
508               ! ... turbulent heat fluxes
509               ! Sensible Heat
510               z_qsb(ji,jj,jl) = rhoa * cpa * Cice * z_wnds_t(ji,jj) * ( pst(ji,jj,jl) - sf(jp_tair)%fnow(ji,jj) )
511               ! Latent Heat
512               p_qla(ji,jj,jl) = MAX( 0.e0, rhoa * Ls  * Cice * z_wnds_t(ji,jj)   &                           
513                  &                    * (  11637800. * EXP( -5897.8 / pst(ji,jj,jl) ) / rhoa - sf(jp_humi)%fnow(ji,jj)  ) )
514               ! Latent heat sensitivity for ice (Dqla/Dt)
515               p_dqla(ji,jj,jl) = zcoef_dqla * z_wnds_t(ji,jj) / ( zst2 ) * EXP( -5897.8 / pst(ji,jj,jl) )
516               ! Sensible heat sensitivity (Dqsb_ice/Dtn_ice)
517               z_dqsb(ji,jj,jl) = zcoef_dqsb * z_wnds_t(ji,jj)
518
519               ! ----------------------------!
520               !     III    Total FLUXES     !
521               ! ----------------------------!
522               ! Downward Non Solar flux
523               p_qns (ji,jj,jl) =     z_qlw (ji,jj,jl) - z_qsb (ji,jj,jl) - p_qla (ji,jj,jl)     
524               ! Total non solar heat flux sensitivity for ice
525               p_dqns(ji,jj,jl) = - ( z_dqlw(ji,jj,jl) + z_dqsb(ji,jj,jl) + p_dqla(ji,jj,jl) )   
526            END DO
527            !
528         END DO
529         !
530      END DO
531      !
532      !--------------------------------------------------------------------
533      ! FRACTIONs of net shortwave radiation which is not absorbed in the
534      ! thin surface layer and penetrates inside the ice cover
535      ! ( Maykut and Untersteiner, 1971 ; Ebert and Curry, 1993 )
536   
537!CDIR COLLAPSE
538      p_fr1(:,:) = ( 0.18 * ( 1.0 - zcoef_frca ) + 0.35 * zcoef_frca )
539!CDIR COLLAPSE
540      p_fr2(:,:) = ( 0.82 * ( 1.0 - zcoef_frca ) + 0.65 * zcoef_frca )
541       
542!CDIR COLLAPSE
543      p_tpr(:,:) = sf(jp_prec)%fnow(:,:) * rn_pfac      ! total precipitation [kg/m2/s]
544!CDIR COLLAPSE
545      p_spr(:,:) = sf(jp_snow)%fnow(:,:) * rn_pfac      ! solid precipitation [kg/m2/s]
546      CALL iom_put( 'snowpre', p_spr )                  ! Snow precipitation
547      !
548      IF(ln_ctl) THEN
549         CALL prt_ctl(tab3d_1=p_qla   , clinfo1=' blk_ice_core: p_qla  : ', tab3d_2=z_qsb   , clinfo2=' z_qsb  : ', kdim=ijpl)
550         CALL prt_ctl(tab3d_1=z_qlw   , clinfo1=' blk_ice_core: z_qlw  : ', tab3d_2=p_dqla  , clinfo2=' p_dqla : ', kdim=ijpl)
551         CALL prt_ctl(tab3d_1=z_dqsb  , clinfo1=' blk_ice_core: z_dqsb : ', tab3d_2=z_dqlw  , clinfo2=' z_dqlw : ', kdim=ijpl)
552         CALL prt_ctl(tab3d_1=p_dqns  , clinfo1=' blk_ice_core: p_dqns : ', tab3d_2=p_qsr   , clinfo2=' p_qsr  : ', kdim=ijpl)
553         CALL prt_ctl(tab3d_1=pst     , clinfo1=' blk_ice_core: pst    : ', tab3d_2=p_qns   , clinfo2=' p_qns  : ', kdim=ijpl)
554         CALL prt_ctl(tab2d_1=p_tpr   , clinfo1=' blk_ice_core: p_tpr  : ', tab2d_2=p_spr   , clinfo2=' p_spr  : ')
555         CALL prt_ctl(tab2d_1=p_taui  , clinfo1=' blk_ice_core: p_taui : ', tab2d_2=p_tauj  , clinfo2=' p_tauj : ')
556         CALL prt_ctl(tab2d_1=z_wnds_t, clinfo1=' blk_ice_core: z_wnds_t : ')
557      ENDIF
558
559   END SUBROUTINE blk_ice_core
560 
561
562   SUBROUTINE TURB_CORE_1Z(zu, sst, T_a, q_sat, q_a,   &
563      &                        dU, Cd, Ch, Ce   )
564      !!----------------------------------------------------------------------
565      !!                      ***  ROUTINE  turb_core  ***
566      !!
567      !! ** Purpose :   Computes turbulent transfert coefficients of surface
568      !!                fluxes according to Large & Yeager (2004)
569      !!
570      !! ** Method  :   I N E R T I A L   D I S S I P A T I O N   M E T H O D
571      !!      Momentum, Latent and sensible heat exchange coefficients
572      !!      Caution: this procedure should only be used in cases when air
573      !!      temperature (T_air), air specific humidity (q_air) and wind (dU)
574      !!      are provided at the same height 'zzu'!
575      !!
576      !! References :
577      !!      Large & Yeager, 2004 : ???
578      !! History :
579      !!        !  XX-XX  (???     )  Original code
580      !!   9.0  !  05-08  (L. Brodeau) Rewriting and optimization
581      !!----------------------------------------------------------------------
582      !! * Arguments
583
584      REAL(wp), INTENT(in) :: zu                 ! altitude of wind measurement       [m]
585      REAL(wp), INTENT(in), DIMENSION(jpi,jpj) ::  &
586         sst,       &       ! sea surface temperature         [Kelvin]
587         T_a,       &       ! potential air temperature       [Kelvin]
588         q_sat,     &       ! sea surface specific humidity   [kg/kg]
589         q_a,       &       ! specific air humidity           [kg/kg]
590         dU                 ! wind module |U(zu)-U(0)|        [m/s]
591      REAL(wp), intent(out), DIMENSION(jpi,jpj)  :: &
592         Cd,    &                ! transfert coefficient for momentum       (tau)
593         Ch,    &                ! transfert coefficient for temperature (Q_sens)
594         Ce                      ! transfert coefficient for evaporation  (Q_lat)
595
596      !! * Local declarations
597      REAL(wp), DIMENSION(jpi,jpj)  ::   &
598         dU10,        &       ! dU                                   [m/s]
599         dT,          &       ! air/sea temperature differeence      [K]
600         dq,          &       ! air/sea humidity difference          [K]
601         Cd_n10,      &       ! 10m neutral drag coefficient
602         Ce_n10,      &       ! 10m neutral latent coefficient
603         Ch_n10,      &       ! 10m neutral sensible coefficient
604         sqrt_Cd_n10, &       ! root square of Cd_n10
605         sqrt_Cd,     &       ! root square of Cd
606         T_vpot,      &       ! virtual potential temperature        [K]
607         T_star,      &       ! turbulent scale of tem. fluct.
608         q_star,      &       ! turbulent humidity of temp. fluct.
609         U_star,      &       ! turb. scale of velocity fluct.
610         L,           &       ! Monin-Obukov length                  [m]
611         zeta,        &       ! stability parameter at height zu
612         U_n10,       &       ! neutral wind velocity at 10m         [m]   
613         xlogt, xct, zpsi_h, zpsi_m
614      !!
615      INTEGER :: j_itt
616      INTEGER, PARAMETER :: nb_itt = 3
617      INTEGER, DIMENSION(jpi,jpj)  ::   &
618         stab         ! 1st guess stability test integer
619
620      REAL(wp), PARAMETER ::                        &
621         grav   = 9.8,          &  ! gravity                       
622         kappa  = 0.4              ! von Karman s constant
623
624      !! * Start
625      !! Air/sea differences
626      dU10 = max(0.5, dU)     ! we don't want to fall under 0.5 m/s
627      dT = T_a - sst          ! assuming that T_a is allready the potential temp. at zzu
628      dq = q_a - q_sat
629      !!   
630      !! Virtual potential temperature
631      T_vpot = T_a*(1. + 0.608*q_a)
632      !!
633      !! Neutral Drag Coefficient
634      stab    = 0.5 + sign(0.5,dT)    ! stable : stab = 1 ; unstable : stab = 0
635      Cd_n10  = 1E-3 * ( 2.7/dU10 + 0.142 + dU10/13.09 )    !   L & Y eq. (6a)
636      sqrt_Cd_n10 = sqrt(Cd_n10)
637      Ce_n10  = 1E-3 * ( 34.6 * sqrt_Cd_n10 )               !   L & Y eq. (6b)
638      Ch_n10  = 1E-3*sqrt_Cd_n10*(18*stab + 32.7*(1-stab)) !   L & Y eq. (6c), (6d)
639      !!
640      !! Initializing transfert coefficients with their first guess neutral equivalents :
641      Cd = Cd_n10 ;  Ce = Ce_n10 ;  Ch = Ch_n10 ;  sqrt_Cd = sqrt(Cd)
642
643      !! * Now starting iteration loop
644      DO j_itt=1, nb_itt
645         !! Turbulent scales :
646         U_star  = sqrt_Cd*dU10                !   L & Y eq. (7a)
647         T_star  = Ch/sqrt_Cd*dT               !   L & Y eq. (7b)
648         q_star  = Ce/sqrt_Cd*dq               !   L & Y eq. (7c)
649
650         !! Estimate the Monin-Obukov length :
651         L  = (U_star**2)/( kappa*grav*(T_star/T_vpot + q_star/(q_a + 1./0.608)) )
652
653         !! Stability parameters :
654         zeta = zu/L ;  zeta   = sign( min(abs(zeta),10.0), zeta )
655         zpsi_h = psi_h(zeta)
656         zpsi_m = psi_m(zeta)
657
658         !! Shifting the wind speed to 10m and neutral stability :
659         U_n10 = dU10*1./(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)) !  L & Y eq. (9a)
660
661         !! Updating the neutral 10m transfer coefficients :
662         Cd_n10  = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09)              !  L & Y eq. (6a)
663         sqrt_Cd_n10 = sqrt(Cd_n10)
664         Ce_n10  = 1E-3 * (34.6 * sqrt_Cd_n10)                           !  L & Y eq. (6b)
665         stab    = 0.5 + sign(0.5,zeta)
666         Ch_n10  = 1E-3*sqrt_Cd_n10*(18.*stab + 32.7*(1-stab))           !  L & Y eq. (6c), (6d)
667
668         !! Shifting the neutral  10m transfer coefficients to ( zu , zeta ) :
669         !!
670         xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10) - zpsi_m)
671         Cd  = Cd_n10/(xct*xct) ;  sqrt_Cd = sqrt(Cd)
672         !!
673         xlogt = log(zu/10.) - zpsi_h
674         !!
675         xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
676         Ch  = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
677         !!
678         xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
679         Ce  = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
680         !!
681      END DO
682      !!
683    END SUBROUTINE TURB_CORE_1Z
684
685
686    SUBROUTINE TURB_CORE_2Z(zt, zu, sst, T_zt, q_sat, q_zt, dU, Cd, Ch, Ce, T_zu, q_zu)
687      !!----------------------------------------------------------------------
688      !!                      ***  ROUTINE  turb_core  ***
689      !!
690      !! ** Purpose :   Computes turbulent transfert coefficients of surface
691      !!                fluxes according to Large & Yeager (2004).
692      !!
693      !! ** Method  :   I N E R T I A L   D I S S I P A T I O N   M E T H O D
694      !!      Momentum, Latent and sensible heat exchange coefficients
695      !!      Caution: this procedure should only be used in cases when air
696      !!      temperature (T_air) and air specific humidity (q_air) are at 2m
697      !!      whereas wind (dU) is at 10m.
698      !!
699      !! References :
700      !!      Large & Yeager, 2004 : ???
701      !! History :
702      !!   9.0  !  06-12  (L. Brodeau) Original code for 2Z
703      !!----------------------------------------------------------------------
704      REAL(wp), INTENT(in)   :: &
705         zt,      &     ! height for T_zt and q_zt                   [m]
706         zu             ! height for dU                              [m]
707      REAL(wp), INTENT(in), DIMENSION(jpi,jpj) ::  &
708         sst,      &     ! sea surface temperature              [Kelvin]
709         T_zt,     &     ! potential air temperature            [Kelvin]
710         q_sat,    &     ! sea surface specific humidity         [kg/kg]
711         q_zt,     &     ! specific air humidity                 [kg/kg]
712         dU              ! relative wind module |U(zu)-U(0)|       [m/s]
713      REAL(wp), INTENT(out), DIMENSION(jpi,jpj)  ::  &
714         Cd,       &     ! transfer coefficient for momentum         (tau)
715         Ch,       &     ! transfer coefficient for sensible heat (Q_sens)
716         Ce,       &     ! transfert coefficient for evaporation   (Q_lat)
717         T_zu,     &     ! air temp. shifted at zu                     [K]
718         q_zu            ! spec. hum.  shifted at zu               [kg/kg]
719
720      !! * Local declarations
721      REAL(wp), DIMENSION(jpi,jpj) ::  &
722         dU10,        &     ! dU                                [m/s]
723         dT,          &     ! air/sea temperature differeence   [K]
724         dq,          &     ! air/sea humidity difference       [K]
725         Cd_n10,      &     ! 10m neutral drag coefficient
726         Ce_n10,      &     ! 10m neutral latent coefficient
727         Ch_n10,      &     ! 10m neutral sensible coefficient
728         sqrt_Cd_n10, &     ! root square of Cd_n10
729         sqrt_Cd,     &     ! root square of Cd
730         T_vpot_u,    &     ! virtual potential temperature        [K]
731         T_star,      &     ! turbulent scale of tem. fluct.
732         q_star,      &     ! turbulent humidity of temp. fluct.
733         U_star,      &     ! turb. scale of velocity fluct.
734         L,           &     ! Monin-Obukov length                  [m]
735         zeta_u,      &     ! stability parameter at height zu
736         zeta_t,      &     ! stability parameter at height zt
737         U_n10,       &     ! neutral wind velocity at 10m        [m]
738         xlogt, xct, zpsi_hu, zpsi_ht, zpsi_m
739
740      INTEGER :: j_itt
741      INTEGER, PARAMETER :: nb_itt = 3   ! number of itterations
742      INTEGER, DIMENSION(jpi,jpj) :: &
743           &     stab                ! 1st stability test integer
744      REAL(wp), PARAMETER ::                        &
745         grav   = 9.8,      &  ! gravity                       
746         kappa  = 0.4          ! von Karman's constant
747
748      !!  * Start
749
750      !! Initial air/sea differences
751      dU10 = max(0.5, dU)      !  we don't want to fall under 0.5 m/s
752      dT = T_zt - sst 
753      dq = q_zt - q_sat
754
755      !! Neutral Drag Coefficient :
756      stab = 0.5 + sign(0.5,dT)                 ! stab = 1  if dT > 0  -> STABLE
757      Cd_n10  = 1E-3*( 2.7/dU10 + 0.142 + dU10/13.09 ) 
758      sqrt_Cd_n10 = sqrt(Cd_n10)
759      Ce_n10  = 1E-3*( 34.6 * sqrt_Cd_n10 )
760      Ch_n10  = 1E-3*sqrt_Cd_n10*(18*stab + 32.7*(1 - stab))
761
762      !! Initializing transf. coeff. with their first guess neutral equivalents :
763      Cd = Cd_n10 ;  Ce = Ce_n10 ;  Ch = Ch_n10 ;  sqrt_Cd = sqrt(Cd)
764
765      !! Initializing z_u values with z_t values :
766      T_zu = T_zt ;  q_zu = q_zt
767
768      !!  * Now starting iteration loop
769      DO j_itt=1, nb_itt
770         dT = T_zu - sst ;  dq = q_zu - q_sat ! Updating air/sea differences
771         T_vpot_u = T_zu*(1. + 0.608*q_zu)    ! Updating virtual potential temperature at zu
772         U_star = sqrt_Cd*dU10                ! Updating turbulent scales :   (L & Y eq. (7))
773         T_star  = Ch/sqrt_Cd*dT              !
774         q_star  = Ce/sqrt_Cd*dq              !
775         !!
776         L = (U_star*U_star) &                ! Estimate the Monin-Obukov length at height zu
777              & / (kappa*grav/T_vpot_u*(T_star*(1.+0.608*q_zu) + 0.608*T_zu*q_star))
778         !! Stability parameters :
779         zeta_u  = zu/L  ;  zeta_u = sign( min(abs(zeta_u),10.0), zeta_u )
780         zeta_t  = zt/L  ;  zeta_t = sign( min(abs(zeta_t),10.0), zeta_t )
781         zpsi_hu = psi_h(zeta_u)
782         zpsi_ht = psi_h(zeta_t)
783         zpsi_m  = psi_m(zeta_u)
784         !!
785         !! Shifting the wind speed to 10m and neutral stability : (L & Y eq.(9a))
786!        U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - psi_m(zeta_u)))
787         U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m))
788         !!
789         !! Shifting temperature and humidity at zu :          (L & Y eq. (9b-9c))
790!        T_zu = T_zt - T_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
791         T_zu = T_zt - T_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
792!        q_zu = q_zt - q_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
793         q_zu = q_zt - q_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
794         !!
795         !! q_zu cannot have a negative value : forcing 0
796         stab = 0.5 + sign(0.5,q_zu) ;  q_zu = stab*q_zu
797         !!
798         !! Updating the neutral 10m transfer coefficients :
799         Cd_n10  = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09)    ! L & Y eq. (6a)
800         sqrt_Cd_n10 = sqrt(Cd_n10)
801         Ce_n10  = 1E-3 * (34.6 * sqrt_Cd_n10)                 ! L & Y eq. (6b)
802         stab    = 0.5 + sign(0.5,zeta_u)
803         Ch_n10  = 1E-3*sqrt_Cd_n10*(18.*stab + 32.7*(1-stab)) ! L & Y eq. (6c-6d)
804         !!
805         !!
806         !! Shifting the neutral 10m transfer coefficients to (zu,zeta_u) :
807!        xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10.) - psi_m(zeta_u))
808         xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)
809         Cd = Cd_n10/(xct*xct) ; sqrt_Cd = sqrt(Cd)
810         !!
811!        xlogt = log(zu/10.) - psi_h(zeta_u)
812         xlogt = log(zu/10.) - zpsi_hu
813         !!
814         xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
815         Ch  = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
816         !!
817         xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
818         Ce  = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
819         !!
820         !!
821      END DO
822      !!
823    END SUBROUTINE TURB_CORE_2Z
824
825
826    FUNCTION psi_m(zta)   !! Psis, L & Y eq. (8c), (8d), (8e)
827      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
828
829      REAL(wp), PARAMETER :: pi = 3.141592653589793_wp
830      REAL(wp), DIMENSION(jpi,jpj)             :: psi_m
831      REAL(wp), DIMENSION(jpi,jpj)             :: X2, X, stabit
832      X2 = sqrt(abs(1. - 16.*zta))  ;  X2 = max(X2 , 1.0) ;  X  = sqrt(X2)
833      stabit    = 0.5 + sign(0.5,zta)
834      psi_m = -5.*zta*stabit  &                                                  ! Stable
835           & + (1. - stabit)*(2*log((1. + X)/2) + log((1. + X2)/2) - 2*atan(X) + pi/2)  ! Unstable
836    END FUNCTION psi_m
837
838    FUNCTION psi_h(zta)    !! Psis, L & Y eq. (8c), (8d), (8e)
839      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
840
841      REAL(wp), DIMENSION(jpi,jpj)             :: psi_h
842      REAL(wp), DIMENSION(jpi,jpj)             :: X2, X, stabit
843      X2 = sqrt(abs(1. - 16.*zta))  ;  X2 = max(X2 , 1.) ;  X  = sqrt(X2)
844      stabit    = 0.5 + sign(0.5,zta)
845      psi_h = -5.*zta*stabit  &                                       ! Stable
846           & + (1. - stabit)*(2.*log( (1. + X2)/2. ))                 ! Unstable
847    END FUNCTION psi_h
848 
849   !!======================================================================
850END MODULE sbcblk_core
Note: See TracBrowser for help on using the repository browser.