New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in trunk/NEMO/OPA_SRC – NEMO

source: trunk/NEMO/OPA_SRC/daymod.F90 @ 1601

Last change on this file since 1601 was 1559, checked in by ctlod, 15 years ago

only cosmetic changes
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 17.3 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------     
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !! 
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !! 
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
33   USE prtctl          ! Print control
34   USE restart         !
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   day        ! called by step.F90
40   PUBLIC   day_init   ! called by istate.F90
41
42   INTEGER , PUBLIC ::   nyear       !: current year
43   INTEGER , PUBLIC ::   nmonth      !: current month
44   INTEGER , PUBLIC ::   nday        !: current day of the month
45   INTEGER , PUBLIC ::   ndastp      !: time step date in yyyymmdd format
46   INTEGER , PUBLIC ::   nday_year   !: current day counted from jan 1st of the current year
47   REAL(wp), PUBLIC ::   rsec_year   !: current time step counted in second since 00h jan 1st of the current year
48   REAL(wp), PUBLIC ::   rsec_month  !: current time step counted in second since 00h 1st day of the current month
49   REAL(wp), PUBLIC ::   rsec_day    !: current time step counted in second since 00h of the current day
50
51   REAL(wp), PUBLIC ::   fjulday     !: julian day
52   REAL(wp), PUBLIC ::   adatrj      !: number of elapsed days since the begining of the whole simulation
53   !                                 !: (cumulative duration of previous runs that may have used different time-step size)
54   INTEGER , PUBLIC, DIMENSION(0: 1) ::   nyear_len    !: length in days of the previous/current year
55   INTEGER , PUBLIC, DIMENSION(0:13) ::   nmonth_len   !: length in days of the months of the current year
56   REAL(wp), PUBLIC, DIMENSION(0:13) ::   rmonth_half  !: second since Jan 1st 0h of the current year and the half of the months
57   REAL(wp), PUBLIC, DIMENSION(0:13) ::   rmonth_end   !: second since Jan 1st 0h of the current year and the end of the months
58   REAL(wp), PUBLIC                  ::   sec1jan000   !: second since Jan 1st 0h of nit000 year and Jan 1st 0h the current year
59
60   ! this two variables are wrong DO NOT USE THEM !!!
61   INTEGER, PUBLIC, DIMENSION(12) ::   nbiss = (/ 31, 29, 31, 30, 31, 30,    &  !: number of days per month
62      &                                           31, 31, 30, 31, 30, 31 /)     !: (leap-year)
63   INTEGER, PUBLIC, DIMENSION(12) ::   nobis = (/ 31, 28, 31, 30, 31, 30,    &  !: number of days per month
64      &                                           31, 31, 30, 31, 30, 31 /)     !: (365 days a year)
65
66   !!----------------------------------------------------------------------
67   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
68   !! $Id$
69   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71
72CONTAINS
73
74   SUBROUTINE day_init
75      !!----------------------------------------------------------------------
76      !!                   ***  ROUTINE day_init  ***
77      !!
78      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
79      !!                because day will be called at the beginning of step
80      !!
81      !! ** Action  : - nyear        : current year
82      !!              - nmonth       : current month of the year nyear
83      !!              - nday         : current day of the month nmonth
84      !!              - nday_year    : current day of the year nyear
85      !!              - rsec_year    : current time step counted in second since 00h jan 1st of the current year
86      !!              - rsec_month   : current time step counted in second since 00h 1st day of the current month
87      !!              - rsec_day     : current time step counted in second since 00h of the current day
88      !!              - sec1jan000   : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
89      !!              - nmonth_len, nyear_len, rmonth_half, rmonth_end through day_mth
90      !!----------------------------------------------------------------------
91
92      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
93      IF( MOD( rday, rdttra(1) ) /= 0 )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
94
95      CALL day_rst( nit000, 'READ' ) 
96
97      ! set the calandar from ndastp (read in restart file and namelist)
98
99      nyear   =   ndastp / 10000
100      nmonth  = ( ndastp - (nyear * 10000) ) / 100
101      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 ) 
102
103      CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday )  ! we assume that we start run at 00:00
104      fjulday = fjulday + 1.                             ! move back to the day at nit000 (and not at nit000 - 1)
105
106      sec1jan000 = 0.e0
107      CALL day_mth
108     
109      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
110         nmonth = nmonth - 1 
111         nday = nmonth_len(nmonth)
112      ENDIF
113      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
114         nmonth = 12
115         nyear = nyear - 1
116         sec1jan000 = sec1jan000 - rday * REAL( nyear_len(0), wp )
117         IF( nleapy == 1 )   CALL day_mth
118      ENDIF
119     
120      ! day since january 1st
121      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
122     
123      ! number of seconds since the beginning of current year/month at the middle of the time-step
124      rsec_year  = REAL( nday_year, wp ) * rday - 0.5 * rdttra(1)   ! 1 time step before the middle of the first time step
125      rsec_month = REAL( nday     , wp ) * rday - 0.5 * rdttra(1)   ! because day will be called at the beginning of step
126      rsec_day   =                         rday - 0.5 * rdttra(1)
127
128      ! control print
129      IF(lwp) WRITE(numout,*)' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
130           &                   nyear, '/', nmonth, '/', nday, '  rsec_day:', rsec_day
131     
132   END SUBROUTINE day_init
133
134
135   SUBROUTINE day_mth
136      !!----------------------------------------------------------------------
137      !!                   ***  ROUTINE day_init  ***
138      !!
139      !! ** Purpose :   calendar values related to the months
140      !!
141      !! ** Action  : - nmonth_len    : length in days of the months of the current year
142      !!              - nyear_len     : length in days of the previous/current year
143      !!              - rmonth_half   : second since the beginning of the year and the halft of the months
144      !!              - rmonth_end    : second since the beginning of the year and the end of the months
145      !!----------------------------------------------------------------------
146      INTEGER  ::   jm               ! dummy loop indice
147      !!----------------------------------------------------------------------
148
149      ! length of the month of the current year (from nleapy, read in namelist)
150      IF ( nleapy < 2 ) THEN
151         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
152         nyear_len(:) = 365
153         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
154            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
155               nyear_len(0) = 366
156            ENDIF
157            IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN
158               nmonth_len(2) = 29
159               nyear_len(1) = 366
160            ENDIF
161         ENDIF
162      ELSE
163         nmonth_len(:) = nleapy   ! all months with nleapy days per year
164         nyear_len(:) = 12 * nleapy
165      ENDIF
166
167      ! half month in second since the begining of the year:
168      ! time since Jan 1st   0     1     2    ...    11    12    13
169      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
170      !                 <---> <---> <--->  ...  <---> <---> <--->       
171      ! month number      0     1     2    ...    11    12    13
172      !
173      ! rmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
174      rmonth_half(0) = - 0.5 * rday * REAL( nmonth_len(0), wp )
175      DO jm = 1, 13
176         rmonth_half(jm) = rmonth_half(jm-1) + 0.5 * rday * REAL( nmonth_len(jm-1) + nmonth_len(jm), wp )
177      END DO
178
179      rmonth_end(0) = 0.
180      DO jm = 1, 13
181         rmonth_end(jm) = rmonth_end(jm-1) + rday * REAL( nmonth_len(jm), wp )
182      END DO
183      !           
184   END SUBROUTINE
185
186
187   SUBROUTINE day( kt )
188      !!----------------------------------------------------------------------
189      !!                      ***  ROUTINE day  ***
190      !!
191      !! ** Purpose :   Compute the date with a day iteration IF necessary.
192      !!
193      !! ** Method  : - ???
194      !!
195      !! ** Action  : - nyear     : current year
196      !!              - nmonth    : current month of the year nyear
197      !!              - nday      : current day of the month nmonth
198      !!              - nday_year : current day of the year nyear
199      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
200      !!              - adatrj    : date in days since the beginning of the run
201      !!              - rsec_year : current time of the year (in second since 00h, jan 1st)
202      !!----------------------------------------------------------------------     
203      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
204      !
205      CHARACTER (len=25) ::   charout
206      !!----------------------------------------------------------------------
207
208      !                                                 ! New time-step
209      rsec_year  = rsec_year  + rdttra(1) 
210      rsec_month = rsec_month + rdttra(1)                 
211      rsec_day   = rsec_day   + rdttra(1)                 
212      adatrj  = adatrj  + rdttra(1) / rday
213      fjulday = fjulday + rdttra(1) / rday
214     
215      IF( rsec_day > rday ) THEN                        ! NEW day
216         !
217         nday      = nday + 1
218         nday_year = nday_year + 1
219         rsec_day  = 0.5 * rdttra(1)                 
220         !
221         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! NEW month
222            nday   = 1
223            nmonth = nmonth + 1
224            rsec_month = 0.5 * rdttra(1)
225            IF( nmonth == 13 ) THEN                     ! NEW year
226               nyear     = nyear + 1
227               nmonth    = 1
228               nday_year = 1
229               rsec_year = 0.5 * rdttra(1)
230               sec1jan000 = sec1jan000 + rday * REAL( nyear_len(1), wp )
231               IF( nleapy == 1 )   CALL day_mth
232            ENDIF
233         ENDIF
234         !
235         ndastp = nyear * 10000 + nmonth * 100 + nday   ! NEW date
236         !
237         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
238              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
239         IF(lwp) WRITE(numout,'(a,F9.0,a,F9.0,a,F9.0)') '         rsec_year = ', rsec_year,   &
240              &   '   rsec_month = ', rsec_month, '   rsec_day = ', rsec_day
241      ENDIF
242     
243      IF(ln_ctl) THEN
244         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
245         CALL prt_ctl_info(charout)
246      ENDIF
247
248      IF( lrst_oce )   CALL day_rst( kt, 'WRITE' )
249      !
250   END SUBROUTINE day
251
252
253   SUBROUTINE day_rst( kt, cdrw )
254      !!---------------------------------------------------------------------
255      !!                   ***  ROUTINE ts_rst  ***
256      !!
257      !!  ** Purpose : Read or write calendar in restart file:
258      !!
259      !!  WRITE(READ) mode:
260      !!       kt        : number of time step since the begining of the experiment at the
261      !!                   end of the current(previous) run
262      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
263      !!                   end of the current(previous) run (REAL -> keep fractions of day)
264      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
265      !!
266      !!   According to namelist parameter nrstdt,
267      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
268      !!       nrstdt = 1  we verify that nit000 is equal to the last
269      !!                   time step of previous run + 1.
270      !!       In both those options, the  exact duration of the experiment
271      !!       since the beginning (cumulated duration of all previous restart runs)
272      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
273      !!       This is valid is the time step has remained constant.
274      !!
275      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
276      !!                    has been stored in the restart file.
277      !!----------------------------------------------------------------------
278      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
279      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
280      !
281      REAL(wp) ::   zkt, zndastp
282      !!----------------------------------------------------------------------
283     
284      IF( TRIM(cdrw) == 'READ' ) THEN
285
286         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
287            ! Get Calendar informations
288            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
289            IF(lwp) THEN
290               WRITE(numout,*) ' *** Info read in restart : '
291               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
292               WRITE(numout,*) ' *** restart option'
293               SELECT CASE ( nrstdt )
294               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
295               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
296               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
297               END SELECT
298               WRITE(numout,*)
299            ENDIF
300            ! Control of date
301            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         & 
302                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 & 
303                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
304            ! define ndastp and adatrj
305            IF ( nrstdt == 2 ) THEN 
306               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
307               CALL iom_get( numror, 'ndastp', zndastp )
308               ndastp = NINT( zndastp )
309               CALL iom_get( numror, 'adatrj', adatrj  )
310            ELSE 
311               ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
312               ndastp = ndate0 - 1     ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
313               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
314               ! note this is wrong if time step has changed during run
315            ENDIF
316         ELSE
317            ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
318            ndastp = ndate0 - 1        ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
319            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
320         ENDIF
321         !
322         IF(lwp) THEN
323            WRITE(numout,*) ' *** Info used values : '
324            WRITE(numout,*) '   date ndastp                                      : ', ndastp
325            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
326            WRITE(numout,*)
327         ENDIF
328         !
329      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
330         !
331         IF( kt == nitrst ) THEN
332            IF(lwp) WRITE(numout,*)
333            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
334            IF(lwp) WRITE(numout,*) '~~~~~~~'         
335         ENDIF
336         ! calendar control
337         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
338         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
339         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
340         !                                                                     ! the begining of the run [s]
341      ENDIF
342      !
343   END SUBROUTINE day_rst
344
345   !!======================================================================
346END MODULE daymod
Note: See TracBrowser for help on using the repository browser.