source: trunk/NEMO/TOP_SRC/PISCES/p4zlys.F90 @ 1735

Last change on this file since 1735 was 1735, checked in by cetlod, 11 years ago

suppress useless variables in TOP modules, see ticket:602

  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 8.9 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!----------------------------------------------------------------------
12#if defined key_pisces
13   !!----------------------------------------------------------------------
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_lys        :   Compute the CaCO3 dissolution
17   !!   p4z_lys_init   :   Read the namelist parameters
18   !!----------------------------------------------------------------------
19   USE trc
20   USE oce_trc         !
21   USE trc
22   USE sms_pisces
23   USE prtctl_trc
24   USE iom
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_lys    ! called in p4zprg.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::   &
33     kdca = 0.327e3_wp   ,  &  !:
34     nca  = 1.0_wp             !:
35
36   !! * Module variables
37   REAL(wp) :: &
38      calcon = 1.03E-2        ! mean calcite concentration [Ca2+] in sea water [mole/kg solution]
39
40   INTEGER ::               &
41     rmtss                    !: number of seconds per month
42
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
45   !! $Id$
46   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48
49CONTAINS
50
51   SUBROUTINE p4z_lys( kt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_lys  ***
54      !!
55      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
56      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
57      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT(in) ::   kt ! ocean time step
62      INTEGER  ::   ji, jj, jk, jn
63      REAL(wp) ::   zbot, zalk, zdic, zph, zremco3, zah2
64      REAL(wp) ::   zdispot, zfact, zalka
65      REAL(wp) ::   zomegaca, zexcess, zexcess0
66      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zco3
67#if defined key_trc_dia3d && defined key_iomput
68      REAL(wp) ::   zrfact2
69      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zcaldiss, zw3d
70#endif
71      CHARACTER (len=25) :: charout
72      !!---------------------------------------------------------------------
73
74      IF( kt == nittrc000  )   CALL p4z_lys_init      ! Initialization (first time-step only)
75
76      zco3(:,:,:) = 0.
77
78# if defined key_trc_dia3d && defined key_iomput
79      zcaldiss(:,:,:) = 0.
80# endif
81      !     -------------------------------------------
82      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
83      !     -------------------------------------------
84     
85      DO jn = 1, 5                               !  BEGIN OF ITERATION
86         !
87!CDIR NOVERRCHK
88         DO jk = 1, jpkm1
89!CDIR NOVERRCHK
90            DO jj = 1, jpj
91!CDIR NOVERRCHK
92               DO ji = 1, jpi
93
94                  ! SET DUMMY VARIABLE FOR TOTAL BORATE
95                  zbot  = borat(ji,jj,jk)
96                  zfact = rhop (ji,jj,jk) / 1000. + rtrn
97
98                  ! SET DUMMY VARIABLE FOR [H+]
99                  zph   = hi(ji,jj,jk) * tmask(ji,jj,jk) / zfact + ( 1.-tmask(ji,jj,jk) ) * 1.e-9
100
101                  ! SET DUMMY VARIABLE FOR [SUM(CO2)]GIVEN
102                  zdic  = trn(ji,jj,jk,jpdic) / zfact
103                  zalka = trn(ji,jj,jk,jptal) / zfact
104
105                  ! CALCULATE [ALK]([CO3--], [HCO3-])
106                  zalk  = zalka - (  akw3(ji,jj,jk) / zph - zph   &
107                     &             + zbot / (1.+ zph / akb3(ji,jj,jk) )  )
108
109                  ! CALCULATE [H+] and [CO3--]
110                  zah2 = SQRT( (zdic-zalk)*(zdic-zalk)+   &
111                     &     4.*(zalk*ak23(ji,jj,jk)/ak13(ji,jj,jk))   &
112                     &     *(2*zdic-zalk))
113
114                  zah2=0.5*ak13(ji,jj,jk)/zalk*((zdic-zalk)+zah2)
115                  zco3(ji,jj,jk) = zalk/(2.+zah2/ak23(ji,jj,jk))*zfact
116
117                  hi(ji,jj,jk)  = zah2*zfact
118
119               END DO
120            END DO
121         END DO
122         !
123      END DO 
124
125      !     ---------------------------------------------------------
126      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
127      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
128      !        MGCO3)
129      !     ---------------------------------------------------------
130
131      DO jk = 1, jpkm1
132         DO jj = 1, jpj
133            DO ji = 1, jpi
134
135               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
136               zomegaca = ( calcon * zco3(ji,jj,jk) ) / aksp(ji,jj,jk)
137
138               ! SET DEGREE OF UNDER-/SUPERSATURATION
139               zexcess0 = MAX( 0., ( 1.- zomegaca ) )
140               zexcess  = zexcess0**nca
141
142               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
143               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
144               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
145# if defined key_off_degrad
146              zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal) * facvol(ji,jj,jk)
147# else
148              zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal)
149# endif
150
151              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
152              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
153              zremco3 = zdispot / rmtss
154              zco3(ji,jj,jk) = zco3(ji,jj,jk) + zremco3 * rfact
155              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zremco3
156              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zremco3
157              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zremco3
158
159# if defined key_trc_dia3d && defined key_iomput
160              zcaldiss(ji,jj,jk) = zremco3  ! calcite dissolution
161# endif
162            END DO
163         END DO
164      END DO
165
166# if defined key_trc_diaadd &&  defined key_trc_dia3d
167#  if ! defined key_iomput
168      trc3d(:,:,:,jp_pcs0_3d    ) = hi  (:,:,:)          * tmask(:,:,:)
169      trc3d(:,:,:,jp_pcs0_3d + 1) = zco3(:,:,:)          * tmask(:,:,:)
170      trc3d(:,:,:,jp_pcs0_3d + 2) = aksp(:,:,:) / calcon * tmask(:,:,:)
171#  else
172      zrfact2 = 1.e3 * rfact2r
173      zw3d(:,:,:) = hi  (:,:,:)                    * tmask(:,:,:)
174      CALL iom_put( "PH", zw3d )
175      zw3d(:,:,:) = zco3(:,:,:)                    * tmask(:,:,:)
176      CALL iom_put( "CO3", zw3d )
177      zw3d(:,:,:) = aksp(:,:,:) / calcon           * tmask(:,:,:)
178      CALL iom_put( "CO3sat", zw3d )
179      zw3d(:,:,:) = zcaldiss(:,:,:) * zrfact2 * tmask(:,:,:)
180      CALL iom_put( "Dcal", zw3d )
181#  endif
182# endif
183      !
184       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
185         WRITE(charout, FMT="('lys ')")
186         CALL prt_ctl_trc_info(charout)
187         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
188       ENDIF
189
190   END SUBROUTINE p4z_lys
191
192   SUBROUTINE p4z_lys_init
193
194      !!----------------------------------------------------------------------
195      !!                  ***  ROUTINE p4z_lys_init  ***
196      !!
197      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
198      !!
199      !! ** Method  :   Read the nampiscal namelist and check the parameters
200      !!      called at the first timestep (nittrc000)
201      !!
202      !! ** input   :   Namelist nampiscal
203      !!
204      !!----------------------------------------------------------------------
205
206      NAMELIST/nampiscal/ kdca, nca
207
208      REWIND( numnat )                     ! read numnat
209      READ  ( numnat, nampiscal )
210
211      IF(lwp) THEN                         ! control print
212         WRITE(numout,*) ' '
213         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
214         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
215         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
216         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
217      ENDIF
218
219      ! Number of seconds per month
220      rmtss =  nyear_len(1) * rday / raamo
221
222   END SUBROUTINE p4z_lys_init
223
224#else
225   !!======================================================================
226   !!  Dummy module :                                   No PISCES bio-model
227   !!======================================================================
228CONTAINS
229   SUBROUTINE p4z_lys( kt )                   ! Empty routine
230      INTEGER, INTENT( in ) ::   kt
231      WRITE(*,*) 'p4z_lys: You should not have seen this print! error?', kt
232   END SUBROUTINE p4z_lys
233#endif 
234
235   !!======================================================================
236END MODULE  p4zlys
Note: See TracBrowser for help on using the repository browser.