New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 247

Last change on this file since 247 was 247, checked in by opalod, 19 years ago

CL : Add CVS Header and CeCILL licence information
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 17.1 KB
Line 
1MODULE traadv_muscl
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean active tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6
7   !!----------------------------------------------------------------------
8   !!   tra_adv_muscl : update the tracer trend with the horizontal
9   !!                   and vertical advection trends using MUSCL scheme
10   !!----------------------------------------------------------------------
11   !! * Modules used
12   USE oce             ! ocean dynamics and active tracers
13   USE dom_oce         ! ocean space and time domain
14   USE trdmod          ! ocean active tracers trends
15   USE trdmod_oce      ! ocean variables trends
16   USE in_out_manager  ! I/O manager
17   USE dynspg_fsc      ! surface pressure gradient
18   USE dynspg_fsc_atsk ! autotasked surface pressure gradient
19   USE trabbl          ! tracers: bottom boundary layer
20   USE lib_mpp         ! distribued memory computing
21   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
22   USE diaptr          ! poleward transport diagnostics
23
24   IMPLICIT NONE
25   PRIVATE
26
27   !! * Accessibility
28   PUBLIC tra_adv_muscl  ! routine called by step.F90
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32#  include "vectopt_loop_substitute.h90"
33   !!----------------------------------------------------------------------
34   !!   OPA 9.0 , LOCEAN-IPSL (2005)
35   !! $Header$
36   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
37   !!----------------------------------------------------------------------
38
39CONTAINS
40
41   SUBROUTINE tra_adv_muscl( kt )
42      !!----------------------------------------------------------------------
43      !!                    ***  ROUTINE tra_adv_muscl  ***
44      !!
45      !! ** Purpose :   Compute the now trend due to total advection of T and
46      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
47      !!      Conservation Laws) and add it to the general tracer trend.
48      !!
49      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
50      !!
51      !! ** Action  : - update (ta,sa) with the now advective tracer trends
52      !!              - save trends in (ztdta,ztdsa) ('key_trdtra')
53      !!
54      !! References :               
55      !!      Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
56      !! IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
57      !!
58      !! History :
59      !!        !  06-00  (A.Estublier)  for passive tracers
60      !!        !  01-08  (E.Durand G.Madec)  adapted for T & S
61      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
62      !!   9.0  !  04-08  (C. Talandier) New trends organization
63      !!----------------------------------------------------------------------
64      !! * modules used
65#if defined key_trabbl_adv
66      USE oce                , zun => ua,  &  ! use ua as workspace
67         &                     zvn => va      ! use va as workspace
68      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
69#else
70      USE oce                , zun => un,  &  ! When no bbl, zun == un
71                               zvn => vn,  &  !              zvn == vn
72                               zwn => wn      !              zwn == wn
73#endif
74
75      !! * Arguments
76      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
77
78      !! * Local declarations
79      INTEGER ::   ji, jj, jk               ! dummy loop indices
80      REAL(wp) ::   &
81         zu, zv, zw, zeu, zev,           & 
82         zew, zbtr, zstep,               &
83         z0u, z0v, z0w,                  &
84         zzt1, zzt2, zalpha,             &
85         zzs1, zzs2, z2,                 &
86         zta, zsa                         
87      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   &
88         zt1, zt2, ztp1, ztp2,               &
89         zs1, zs2, zsp1, zsp2,               &
90         ztdta, ztdsa
91      !!----------------------------------------------------------------------
92
93      IF( kt == nit000 .AND. lwp ) THEN
94         WRITE(numout,*)
95         WRITE(numout,*) 'tra_adv : MUSCL advection scheme'
96         WRITE(numout,*) '~~~~~~~'
97      ENDIF
98
99      IF( neuler == 0 .AND. kt == nit000 ) THEN
100          z2=1.
101      ELSE
102          z2=2.
103      ENDIF
104
105      ! Save ta and sa trends
106      IF( l_trdtra )   THEN
107         ztdta(:,:,:) = ta(:,:,:) 
108         ztdsa(:,:,:) = sa(:,:,:) 
109         l_adv = 'mus'
110      ENDIF
111
112#if defined key_trabbl_adv
113      ! Advective bottom boundary layer
114      ! -------------------------------
115      zun(:,:,:) = un (:,:,:) - u_bbl(:,:,:)
116      zvn(:,:,:) = vn (:,:,:) - v_bbl(:,:,:)
117      zwn(:,:,:) = wn (:,:,:) + w_bbl( :,:,:)
118#endif
119
120
121      ! I. Horizontal advective fluxes
122      ! ------------------------------
123
124      ! first guess of the slopes
125      ! interior values
126      DO jk = 1, jpkm1
127         DO jj = 1, jpjm1     
128            DO ji = 1, fs_jpim1   ! vector opt.
129               zt1(ji,jj,jk) = umask(ji,jj,jk) * ( tb(ji+1,jj,jk) - tb(ji,jj,jk) )
130               zs1(ji,jj,jk) = umask(ji,jj,jk) * ( sb(ji+1,jj,jk) - sb(ji,jj,jk) )
131               zt2(ji,jj,jk) = vmask(ji,jj,jk) * ( tb(ji,jj+1,jk) - tb(ji,jj,jk) )
132               zs2(ji,jj,jk) = vmask(ji,jj,jk) * ( sb(ji,jj+1,jk) - sb(ji,jj,jk) )
133            END DO
134         END DO
135      END DO
136      ! bottom values
137      zt1(:,:,jpk) = 0.e0    ;    zt2(:,:,jpk) = 0.e0
138      zs1(:,:,jpk) = 0.e0    ;    zs2(:,:,jpk) = 0.e0
139
140      ! lateral boundary conditions on zt1, zt2 ; zs1, zs2   (changed sign)
141      CALL lbc_lnk( zt1, 'U', -1. )   ;   CALL lbc_lnk( zs1, 'U', -1. )
142      CALL lbc_lnk( zt2, 'V', -1. )   ;   CALL lbc_lnk( zs2, 'V', -1. )
143
144      ! Slopes
145      ! interior values
146      DO jk = 1, jpkm1
147         DO jj = 2, jpj
148            DO ji = fs_2, jpi   ! vector opt.
149               ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji-1,jj  ,jk) )   &
150                  &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji-1,jj  ,jk) ) )
151               zsp1(ji,jj,jk) =                    ( zs1(ji,jj,jk) + zs1(ji-1,jj  ,jk) )   &
152                  &           * ( 0.25 + SIGN( 0.25, zs1(ji,jj,jk) * zs1(ji-1,jj  ,jk) ) )
153               ztp2(ji,jj,jk) =                    ( zt2(ji,jj,jk) + zt2(ji  ,jj-1,jk) )   &
154                  &           * ( 0.25 + SIGN( 0.25, zt2(ji,jj,jk) * zt2(ji  ,jj-1,jk) ) )
155               zsp2(ji,jj,jk) =                    ( zs2(ji,jj,jk) + zs2(ji  ,jj-1,jk) )   &
156                  &           * ( 0.25 + SIGN( 0.25, zs2(ji,jj,jk) * zs2(ji  ,jj-1,jk) ) )
157            END DO
158         END DO
159      END DO
160      ! bottom values
161      ztp1(:,:,jpk) = 0.e0    ;    ztp2(:,:,jpk) = 0.e0
162      zsp1(:,:,jpk) = 0.e0    ;    zsp2(:,:,jpk) = 0.e0
163
164      ! Slopes limitation
165      DO jk = 1, jpkm1
166         DO jj = 2, jpj
167            DO ji = fs_2, jpi   ! vector opt.
168               ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
169                  &           * MIN(    ABS( ztp1(ji  ,jj,jk) ),   &
170                  &                  2.*ABS( zt1 (ji-1,jj,jk) ),   &
171                  &                  2.*ABS( zt1 (ji  ,jj,jk) ) )
172               zsp1(ji,jj,jk) = SIGN( 1., zsp1(ji,jj,jk) )   &
173                  &           * MIN(    ABS( zsp1(ji  ,jj,jk) ),   &
174                  &                  2.*ABS( zs1 (ji-1,jj,jk) ),   &
175                  &                  2.*ABS( zs1 (ji  ,jj,jk) ) )
176               ztp2(ji,jj,jk) = SIGN( 1., ztp2(ji,jj,jk) )   &
177                  &           * MIN(    ABS( ztp2(ji,jj  ,jk) ),   &
178                  &                  2.*ABS( zt2 (ji,jj-1,jk) ),   &
179                  &                  2.*ABS( zt2 (ji,jj  ,jk) ) )
180               zsp2(ji,jj,jk) = SIGN( 1., zsp2(ji,jj,jk) )   &
181                  &           * MIN(    ABS( zsp2(ji,jj  ,jk) ),   &
182                  &                  2.*ABS( zs2 (ji,jj-1,jk) ),   &
183                  &                  2.*ABS( zs2 (ji,jj  ,jk) ) )
184            END DO
185         END DO
186      END DO       
187
188      ! Advection terms
189      ! interior values
190      DO jk = 1, jpkm1
191         zstep  = z2 * rdttra(jk)
192         DO jj = 2, jpjm1     
193            DO ji = fs_2, fs_jpim1   ! vector opt.
194               ! volume fluxes
195#if defined key_s_coord || defined key_partial_steps
196               zeu = e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
197               zev = e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
198#else
199               zeu = e2u(ji,jj) * zun(ji,jj,jk)
200               zev = e1v(ji,jj) * zvn(ji,jj,jk)
201#endif
202               ! MUSCL fluxes
203               z0u = SIGN( 0.5, zun(ji,jj,jk) )           
204               zalpha = 0.5 - z0u
205               zu  = z0u - 0.5 * zun(ji,jj,jk) * zstep / e1u(ji,jj)
206               zzt1 = tb(ji+1,jj,jk) + zu*ztp1(ji+1,jj,jk)
207               zzt2 = tb(ji  ,jj,jk) + zu*ztp1(ji  ,jj,jk)
208               zzs1 = sb(ji+1,jj,jk) + zu*zsp1(ji+1,jj,jk)
209               zzs2 = sb(ji  ,jj,jk) + zu*zsp1(ji  ,jj,jk)
210               zt1(ji,jj,jk) = zeu * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
211               zs1(ji,jj,jk) = zeu * ( zalpha * zzs1 + (1.-zalpha) * zzs2 )
212
213               z0v = SIGN( 0.5, zvn(ji,jj,jk) )           
214               zalpha = 0.5 - z0v
215               zv  = z0v - 0.5 * zvn(ji,jj,jk) * zstep / e2v(ji,jj)
216               zzt1 = tb(ji,jj+1,jk) + zv*ztp2(ji,jj+1,jk)
217               zzt2 = tb(ji,jj  ,jk) + zv*ztp2(ji,jj  ,jk)
218               zzs1 = sb(ji,jj+1,jk) + zv*zsp2(ji,jj+1,jk)
219               zzs2 = sb(ji,jj  ,jk) + zv*zsp2(ji,jj  ,jk)
220               zt2(ji,jj,jk) = zev * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
221               zs2(ji,jj,jk) = zev * ( zalpha * zzs1 + (1.-zalpha) * zzs2 )
222            END DO
223         END DO
224      END DO
225
226      ! lateral boundary conditions on zt1, zt2 ; zs1, zs2   (changed sign)
227      CALL lbc_lnk( zt1, 'U', -1. )   ;   CALL lbc_lnk( zs1, 'U', -1. ) 
228      CALL lbc_lnk( zt2, 'V', -1. )   ;   CALL lbc_lnk( zs2, 'V', -1. )
229
230      ! Save MUSCL fluxes to compute i- & j- horizontal
231      ! advection trends in the MLD
232      IF( l_trdtra )   THEN
233         ! save i- terms
234         tladi(:,:,:) = zt1(:,:,:) 
235         sladi(:,:,:) = zs1(:,:,:) 
236         ! save j- terms
237         tladj(:,:,:) = zt2(:,:,:) 
238         sladj(:,:,:) = zs2(:,:,:) 
239      ENDIF
240
241      ! Compute & add the horizontal advective trend
242
243      DO jk = 1, jpkm1
244         DO jj = 2, jpjm1     
245            DO ji = fs_2, fs_jpim1   ! vector opt.
246#if defined key_s_coord || defined key_partial_steps
247               zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
248#else
249               zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj) )
250#endif
251               ! horizontal advective trends
252               zta = - zbtr * ( zt1(ji,jj,jk) - zt1(ji-1,jj  ,jk  )   &
253                  &           + zt2(ji,jj,jk) - zt2(ji  ,jj-1,jk  ) )
254               zsa = - zbtr * ( zs1(ji,jj,jk) - zs1(ji-1,jj  ,jk  )   &
255                  &           + zs2(ji,jj,jk) - zs2(ji  ,jj-1,jk  ) ) 
256               ! add it to the general tracer trends
257               ta(ji,jj,jk) = ta(ji,jj,jk) + zta
258               sa(ji,jj,jk) = sa(ji,jj,jk) + zsa
259            END DO
260        END DO
261      END DO       
262
263      ! Save the horizontal advective trends for diagnostic
264
265      IF( l_trdtra )   THEN
266         ! Recompute the horizontal advection zta & zsa trends computed
267         ! at the step 2. above in making the difference between the new
268         ! trends and the previous one ta()/sa - ztdta()/ztdsa() and add
269         ! the term tn()/sn()*hdivn() to recover the Uh gradh(T/S) trends
270         ztdta(:,:,:) = ta(:,:,:) - ztdta(:,:,:) + tn(:,:,:) * hdivn(:,:,:) 
271         ztdsa(:,:,:) = sa(:,:,:) - ztdsa(:,:,:) + sn(:,:,:) * hdivn(:,:,:)
272
273         CALL trd_mod(ztdta, ztdsa, jpttdlad, 'TRA', kt)
274
275         ! Save the new ta and sa trends
276         ztdta(:,:,:) = ta(:,:,:) 
277         ztdsa(:,:,:) = sa(:,:,:) 
278
279      ENDIF
280
281      IF(l_ctl) THEN
282         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
283         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
284         WRITE(numout,*) ' had  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl, ' muscl'
285         t_ctl = zta   ;   s_ctl = zsa
286      ENDIF
287
288      ! "zonal" mean advective heat and salt transport
289      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
290# if defined key_s_coord || defined key_partial_steps
291         pht_adv(:) = ptr_vj( zt2(:,:,:) )
292         pst_adv(:) = ptr_vj( zs2(:,:,:) )
293# else
294         DO jk = 1, jpkm1
295            DO jj = 2, jpjm1
296               DO ji = fs_2, fs_jpim1   ! vector opt.
297                 zt2(ji,jj,jk) = zt2(ji,jj,jk) * fse3v(ji,jj,jk)
298                 zs2(ji,jj,jk) = zs2(ji,jj,jk) * fse3v(ji,jj,jk)
299               END DO
300            END DO
301         END DO
302         pht_adv(:) = ptr_vj( zt2(:,:,:) )
303         pst_adv(:) = ptr_vj( zs2(:,:,:) )
304# endif
305      ENDIF
306
307      ! II. Vertical advective fluxes
308      ! -----------------------------
309     
310      ! First guess of the slope
311      ! interior values
312      DO jk = 2, jpkm1
313         zt1(:,:,jk) = tmask(:,:,jk) * ( tb(:,:,jk-1) - tb(:,:,jk) )
314         zs1(:,:,jk) = tmask(:,:,jk) * ( sb(:,:,jk-1) - sb(:,:,jk) )
315      END DO
316      ! surface & bottom boundary conditions
317      zt1 (:,:, 1 ) = 0.e0    ;    zt1 (:,:,jpk) = 0.e0
318      zs1 (:,:, 1 ) = 0.e0    ;    zs1 (:,:,jpk) = 0.e0
319
320      ! Slopes
321      DO jk = 2, jpkm1
322         DO jj = 1, jpj
323            DO ji = 1, jpi
324               ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji,jj,jk+1) )   &
325                  &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji,jj,jk+1) ) )
326               zsp1(ji,jj,jk) =                    ( zs1(ji,jj,jk) + zs1(ji,jj,jk+1) )   &
327                  &           * ( 0.25 + SIGN( 0.25, zs1(ji,jj,jk) * zs1(ji,jj,jk+1) ) )
328            END DO
329         END DO
330      END DO
331
332      ! Slopes limitation
333      ! interior values
334      DO jk = 2, jpkm1
335         DO jj = 1, jpj
336            DO ji = 1, jpi
337               ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
338                  &           * MIN(    ABS( ztp1(ji,jj,jk  ) ),   &
339                  &                  2.*ABS( zt1 (ji,jj,jk+1) ),   &
340                  &                  2.*ABS( zt1 (ji,jj,jk  ) ) )
341               zsp1(ji,jj,jk) = SIGN( 1., zsp1(ji,jj,jk) )   &
342                  &           * MIN(    ABS( zsp1(ji,jj,jk  ) ),   &
343                  &                  2.*ABS( zs1 (ji,jj,jk+1) ),   &
344                  &                  2.*ABS( zs1 (ji,jj,jk  ) ) )
345            END DO
346         END DO
347      END DO
348      ! surface values
349      ztp1(:,:,1) = 0.e0
350      zsp1(:,:,1) = 0.e0
351
352      ! vertical advective flux
353      ! interior values
354      DO jk = 1, jpkm1
355         zstep  = z2 * rdttra(jk)
356         DO jj = 2, jpjm1     
357            DO ji = fs_2, fs_jpim1   ! vector opt.
358               zew = zwn(ji,jj,jk+1)
359               z0w = SIGN( 0.5, zwn(ji,jj,jk+1) )
360               zalpha = 0.5 + z0w
361               zw  = z0w - 0.5 * zwn(ji,jj,jk+1)*zstep / fse3w(ji,jj,jk+1)
362               zzt1 = tb(ji,jj,jk+1) + zw*ztp1(ji,jj,jk+1)
363               zzt2 = tb(ji,jj,jk  ) + zw*ztp1(ji,jj,jk  )
364               zzs1 = sb(ji,jj,jk+1) + zw*zsp1(ji,jj,jk+1)
365               zzs2 = sb(ji,jj,jk  ) + zw*zsp1(ji,jj,jk  )
366               zt1(ji,jj,jk+1) = zew * ( zalpha * zzt1 + (1.-zalpha)*zzt2 )
367               zs1(ji,jj,jk+1) = zew * ( zalpha * zzs1 + (1.-zalpha)*zzs2 )
368            END DO
369         END DO
370      END DO
371      ! surface values
372      IF( lk_dynspg_fsc .OR. lk_dynspg_fsc_tsk ) THEN   ! free surface-constant volume
373         zt1(:,:, 1 ) = zwn(:,:,1) * tb(:,:,1)
374         zs1(:,:, 1 ) = zwn(:,:,1) * sb(:,:,1)
375      ELSE                                              ! rigid lid : flux set to zero
376         zt1(:,:, 1 ) = 0.e0
377         zs1(:,:, 1 ) = 0.e0
378      ENDIF
379
380      ! bottom values
381      zt1(:,:,jpk) = 0.e0
382      zs1(:,:,jpk) = 0.e0
383
384
385      ! Compute & add the vertical advective trend
386
387      DO jk = 1, jpkm1
388         DO jj = 2, jpjm1     
389            DO ji = fs_2, fs_jpim1   ! vector opt.
390               zbtr = 1. / fse3t(ji,jj,jk)
391               ! horizontal advective trends
392               zta = - zbtr * ( zt1(ji,jj,jk) - zt1(ji,jj,jk+1) )
393               zsa = - zbtr * ( zs1(ji,jj,jk) - zs1(ji,jj,jk+1) )
394               ! add it to the general tracer trends
395               ta(ji,jj,jk) =  ta(ji,jj,jk) + zta
396               sa(ji,jj,jk) =  sa(ji,jj,jk) + zsa
397            END DO
398         END DO
399      END DO
400
401      ! Save the vertical advective trends for diagnostic
402
403      IF( l_trdtra )   THEN
404         ! Recompute the vertical advection zta & zsa trends computed
405         ! at the step 2. above in making the difference between the new
406         ! trends and the previous one: ta()/sa - ztdta()/ztdsa() and substract
407         ! the term tn()/sn()*hdivn() to recover the W gradz(T/S) trends
408         ztdta(:,:,:) = ta(:,:,:) - ztdta(:,:,:) - tn(:,:,:) * hdivn(:,:,:) 
409         ztdsa(:,:,:) = sa(:,:,:) - ztdsa(:,:,:) - sn(:,:,:) * hdivn(:,:,:)
410
411         CALL trd_mod(ztdta, ztdsa, jpttdzad, 'TRA', kt)
412      ENDIF
413
414      IF(l_ctl) THEN
415         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
416         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
417         WRITE(numout,*) ' zad  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl, ' muscl'
418         t_ctl = zta   ;   s_ctl = zsa
419      ENDIF
420
421   END SUBROUTINE tra_adv_muscl
422
423   !!======================================================================
424END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.