New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in trunk/NEMO/OPA_SRC – NEMO

source: trunk/NEMO/OPA_SRC/restart.F90 @ 1481

Last change on this file since 1481 was 1481, checked in by ctlod, 15 years ago

ensure restartability of TKE2 in coupled mode + few minor bugs corrections, see ticket: #466
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 11.6 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :        !  99-11  (M. Imbard)  Original code
7   !!             8.5  !  02-08  (G. Madec)  F90: Free form
8   !!             9.0  !  05-11  (V. Garnier) Surface pressure gradient organization
9   !!             9.0  !  06-07  (S. Masson)  use IOM for restart
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   rst_opn    : open the ocean restart file
14   !!   rst_write  : write the ocean restart file
15   !!   rst_read   : read the ocean restart file
16   !!----------------------------------------------------------------------
17   USE dom_oce         ! ocean space and time domain
18   USE oce             ! ocean dynamics and tracers
19   USE phycst          ! physical constants
20   USE in_out_manager  ! I/O manager
21   USE iom             ! I/O module
22   USE c1d             ! re-initialization of u-v mask for the 1D configuration
23   USE zpshde          ! partial step: hor. derivative (zps_hde routine)
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE zdfddm          ! double diffusion mixing
26   USE zdfmxl          ! mixed layer depth
27   USE trdmld_oce      ! ocean active mixed layer tracers trends variables
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   rst_opn    ! routine called by step module
33   PUBLIC   rst_write  ! routine called by step module
34   PUBLIC   rst_read   ! routine called by opa  module
35
36   LOGICAL, PUBLIC ::   lrst_oce =  .FALSE.       !: logical to control the oce restart write
37   INTEGER, PUBLIC ::   numror, numrow            !: logical unit for cean restart (read and write)
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !!  OPA 9.0 , LOCEAN-IPSL (2006)
43   !! $Id$
44   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46
47CONTAINS
48
49   SUBROUTINE rst_opn( kt )
50      !!---------------------------------------------------------------------
51      !!                   ***  ROUTINE rst_opn  ***
52      !!                     
53      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
54      !!              + open the restart when we are one time step before nitrst
55      !!                   - restart header is defined when kt = nitrst-1
56      !!                   - restart data  are written when kt = nitrst
57      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
58      !!----------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt     ! ocean time-step
60      !!
61      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
62      CHARACTER(LEN=50)   ::   clname   ! ice output restart file name
63      !!----------------------------------------------------------------------
64      !
65      IF( kt == nit000 ) THEN   ! default definitions
66         lrst_oce = .FALSE.   
67         nitrst = nitend
68      ENDIF
69      IF( MOD( kt - 1, nstock ) == 0 ) THEN   
70         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
71         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
72         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
73      ENDIF
74      ! to get better performances with NetCDF format:
75      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
76      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
77      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
78         ! beware of the format used to write kt (default is i8.8, that should be large enough...)
79         IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
80         ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
81         ENDIF
82         ! create the file
83         clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
84         IF(lwp) THEN
85            WRITE(numout,*)
86            SELECT CASE ( jprstlib )
87            CASE ( jprstdimg )   ;   WRITE(numout,*) '             open ocean restart binary file: '//clname
88            CASE DEFAULT         ;   WRITE(numout,*) '             open ocean restart NetCDF file: '//clname
89            END SELECT
90            IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
91            ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
92            ENDIF
93         ENDIF
94
95         CALL iom_open( clname, numrow, ldwrt = .TRUE., kiolib = jprstlib )
96         lrst_oce = .TRUE.
97      ENDIF
98      !
99   END SUBROUTINE rst_opn
100
101
102   SUBROUTINE rst_write( kt )
103      !!---------------------------------------------------------------------
104      !!                   ***  ROUTINE rstwrite  ***
105      !!                     
106      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
107      !!
108      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
109      !!      file, save fields which are necessary for restart
110      !!----------------------------------------------------------------------
111      INTEGER, INTENT(in) ::   kt   ! ocean time-step
112      !!----------------------------------------------------------------------
113
114      !                                                                     ! the begining of the run [s]
115      CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt               )   ! dynamics time step
116      CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1)         )   ! surface tracer time step
117
118      ! prognostic variables
119      CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub      )   
120      CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb      )
121      CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tb      )
122      CALL iom_rstput( kt, nitrst, numrow, 'sb'     , sb      )
123      CALL iom_rstput( kt, nitrst, numrow, 'rotb'   , rotb    )
124      CALL iom_rstput( kt, nitrst, numrow, 'hdivb'  , hdivb   )
125      CALL iom_rstput( kt, nitrst, numrow, 'un'     , un      )
126      CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn      )
127      CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tn      )
128      CALL iom_rstput( kt, nitrst, numrow, 'sn'     , sn      )
129      CALL iom_rstput( kt, nitrst, numrow, 'rotn'   , rotn    )
130      CALL iom_rstput( kt, nitrst, numrow, 'hdivn'  , hdivn   )
131
132      CALL iom_rstput( kt, nitrst, numrow, 'rhop'  , rhop   )
133
134      IF( lk_zdfddm )   CALL iom_rstput( kt, nitrst, numrow, 'rrau' , rrau  )
135
136      IF( kt == nitrst ) THEN
137         CALL iom_close( numrow )     ! close the restart file (only at last time step)
138         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
139      ENDIF
140      !
141   END SUBROUTINE rst_write
142
143
144   SUBROUTINE rst_read
145      !!----------------------------------------------------------------------
146      !!                   ***  ROUTINE rst_read  ***
147      !!
148      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
149      !!
150      !! ** Method  :   Read the previous fields on the NetCDF/binary file
151      !!      the first record indicates previous characterics
152      !!      after control with the present run, we read :
153      !!      - prognostic variables on the second record
154      !!      - elliptic solver arrays
155      !!      - barotropic stream function arrays ("key_dynspg_rl" defined)
156      !!        or free surface arrays
157      !!      - tke arrays (lk_zdftke=T .OR. lk_zdftke2=T)
158      !!      for this last three records,  the previous characteristics
159      !!      could be different with those used in the present run.
160      !!----------------------------------------------------------------------
161      REAL(wp) ::   zrdt, zrdttra1
162      INTEGER  ::   jlibalt = jprstlib
163      LOGICAL  ::   llok
164      !!----------------------------------------------------------------------
165
166      IF(lwp) THEN                                             ! Contol prints
167         WRITE(numout,*)
168         SELECT CASE ( jprstlib )
169         CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
170         CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
171         END SELECT
172         WRITE(numout,*) '~~~~~~~~'
173      ENDIF
174
175      IF ( jprstlib == jprstdimg ) THEN
176        ! eventually read netcdf file (monobloc)  for restarting on different number of processors
177        ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
178        INQUIRE( FILE = TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
179        IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
180      ENDIF
181      CALL iom_open( cn_ocerst_in, numror, kiolib = jlibalt )
182
183      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
184      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
185         CALL iom_get( numror, 'rdt', zrdt )
186         IF( zrdt /= rdt )   neuler = 0
187      ENDIF
188      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
189         CALL iom_get( numror, 'rdttra1', zrdttra1 )
190         IF( zrdttra1 /= rdttra(1) )   neuler = 0
191      ENDIF
192      !                                                       ! Read prognostic variables
193      CALL iom_get( numror, jpdom_autoglo, 'ub'   , ub    )        ! before i-component velocity
194      CALL iom_get( numror, jpdom_autoglo, 'vb'   , vb    )        ! before j-component velocity
195      CALL iom_get( numror, jpdom_autoglo, 'tb'   , tb    )        ! before temperature
196      CALL iom_get( numror, jpdom_autoglo, 'sb'   , sb    )        ! before salinity
197      CALL iom_get( numror, jpdom_autoglo, 'rotb' , rotb  )        ! before curl
198      CALL iom_get( numror, jpdom_autoglo, 'hdivb', hdivb )        ! before horizontal divergence
199      CALL iom_get( numror, jpdom_autoglo, 'un'   , un    )        ! now    i-component velocity
200      CALL iom_get( numror, jpdom_autoglo, 'vn'   , vn    )        ! now    j-component velocity
201      CALL iom_get( numror, jpdom_autoglo, 'tn'   , tn    )        ! now    temperature
202      CALL iom_get( numror, jpdom_autoglo, 'sn'   , sn    )        ! now    salinity
203      CALL iom_get( numror, jpdom_autoglo, 'rotn' , rotn  )        ! now    curl
204      CALL iom_get( numror, jpdom_autoglo, 'hdivn', hdivn )        ! now    horizontal divergence
205
206      CALL iom_get( numror, jpdom_autoglo, 'rhop', rhop )          ! now    mixed layer depth
207
208      IF( lk_zdfddm ) THEN
209         IF( iom_varid( numror, 'rrau', ldstop = .FALSE. ) > 0 ) THEN
210            CALL iom_get( numror, jpdom_autoglo, 'rrau' , rrau  )
211         ELSE
212            CALL eos_init                   ! read equation state type neos parameter
213            CALL eos( tb, sb, rhd, rhop )   ! compute rrau
214         ENDIF
215      ENDIF
216
217      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
218         tb   (:,:,:) = tn   (:,:,:)                             ! all before fields set to now field values
219         sb   (:,:,:) = sn   (:,:,:)
220         ub   (:,:,:) = un   (:,:,:)
221         vb   (:,:,:) = vn   (:,:,:)
222         rotb (:,:,:) = rotn (:,:,:)
223         hdivb(:,:,:) = hdivn(:,:,:)
224      ENDIF
225      !
226   END SUBROUTINE rst_read
227
228
229   !!=====================================================================
230END MODULE restart
Note: See TracBrowser for help on using the repository browser.