New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 247

Last change on this file since 247 was 247, checked in by opalod, 19 years ago

CL : Add CVS Header and CeCILL licence information
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 13.3 KB
Line 
1MODULE traldf_iso
2   !!==============================================================================
3   !!                    ***  MODULE  traldf_iso  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if defined key_ldfslp   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'                  rotation of the lateral mixing tensor
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_iso : update the tracer trend with the horizontal component
11   !!                 of iso neutral laplacian operator or horizontal
12   !!                 laplacian operator in s-coordinate
13   !!----------------------------------------------------------------------
14   !! * Modules used
15   USE oce             ! ocean dynamics and tracers variables
16   USE dom_oce         ! ocean space and time domain variables
17   USE ldftra_oce      ! ocean active tracers: lateral physics
18   USE trdmod          ! ocean active tracers trends
19   USE trdmod_oce      ! ocean variables trends
20   USE in_out_manager  ! I/O manager
21   USE ldfslp          ! iso-neutral slopes
22   USE diaptr          ! poleward transport diagnostics
23
24   IMPLICIT NONE
25   PRIVATE
26
27   !! * Routine accessibility
28   PUBLIC tra_ldf_iso  ! routine called by step.F90
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32#  include "ldftra_substitute.h90"
33#  include "ldfeiv_substitute.h90"
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !!----------------------------------------------------------------------
37   !!  OPA 9.0 , LOCEAN-IPSL (2005)
38   !! $Header$
39   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE tra_ldf_iso( kt )
44      !!----------------------------------------------------------------------
45      !!                  ***  ROUTINE tra_ldf_iso  ***
46      !!
47      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
48      !!      trend and add it to the general trend of tracer equation.
49      !!
50      !! ** Method  :   The horizontal component of the lateral diffusive trends
51      !!      is provided by a 2nd order operator rotated along neural or geopo-
52      !!      tential surfaces to which an eddy induced advection can be added
53      !!      It is computed using before fields (forward in time) and isopyc-
54      !!      nal or geopotential slopes computed in routine ldfslp.
55      !!
56      !!      horizontal fluxes associated with the rotated lateral mixing:
57      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
58      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
59      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
60      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
61      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
62      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
63      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
64      !!      take the horizontal divergence of the fluxes:
65      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
66      !!      Add this trend to the general trend (ta,sa):
67      !!         ta = ta + difft
68      !!
69      !! ** Action  : - Update (ta,sa) arrays with the before isopycnal or
70      !!                geopotential s-coord harmonic mixing trend.
71      !!              - Save the trends in (ztdta,ztdsa) ('key_trdtra')
72      !!
73      !! History :
74      !!        !  94-08  (G. Madec, M. Imbard)
75      !!        !  97-05  (G. Madec)  split into traldf and trazdf
76      !!   8.5  !  02-08  (G. Madec)  Free form, F90
77      !!   9.0  !  04-08  (C. Talandier) New trends organization
78      !!----------------------------------------------------------------------
79      !! * Modules used
80      USE oce           , zftu => ua,  &  ! use ua as workspace
81         &                zfsu => va      ! use va as workspace
82
83      !! * Arguments
84      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
85
86      !! * Local declarations
87      INTEGER ::   ji, jj, jk             ! dummy loop indices
88      REAL(wp) ::   &
89         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
90#if defined key_traldf_eiv
91         zcg1, zcg2, zuwk, zvwk,       &
92         zuwk1, zvwk1,                 &
93#endif
94         zmsku, zmskv, zbtr, zta, zsa
95      REAL(wp), DIMENSION(jpi,jpj) ::   &
96         zdkt, zdk1t,      &  ! workspace
97         zdks, zdk1s
98#if defined key_traldf_eiv
99      REAL(wp), DIMENSION(jpi,jpj) ::   &
100         zftug, zftvg,                  &
101         zfsug, zfsvg
102#endif
103      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
104         zftv, zfsv,                        &  ! workspace
105         ztdta, ztdsa
106      !!----------------------------------------------------------------------
107
108      IF( kt == nit000 ) THEN
109         IF(lwp) WRITE(numout,*)
110         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : iso neutral lateral diffusion or'
111         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   horizontal laplacian diffusion in s-coordinate'
112#if defined key_diaeiv
113         u_eiv(:,:,:) = 0.e0
114         v_eiv(:,:,:) = 0.e0
115#endif
116      ENDIF
117
118      ! Save ta and sa trends
119      IF( l_trdtra )   THEN
120         ztdta(:,:,:) = ta(:,:,:) 
121         ztdsa(:,:,:) = sa(:,:,:) 
122      ENDIF
123
124      !                                                ! ===============
125      DO jk = 1, jpkm1                                 ! Horizontal slab
126         !                                             ! ===============
127         ! 1. Vertical tracer gradient at level jk and jk+1
128         ! ------------------------------------------------
129         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
130
131         zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1)
132         zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1)
133
134         IF( jk == 1 ) THEN
135            zdkt(:,:) = zdk1t(:,:)
136            zdks(:,:) = zdk1s(:,:)
137         ELSE
138            zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk)
139            zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk)
140         ENDIF
141
142
143         ! 2. Horizontal fluxes
144         ! --------------------
145
146         DO jj = 1 , jpjm1
147            DO ji = 1, fs_jpim1   ! vector opt.
148               zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
149               zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
150
151               zmsku = 1. / MAX(   tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
152                                 + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
153
154               zmskv = 1. / MAX(   tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
155                                 + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
156
157               zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
158               zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
159
160               zftu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   tb(ji+1,jj,jk) - tb(ji,jj,jk)  )   &
161                  &                              + zcof1 * (   zdkt (ji+1,jj) + zdk1t(ji,jj)      &
162                  &                                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
163
164               zftv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   tb(ji,jj+1,jk) - tb(ji,jj,jk)  )   &
165                  &                              + zcof2 * (   zdkt (ji,jj+1) + zdk1t(ji,jj)      &
166                  &                                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
167
168               zfsu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   sb(ji+1,jj,jk) - sb(ji,jj,jk)  )   &
169                  &                              + zcof1 * (   zdks (ji+1,jj) + zdk1s(ji,jj)      &
170                  &                              + zdk1s(ji+1,jj) + zdks (ji,jj)  )  )
171
172               zfsv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   sb(ji,jj+1,jk) - sb(ji,jj,jk)  )   &
173                  &                              + zcof2 * (   zdks (ji,jj+1) + zdk1s(ji,jj)      &
174                  &                              + zdk1s(ji,jj+1) + zdks (ji,jj)  )  )
175            END DO
176         END DO
177
178#   if defined key_traldf_eiv
179         !                              ! ---------------------------------------!
180         !                              ! Eddy induced vertical advective fluxes !
181         !                              ! ---------------------------------------!
182            DO jj = 1, jpjm1
183               DO ji = 1, fs_jpim1   ! vector opt.
184                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
185                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
186                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
187                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
188   
189                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
190                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
191   
192                  zftug(ji,jj) = zcg1 * ( tb(ji+1,jj,jk) + tb(ji,jj,jk) )
193                  zftvg(ji,jj) = zcg2 * ( tb(ji,jj+1,jk) + tb(ji,jj,jk) )
194                  zfsug(ji,jj) = zcg1 * ( sb(ji+1,jj,jk) + sb(ji,jj,jk) )
195                  zfsvg(ji,jj) = zcg2 * ( sb(ji,jj+1,jk) + sb(ji,jj,jk) )
196   
197                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
198                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
199                  zfsu(ji,jj,jk) = zfsu(ji,jj,jk) + zfsug(ji,jj)
200                  zfsv(ji,jj,jk) = zfsv(ji,jj,jk) + zfsvg(ji,jj)
201#   if defined key_diaeiv
202                  u_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
203                  v_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
204#   endif
205               END DO
206            END DO
207#   endif
208
209         ! II.4 Second derivative (divergence) and add to the general trend
210         ! ----------------------------------------------------------------
211
212         DO jj = 2 , jpjm1
213            DO ji = fs_2, fs_jpim1   ! vector opt.
214               zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
215               zta = zbtr * (  zftu(ji,jj,jk) - zftu(ji-1,jj  ,jk)   &
216                  &          + zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk)  )
217               zsa = zbtr * (  zfsu(ji,jj,jk) - zfsu(ji-1,jj  ,jk)   &
218                  &          + zfsv(ji,jj,jk) - zfsv(ji  ,jj-1,jk)  )
219               ta (ji,jj,jk) = ta (ji,jj,jk) + zta
220               sa (ji,jj,jk) = sa (ji,jj,jk) + zsa
221            END DO
222         END DO
223         !                                          ! ===============
224      END DO                                        !   End of slab 
225      !                                             ! ===============
226
227      ! save the trends for diagnostic
228      ! save the horizontal diffusive trends
229      IF( l_trdtra )   THEN
230#   if defined key_traldf_eiv
231         DO jk = 1 , jpkm1
232            DO jj = 2 , jpjm1
233               DO ji = fs_2, fs_jpim1   ! vector opt.
234                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
235                  tladi(ji,jj,jk) = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
236                  tladj(ji,jj,jk) = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
237                  sladi(ji,jj,jk) = ( zfsug(ji,jj) - zfsug(ji-1,jj  ) ) * zbtr
238                  sladj(ji,jj,jk) = ( zfsvg(ji,jj) - zfsvg(ji  ,jj-1) ) * zbtr
239               END DO
240            END DO
241         END DO
242#   else
243         tladi(:,:,:) = 0.e0
244         tladj(:,:,:) = 0.e0
245         sladi(:,:,:) = 0.e0
246         sladj(:,:,:) = 0.e0
247#   endif
248       
249         ! Substract the eddy induced velocity for T/S
250         ztdta(:,:,:) = ta(:,:,:) - ztdta(:,:,:) - tladi(:,:,:) - tladj(:,:,:) 
251         ztdsa(:,:,:) = sa(:,:,:) - ztdsa(:,:,:) - sladi(:,:,:) - sladj(:,:,:) 
252
253         CALL trd_mod(ztdta, ztdsa, jpttdldf, 'TRA', kt)
254      ENDIF
255
256      IF(l_ctl) THEN         ! print mean trends (used for debugging)
257         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
258         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
259         WRITE(numout,*) ' ldf  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl
260         t_ctl = zta   ;   s_ctl = zsa
261      ENDIF
262
263      !!bug  no separation of diff iso and eiv
264      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
265         ! "zonal" mean lateral diffusive heat and salt transports
266         pht_ldf(:) = ptr_vj( zftv(:,:,:) )
267         pst_ldf(:) = ptr_vj( zfsv(:,:,:) )
268         ! "zonal" mean lateral eddy induced velocity heat and salt transports
269         pht_eiv(:) = ptr_vj( zftv(:,:,:) )
270         pst_eiv(:) = ptr_vj( zfsv(:,:,:) )
271      ENDIF
272
273   END SUBROUTINE tra_ldf_iso
274
275#else
276   !!----------------------------------------------------------------------
277   !!   Dummy module :             No rotation of the lateral mixing tensor
278   !!----------------------------------------------------------------------
279CONTAINS
280   SUBROUTINE tra_ldf_iso( kt )               ! Empty routine
281      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
282   END SUBROUTINE tra_ldf_iso
283#endif
284
285   !!==============================================================================
286END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.