New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 216

Last change on this file since 216 was 216, checked in by opalod, 19 years ago

CT : UPDATE151 : New trends organization
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 17.0 KB
Line 
1MODULE traadv_muscl
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean active tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6
7   !!----------------------------------------------------------------------
8   !!   tra_adv_muscl : update the tracer trend with the horizontal
9   !!                   and vertical advection trends using MUSCL scheme
10   !!----------------------------------------------------------------------
11   !! * Modules used
12   USE oce             ! ocean dynamics and active tracers
13   USE dom_oce         ! ocean space and time domain
14   USE trdmod          ! ocean active tracers trends
15   USE trdmod_oce      ! ocean variables trends
16   USE in_out_manager  ! I/O manager
17   USE dynspg_fsc      ! surface pressure gradient
18   USE dynspg_fsc_atsk ! autotasked surface pressure gradient
19   USE trabbl          ! tracers: bottom boundary layer
20   USE lib_mpp         ! distribued memory computing
21   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
22   USE diaptr          ! poleward transport diagnostics
23
24   IMPLICIT NONE
25   PRIVATE
26
27   !! * Accessibility
28   PUBLIC tra_adv_muscl  ! routine called by step.F90
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32#  include "vectopt_loop_substitute.h90"
33   !!----------------------------------------------------------------------
34   !!   OPA 9.0 , LODYC-IPSL (2003)
35   !!----------------------------------------------------------------------
36
37CONTAINS
38
39   SUBROUTINE tra_adv_muscl( kt )
40      !!----------------------------------------------------------------------
41      !!                    ***  ROUTINE tra_adv_muscl  ***
42      !!
43      !! ** Purpose :   Compute the now trend due to total advection of T and
44      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
45      !!      Conservation Laws) and add it to the general tracer trend.
46      !!
47      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
48      !!
49      !! ** Action  : - update (ta,sa) with the now advective tracer trends
50      !!              - save trends in (ztdta,ztdsa) ('key_trdtra')
51      !!
52      !! References :               
53      !!      Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
54      !! IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
55      !!
56      !! History :
57      !!        !  06-00  (A.Estublier)  for passive tracers
58      !!        !  01-08  (E.Durand G.Madec)  adapted for T & S
59      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
60      !!   9.0  !  04-08  (C. Talandier) New trends organization
61      !!----------------------------------------------------------------------
62      !! * modules used
63#if defined key_trabbl_adv
64      USE oce                , zun => ua,  &  ! use ua as workspace
65         &                     zvn => va      ! use va as workspace
66      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
67#else
68      USE oce                , zun => un,  &  ! When no bbl, zun == un
69                               zvn => vn,  &  !              zvn == vn
70                               zwn => wn      !              zwn == wn
71#endif
72
73      !! * Arguments
74      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
75
76      !! * Local declarations
77      INTEGER ::   ji, jj, jk               ! dummy loop indices
78      REAL(wp) ::   &
79         zu, zv, zw, zeu, zev,           & 
80         zew, zbtr, zstep,               &
81         z0u, z0v, z0w,                  &
82         zzt1, zzt2, zalpha,             &
83         zzs1, zzs2, z2,                 &
84         zta, zsa                         
85      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   &
86         zt1, zt2, ztp1, ztp2,               &
87         zs1, zs2, zsp1, zsp2,               &
88         ztdta, ztdsa
89      !!----------------------------------------------------------------------
90
91      IF( kt == nit000 .AND. lwp ) THEN
92         WRITE(numout,*)
93         WRITE(numout,*) 'tra_adv : MUSCL advection scheme'
94         WRITE(numout,*) '~~~~~~~'
95      ENDIF
96
97      IF( neuler == 0 .AND. kt == nit000 ) THEN
98          z2=1.
99      ELSE
100          z2=2.
101      ENDIF
102
103      ! Save ta and sa trends
104      IF( l_trdtra )   THEN
105         ztdta(:,:,:) = ta(:,:,:) 
106         ztdsa(:,:,:) = sa(:,:,:) 
107         l_adv = 'mus'
108      ENDIF
109
110#if defined key_trabbl_adv
111      ! Advective bottom boundary layer
112      ! -------------------------------
113      zun(:,:,:) = un (:,:,:) - u_bbl(:,:,:)
114      zvn(:,:,:) = vn (:,:,:) - v_bbl(:,:,:)
115      zwn(:,:,:) = wn (:,:,:) + w_bbl( :,:,:)
116#endif
117
118
119      ! I. Horizontal advective fluxes
120      ! ------------------------------
121
122      ! first guess of the slopes
123      ! interior values
124      DO jk = 1, jpkm1
125         DO jj = 1, jpjm1     
126            DO ji = 1, fs_jpim1   ! vector opt.
127               zt1(ji,jj,jk) = umask(ji,jj,jk) * ( tb(ji+1,jj,jk) - tb(ji,jj,jk) )
128               zs1(ji,jj,jk) = umask(ji,jj,jk) * ( sb(ji+1,jj,jk) - sb(ji,jj,jk) )
129               zt2(ji,jj,jk) = vmask(ji,jj,jk) * ( tb(ji,jj+1,jk) - tb(ji,jj,jk) )
130               zs2(ji,jj,jk) = vmask(ji,jj,jk) * ( sb(ji,jj+1,jk) - sb(ji,jj,jk) )
131            END DO
132         END DO
133      END DO
134      ! bottom values
135      zt1(:,:,jpk) = 0.e0    ;    zt2(:,:,jpk) = 0.e0
136      zs1(:,:,jpk) = 0.e0    ;    zs2(:,:,jpk) = 0.e0
137
138      ! lateral boundary conditions on zt1, zt2 ; zs1, zs2   (changed sign)
139      CALL lbc_lnk( zt1, 'U', -1. )   ;   CALL lbc_lnk( zs1, 'U', -1. )
140      CALL lbc_lnk( zt2, 'V', -1. )   ;   CALL lbc_lnk( zs2, 'V', -1. )
141
142      ! Slopes
143      ! interior values
144      DO jk = 1, jpkm1
145         DO jj = 2, jpj
146            DO ji = fs_2, jpi   ! vector opt.
147               ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji-1,jj  ,jk) )   &
148                  &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji-1,jj  ,jk) ) )
149               zsp1(ji,jj,jk) =                    ( zs1(ji,jj,jk) + zs1(ji-1,jj  ,jk) )   &
150                  &           * ( 0.25 + SIGN( 0.25, zs1(ji,jj,jk) * zs1(ji-1,jj  ,jk) ) )
151               ztp2(ji,jj,jk) =                    ( zt2(ji,jj,jk) + zt2(ji  ,jj-1,jk) )   &
152                  &           * ( 0.25 + SIGN( 0.25, zt2(ji,jj,jk) * zt2(ji  ,jj-1,jk) ) )
153               zsp2(ji,jj,jk) =                    ( zs2(ji,jj,jk) + zs2(ji  ,jj-1,jk) )   &
154                  &           * ( 0.25 + SIGN( 0.25, zs2(ji,jj,jk) * zs2(ji  ,jj-1,jk) ) )
155            END DO
156         END DO
157      END DO
158      ! bottom values
159      ztp1(:,:,jpk) = 0.e0    ;    ztp2(:,:,jpk) = 0.e0
160      zsp1(:,:,jpk) = 0.e0    ;    zsp2(:,:,jpk) = 0.e0
161
162      ! Slopes limitation
163      DO jk = 1, jpkm1
164         DO jj = 2, jpj
165            DO ji = fs_2, jpi   ! vector opt.
166               ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
167                  &           * MIN(    ABS( ztp1(ji  ,jj,jk) ),   &
168                  &                  2.*ABS( zt1 (ji-1,jj,jk) ),   &
169                  &                  2.*ABS( zt1 (ji  ,jj,jk) ) )
170               zsp1(ji,jj,jk) = SIGN( 1., zsp1(ji,jj,jk) )   &
171                  &           * MIN(    ABS( zsp1(ji  ,jj,jk) ),   &
172                  &                  2.*ABS( zs1 (ji-1,jj,jk) ),   &
173                  &                  2.*ABS( zs1 (ji  ,jj,jk) ) )
174               ztp2(ji,jj,jk) = SIGN( 1., ztp2(ji,jj,jk) )   &
175                  &           * MIN(    ABS( ztp2(ji,jj  ,jk) ),   &
176                  &                  2.*ABS( zt2 (ji,jj-1,jk) ),   &
177                  &                  2.*ABS( zt2 (ji,jj  ,jk) ) )
178               zsp2(ji,jj,jk) = SIGN( 1., zsp2(ji,jj,jk) )   &
179                  &           * MIN(    ABS( zsp2(ji,jj  ,jk) ),   &
180                  &                  2.*ABS( zs2 (ji,jj-1,jk) ),   &
181                  &                  2.*ABS( zs2 (ji,jj  ,jk) ) )
182            END DO
183         END DO
184      END DO       
185
186      ! Advection terms
187      ! interior values
188      DO jk = 1, jpkm1
189         zstep  = z2 * rdttra(jk)
190         DO jj = 2, jpjm1     
191            DO ji = fs_2, fs_jpim1   ! vector opt.
192               ! volume fluxes
193#if defined key_s_coord || defined key_partial_steps
194               zeu = e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
195               zev = e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
196#else
197               zeu = e2u(ji,jj) * zun(ji,jj,jk)
198               zev = e1v(ji,jj) * zvn(ji,jj,jk)
199#endif
200               ! MUSCL fluxes
201               z0u = SIGN( 0.5, zun(ji,jj,jk) )           
202               zalpha = 0.5 - z0u
203               zu  = z0u - 0.5 * zun(ji,jj,jk) * zstep / e1u(ji,jj)
204               zzt1 = tb(ji+1,jj,jk) + zu*ztp1(ji+1,jj,jk)
205               zzt2 = tb(ji  ,jj,jk) + zu*ztp1(ji  ,jj,jk)
206               zzs1 = sb(ji+1,jj,jk) + zu*zsp1(ji+1,jj,jk)
207               zzs2 = sb(ji  ,jj,jk) + zu*zsp1(ji  ,jj,jk)
208               zt1(ji,jj,jk) = zeu * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
209               zs1(ji,jj,jk) = zeu * ( zalpha * zzs1 + (1.-zalpha) * zzs2 )
210
211               z0v = SIGN( 0.5, zvn(ji,jj,jk) )           
212               zalpha = 0.5 - z0v
213               zv  = z0v - 0.5 * zvn(ji,jj,jk) * zstep / e2v(ji,jj)
214               zzt1 = tb(ji,jj+1,jk) + zv*ztp2(ji,jj+1,jk)
215               zzt2 = tb(ji,jj  ,jk) + zv*ztp2(ji,jj  ,jk)
216               zzs1 = sb(ji,jj+1,jk) + zv*zsp2(ji,jj+1,jk)
217               zzs2 = sb(ji,jj  ,jk) + zv*zsp2(ji,jj  ,jk)
218               zt2(ji,jj,jk) = zev * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
219               zs2(ji,jj,jk) = zev * ( zalpha * zzs1 + (1.-zalpha) * zzs2 )
220            END DO
221         END DO
222      END DO
223
224      ! lateral boundary conditions on zt1, zt2 ; zs1, zs2   (changed sign)
225      CALL lbc_lnk( zt1, 'U', -1. )   ;   CALL lbc_lnk( zs1, 'U', -1. ) 
226      CALL lbc_lnk( zt2, 'V', -1. )   ;   CALL lbc_lnk( zs2, 'V', -1. )
227
228      ! Save MUSCL fluxes to compute i- & j- horizontal
229      ! advection trends in the MLD
230      IF( l_trdtra )   THEN
231         ! save i- terms
232         tladi(:,:,:) = zt1(:,:,:) 
233         sladi(:,:,:) = zs1(:,:,:) 
234         ! save j- terms
235         tladj(:,:,:) = zt2(:,:,:) 
236         sladj(:,:,:) = zs2(:,:,:) 
237      ENDIF
238
239      ! Compute & add the horizontal advective trend
240
241      DO jk = 1, jpkm1
242         DO jj = 2, jpjm1     
243            DO ji = fs_2, fs_jpim1   ! vector opt.
244#if defined key_s_coord || defined key_partial_steps
245               zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
246#else
247               zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj) )
248#endif
249               ! horizontal advective trends
250               zta = - zbtr * ( zt1(ji,jj,jk) - zt1(ji-1,jj  ,jk  )   &
251                  &           + zt2(ji,jj,jk) - zt2(ji  ,jj-1,jk  ) )
252               zsa = - zbtr * ( zs1(ji,jj,jk) - zs1(ji-1,jj  ,jk  )   &
253                  &           + zs2(ji,jj,jk) - zs2(ji  ,jj-1,jk  ) ) 
254               ! add it to the general tracer trends
255               ta(ji,jj,jk) = ta(ji,jj,jk) + zta
256               sa(ji,jj,jk) = sa(ji,jj,jk) + zsa
257            END DO
258        END DO
259      END DO       
260
261      ! Save the horizontal advective trends for diagnostic
262
263      IF( l_trdtra )   THEN
264         ! Recompute the horizontal advection zta & zsa trends computed
265         ! at the step 2. above in making the difference between the new
266         ! trends and the previous one ta()/sa - ztdta()/ztdsa() and add
267         ! the term tn()/sn()*hdivn() to recover the Uh gradh(T/S) trends
268         ztdta(:,:,:) = ta(:,:,:) - ztdta(:,:,:) + tn(:,:,:) * hdivn(:,:,:) 
269         ztdsa(:,:,:) = sa(:,:,:) - ztdsa(:,:,:) + sn(:,:,:) * hdivn(:,:,:)
270
271         CALL trd_mod(ztdta, ztdsa, jpttdlad, 'TRA', kt)
272
273         ! Save the new ta and sa trends
274         ztdta(:,:,:) = ta(:,:,:) 
275         ztdsa(:,:,:) = sa(:,:,:) 
276
277      ENDIF
278
279      IF(l_ctl) THEN
280         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
281         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
282         WRITE(numout,*) ' had  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl, ' muscl'
283         t_ctl = zta   ;   s_ctl = zsa
284      ENDIF
285
286      ! "zonal" mean advective heat and salt transport
287      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
288# if defined key_s_coord || defined key_partial_steps
289         pht_adv(:) = ptr_vj( zt2(:,:,:) )
290         pst_adv(:) = ptr_vj( zs2(:,:,:) )
291# else
292         DO jk = 1, jpkm1
293            DO jj = 2, jpjm1
294               DO ji = fs_2, fs_jpim1   ! vector opt.
295                 zt2(ji,jj,jk) = zt2(ji,jj,jk) * fse3v(ji,jj,jk)
296                 zs2(ji,jj,jk) = zs2(ji,jj,jk) * fse3v(ji,jj,jk)
297               END DO
298            END DO
299         END DO
300         pht_adv(:) = ptr_vj( zt2(:,:,:) )
301         pst_adv(:) = ptr_vj( zs2(:,:,:) )
302# endif
303      ENDIF
304
305      ! II. Vertical advective fluxes
306      ! -----------------------------
307     
308      ! First guess of the slope
309      ! interior values
310      DO jk = 2, jpkm1
311         zt1(:,:,jk) = tmask(:,:,jk) * ( tb(:,:,jk-1) - tb(:,:,jk) )
312         zs1(:,:,jk) = tmask(:,:,jk) * ( sb(:,:,jk-1) - sb(:,:,jk) )
313      END DO
314      ! surface & bottom boundary conditions
315      zt1 (:,:, 1 ) = 0.e0    ;    zt1 (:,:,jpk) = 0.e0
316      zs1 (:,:, 1 ) = 0.e0    ;    zs1 (:,:,jpk) = 0.e0
317
318      ! Slopes
319      DO jk = 2, jpkm1
320         DO jj = 1, jpj
321            DO ji = 1, jpi
322               ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji,jj,jk+1) )   &
323                  &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji,jj,jk+1) ) )
324               zsp1(ji,jj,jk) =                    ( zs1(ji,jj,jk) + zs1(ji,jj,jk+1) )   &
325                  &           * ( 0.25 + SIGN( 0.25, zs1(ji,jj,jk) * zs1(ji,jj,jk+1) ) )
326            END DO
327         END DO
328      END DO
329
330      ! Slopes limitation
331      ! interior values
332      DO jk = 2, jpkm1
333         DO jj = 1, jpj
334            DO ji = 1, jpi
335               ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
336                  &           * MIN(    ABS( ztp1(ji,jj,jk  ) ),   &
337                  &                  2.*ABS( zt1 (ji,jj,jk+1) ),   &
338                  &                  2.*ABS( zt1 (ji,jj,jk  ) ) )
339               zsp1(ji,jj,jk) = SIGN( 1., zsp1(ji,jj,jk) )   &
340                  &           * MIN(    ABS( zsp1(ji,jj,jk  ) ),   &
341                  &                  2.*ABS( zs1 (ji,jj,jk+1) ),   &
342                  &                  2.*ABS( zs1 (ji,jj,jk  ) ) )
343            END DO
344         END DO
345      END DO
346      ! surface values
347      ztp1(:,:,1) = 0.e0
348      zsp1(:,:,1) = 0.e0
349
350      ! vertical advective flux
351      ! interior values
352      DO jk = 1, jpkm1
353         zstep  = z2 * rdttra(jk)
354         DO jj = 2, jpjm1     
355            DO ji = fs_2, fs_jpim1   ! vector opt.
356               zew = zwn(ji,jj,jk+1)
357               z0w = SIGN( 0.5, zwn(ji,jj,jk+1) )
358               zalpha = 0.5 + z0w
359               zw  = z0w - 0.5 * zwn(ji,jj,jk+1)*zstep / fse3w(ji,jj,jk+1)
360               zzt1 = tb(ji,jj,jk+1) + zw*ztp1(ji,jj,jk+1)
361               zzt2 = tb(ji,jj,jk  ) + zw*ztp1(ji,jj,jk  )
362               zzs1 = sb(ji,jj,jk+1) + zw*zsp1(ji,jj,jk+1)
363               zzs2 = sb(ji,jj,jk  ) + zw*zsp1(ji,jj,jk  )
364               zt1(ji,jj,jk+1) = zew * ( zalpha * zzt1 + (1.-zalpha)*zzt2 )
365               zs1(ji,jj,jk+1) = zew * ( zalpha * zzs1 + (1.-zalpha)*zzs2 )
366            END DO
367         END DO
368      END DO
369      ! surface values
370      IF( lk_dynspg_fsc .OR. lk_dynspg_fsc_tsk ) THEN   ! free surface-constant volume
371         zt1(:,:, 1 ) = zwn(:,:,1) * tb(:,:,1)
372         zs1(:,:, 1 ) = zwn(:,:,1) * sb(:,:,1)
373      ELSE                                              ! rigid lid : flux set to zero
374         zt1(:,:, 1 ) = 0.e0
375         zs1(:,:, 1 ) = 0.e0
376      ENDIF
377
378      ! bottom values
379      zt1(:,:,jpk) = 0.e0
380      zs1(:,:,jpk) = 0.e0
381
382
383      ! Compute & add the vertical advective trend
384
385      DO jk = 1, jpkm1
386         DO jj = 2, jpjm1     
387            DO ji = fs_2, fs_jpim1   ! vector opt.
388               zbtr = 1. / fse3t(ji,jj,jk)
389               ! horizontal advective trends
390               zta = - zbtr * ( zt1(ji,jj,jk) - zt1(ji,jj,jk+1) )
391               zsa = - zbtr * ( zs1(ji,jj,jk) - zs1(ji,jj,jk+1) )
392               ! add it to the general tracer trends
393               ta(ji,jj,jk) =  ta(ji,jj,jk) + zta
394               sa(ji,jj,jk) =  sa(ji,jj,jk) + zsa
395            END DO
396         END DO
397      END DO
398
399      ! Save the vertical advective trends for diagnostic
400
401      IF( l_trdtra )   THEN
402         ! Recompute the vertical advection zta & zsa trends computed
403         ! at the step 2. above in making the difference between the new
404         ! trends and the previous one: ta()/sa - ztdta()/ztdsa() and substract
405         ! the term tn()/sn()*hdivn() to recover the W gradz(T/S) trends
406         ztdta(:,:,:) = ta(:,:,:) - ztdta(:,:,:) - tn(:,:,:) * hdivn(:,:,:) 
407         ztdsa(:,:,:) = sa(:,:,:) - ztdsa(:,:,:) - sn(:,:,:) * hdivn(:,:,:)
408
409         CALL trd_mod(ztdta, ztdsa, jpttdzad, 'TRA', kt)
410      ENDIF
411
412      IF(l_ctl) THEN
413         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
414         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
415         WRITE(numout,*) ' zad  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl, ' muscl'
416         t_ctl = zta   ;   s_ctl = zsa
417      ENDIF
418
419   END SUBROUTINE tra_adv_muscl
420
421   !!======================================================================
422END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.