New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_zps.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_iso_zps.F90 @ 193

Last change on this file since 193 was 132, checked in by opalod, 20 years ago

CT : UPDATE082 : Finalization of the poleward transport diagnostics
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 14.1 KB
Line 
1MODULE traldf_iso_zps
2   !!==============================================================================
3   !!                   ***  MODULE  traldf_iso_zps  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if ( defined key_ldfslp   &&   defined key_partial_steps )   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'               slope of the lateral diffusive direction
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_iso_zps : update the tracer trend with the horizontal
11   !!                     component of a iso-neutral laplacian operator
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE ldftra_oce      ! ocean active tracers: lateral physics
17   USE trdtra_oce      ! ocean active tracers: trend
18   USE zdf_oce         ! ocean vertical physics
19   USE in_out_manager  ! I/O manager
20   USE ldfslp          ! iso-neutral slopes
21   USE diaptr          ! poleward transport diagnostics
22
23
24   IMPLICIT NONE
25   PRIVATE
26
27   !! * Accessibility
28   PUBLIC tra_ldf_iso_zps  ! routine called by step.F90
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32#  include "ldftra_substitute.h90"
33#  include "ldfeiv_substitute.h90"
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !!   OPA 9.0 , LODYC-IPSL (2003)
37   !!----------------------------------------------------------------------
38
39CONTAINS
40
41   SUBROUTINE tra_ldf_iso_zps( kt )
42      !!----------------------------------------------------------------------
43      !!                  ***  ROUTINE tra_ldf_iso_zps  ***
44      !!
45      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
46      !!      trend and add it to the general trend of tracer equation.
47      !!
48      !! ** Method  :   The horizontal component of the lateral diffusive trends
49      !!      is provided by a 2nd order operator rotated along neural or geopo-
50      !!      tential surfaces to which an eddy induced advection can be added
51      !!      It is computed using before fields (forward in time) and isopyc-
52      !!      nal or geopotential slopes computed in routine ldfslp.
53      !!
54      !!      horizontal fluxes associated with the rotated lateral mixing:
55      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
56      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
57      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
58      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
59      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
60      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
61      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
62      !!      take the horizontal divergence of the fluxes:
63      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
64      !!      Add this trend to the general trend (ta,sa):
65      !!         ta = ta + difft
66      !!
67      !!      'key_trdtra' defined: the trend is saved for diagnostics.
68      !!
69      !!      macro-tasked on horizontal slab (jk-loop).
70      !!
71      !! ** Action :
72      !!         Update (ta,sa) arrays with the before along level biharmonic
73      !!      mixing trend.
74      !!         Save in (ttrd,strd) arrays the trends if 'key_diatrends' defined
75      !!
76      !! History :
77      !!        !  94-08  (G. Madec, M. Imbard)
78      !!        !  97-05  (G. Madec)  split into traldf and trazdf
79      !!   8.5  !  02-08  (G. Madec)  Free form, F90
80      !!----------------------------------------------------------------------
81      !! * Modules used
82      USE oce           , zftu => ua,  &  ! use ua as workspace
83         &                zfsu => va      ! use va as workspace
84
85      !! * Arguments
86      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
87
88      !! * Local declarations
89      INTEGER ::   ji, jj, jk             ! dummy loop indices
90      INTEGER ::   iku, ikv               ! temporary integer
91      REAL(wp) ::   &
92         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
93         zmsku, zmskv, zbtr, zta, zsa, &  !    "           "
94         ztagu, ztagv, zsagu, zsagv
95#if defined key_traldf_eiv 
96      REAL(wp) ::   &
97         zcg1, zcg2, zuwk, zvwk,       & ! temporary scalars
98         zuwk1, zvwk1                    !    "           "
99#endif
100      REAL(wp), DIMENSION(jpi,jpj) ::   & ! temporary workspace
101         zdkt , zdk1t, zdks , zdk1s       !    "           "
102         
103#if defined key_traldf_eiv 
104      REAL(wp), DIMENSION(jpi,jpj) ::   &  ! temporary workspace
105         zftug, zftvg, zfsug, zfsvg        !     "        "     
106#endif
107      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
108         zftv, zgtbu, zgtbv,                &  ! temporary workspace
109         zfsv, zgsbu, zgsbv                    !    "           "
110      !!----------------------------------------------------------------------
111
112      IF( kt == nit000 ) THEN
113         IF(lwp) WRITE(numout,*)
114         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_zps : iso neutral laplacian diffusion in '
115         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~   z-coordinates with partial steps'
116#if defined key_diaeiv
117         u_eiv(:,:,:) = 0.e0
118         v_eiv(:,:,:) = 0.e0
119#endif
120      ENDIF
121
122      ztagu = 0.e0
123      ztagv = 0.e0
124      zsagu = 0.e0
125      zsagv = 0.e0
126
127      ! Horizontal temperature and salinity gradient
128      DO jk = 1, jpk
129         DO jj = 1, jpj-1
130            DO ji = 1, fs_jpim1   ! vector opt.
131               zgtbu(ji,jj,jk) = tmask(ji,jj,jk) * ( tb(ji+1,jj  ,jk) - tb(ji,jj,jk) )
132               zgsbu(ji,jj,jk) = tmask(ji,jj,jk) * ( sb(ji+1,jj  ,jk) - sb(ji,jj,jk) )
133               zgtbv(ji,jj,jk) = tmask(ji,jj,jk) * ( tb(ji  ,jj+1,jk) - tb(ji,jj,jk) )
134               zgsbv(ji,jj,jk) = tmask(ji,jj,jk) * ( sb(ji  ,jj+1,jk) - sb(ji,jj,jk) )
135            END DO
136         END DO
137      END DO
138      ! partial steps correction at the last level
139      DO jj = 1, jpj-1
140         DO ji = 1, jpi-1
141            ! last level
142       iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
143       ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
144            zgtbu(ji,jj,iku) = gtu(ji,jj) 
145            zgsbu(ji,jj,iku) = gsu(ji,jj)               
146            zgtbv(ji,jj,ikv) = gtv(ji,jj) 
147            zgsbv(ji,jj,ikv) = gsv(ji,jj)               
148         END DO
149      END DO
150     
151      !                                                ! ===============
152      DO jk = 1, jpkm1                                 ! Horizontal slab
153         !                                             ! ===============
154         ! 1. Vertical tracer gradient at level jk and jk+1
155         ! ------------------------------------------------
156         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
157
158         zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1)
159         zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1)
160
161         IF( jk == 1 ) THEN
162            zdkt(:,:) = zdk1t(:,:)
163            zdks(:,:) = zdk1s(:,:)
164         ELSE
165            zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk)
166            zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk)
167         ENDIF
168
169
170         ! 2. Horizontal fluxes
171         ! --------------------
172
173         DO jj = 1 , jpjm1
174            DO ji = 1, fs_jpim1   ! vector opt.
175               zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
176               zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
177
178               zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
179                                + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
180
181               zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
182                                + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
183
184               zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
185               zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
186
187               zftu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgtbu(ji,jj,jk)   &
188                  &                                + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
189                  &                                           + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
190               zftv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgtbv(ji,jj,jk)   &
191                  &                                + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
192                  &                                           + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
193               zfsu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgsbu(ji,jj,jk)   &
194                  &                                + zcof1 * (  zdks (ji+1,jj) + zdk1s(ji,jj)      &
195                  &                                           + zdk1s(ji+1,jj) + zdks (ji,jj)  )  )
196               zfsv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgsbv(ji,jj,jk)   &
197                  &                                + zcof2 * (  zdks (ji,jj+1) + zdk1s(ji,jj)      &
198                  &                                           + zdk1s(ji,jj+1) + zdks (ji,jj)  )  )
199            END DO
200         END DO
201
202#if defined key_traldf_eiv
203                                        ! ---------------------------------------!
204                                        ! Eddy induced vertical advective fluxes !
205                                        ! ---------------------------------------!
206            DO jj = 1, jpjm1
207               DO ji = 1, fs_jpim1   ! vector opt.
208                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj  ,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
209                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj  ,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
210                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji  ,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
211                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji  ,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
212
213                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
214                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
215
216                  zftug(ji,jj) = zcg1 * ( tb(ji+1,jj,jk) + tb(ji,jj,jk) )
217                  zftvg(ji,jj) = zcg2 * ( tb(ji,jj+1,jk) + tb(ji,jj,jk) )
218                  zfsug(ji,jj) = zcg1 * ( sb(ji+1,jj,jk) + sb(ji,jj,jk) )
219                  zfsvg(ji,jj) = zcg2 * ( sb(ji,jj+1,jk) + sb(ji,jj,jk) )
220
221                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
222                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
223                  zfsu(ji,jj,jk) = zfsu(ji,jj,jk) + zfsug(ji,jj)
224                  zfsv(ji,jj,jk) = zfsv(ji,jj,jk) + zfsvg(ji,jj)
225#   if defined key_diaeiv
226                  u_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
227                  v_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
228#   endif
229               END DO
230            END DO
231#endif
232
233         ! II.4 Second derivative (divergence) and add to the general trend
234         ! ----------------------------------------------------------------
235
236         DO jj = 2 , jpjm1
237            DO ji = fs_2, fs_jpim1   ! vector opt.
238               zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
239               zta = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
240               zsa = zbtr * ( zfsu(ji,jj,jk) - zfsu(ji-1,jj,jk) + zfsv(ji,jj,jk) - zfsv(ji,jj-1,jk)  )
241               ta (ji,jj,jk) = ta (ji,jj,jk) + zta
242               sa (ji,jj,jk) = sa (ji,jj,jk) + zsa
243#if defined key_trdtra || defined key_trdmld
244               ttrd (ji,jj,jk,3) = zta
245               strd (ji,jj,jk,3) = zsa
246#endif
247            END DO
248         END DO
249#if defined key_trdtra || defined key_trdmld && key_traldf_eiv
250         DO jj = 2 , jpjm1
251            DO ji = fs_2, fs_jpim1   ! vector opt.
252               zbtr= 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
253               ztagu = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
254               ztagv = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
255               zsagu = ( zfsug(ji,jj) - zfsug(ji-1,jj  ) ) * zbtr
256               zsagv = ( zfsvg(ji,jj) - zfsvg(ji  ,jj-1) ) * zbtr
257               ttrdh(ji,jj,jk,3) = ztagu
258               ttrdh(ji,jj,jk,4) = ztagv
259               strdh(ji,jj,jk,3) = zsagu
260               strdh(ji,jj,jk,4) = zsagv
261               ttrd (ji,jj,jk,3) = ttrd(ji,jj,jk,3) - ztagu - ztagv
262               strd (ji,jj,jk,3) = ttrd(ji,jj,jk,3) - zsagu - zsagv
263            END DO
264         END DO
265#endif
266         !                                          ! ===============
267      END DO                                        !   End of slab 
268      !                                             ! ===============
269
270      IF(l_ctl) THEN         ! print mean trends (used for debugging)
271         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
272         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
273         WRITE(numout,*) ' ldf  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl
274         t_ctl = zta   ;   s_ctl = zsa
275      ENDIF
276
277
278      !!bug  no separation of diff iso and eiv
279      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
280         ! "zonal" mean lateral diffusive heat and salt transports
281         pht_ldf(:) = ptr_vj( zftv(:,:,:) )
282         pst_ldf(:) = ptr_vj( zfsv(:,:,:) )
283         ! "zonal" mean lateral eddy induced velocity heat and salt transports
284         pht_eiv(:) = ptr_vj( zftv(:,:,:) )
285         pst_eiv(:) = ptr_vj( zfsv(:,:,:) )
286      ENDIF
287
288   END SUBROUTINE tra_ldf_iso_zps
289
290#else
291   !!----------------------------------------------------------------------
292   !!   default option :   Dummy code   NO rotation of the diffusive tensor
293   !!----------------------------------------------------------------------
294CONTAINS
295   SUBROUTINE tra_ldf_iso_zps( kt )               ! Empty routine
296      WRITE(*,*) 'tra_ldf_iso_zps: You should not have seen this print! error?', kt
297   END SUBROUTINE tra_ldf_iso_zps
298#endif
299
300   !!==============================================================================
301END MODULE traldf_iso_zps
Note: See TracBrowser for help on using the repository browser.