New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in trunk/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMO/TOP_SRC/PISCES/p4zsink.F90 @ 1180

Last change on this file since 1180 was 1180, checked in by cetlod, 16 years ago

update PISCES modules to couple with the sediment model, see ticket:249
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 28.1 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :   PISCES Compute vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8#if defined key_pisces
9   !!----------------------------------------------------------------------
10   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
11   !!----------------------------------------------------------------------
12   USE trc
13   USE oce_trc         !
14   USE sms_pisces
15   USE prtctl_trc
16
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   p4z_sink    ! called in p4zbio.F90
22
23   !! * Shared module variables
24   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   &   !:
25     wsbio3, wsbio4,      &    !: POC and GOC sinking speeds
26     wscal                     !: Calcite and BSi sinking speeds
27
28   !! * Module variables
29   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   &   !:
30     sinking, sinking2,   &    !: POC sinking fluxes (different meanings depending on the parameterization
31     sinkcal, sinksil,    &    !: CaCO3 and BSi sinking fluxes
32     sinkfer                   !: Small BFe sinking flux
33
34#if  defined key_kriest
35   REAL(wp)          ::       &   
36      xkr_sfact    = 250.  ,  &   !: Sinking factor
37      xkr_stick    = 0.2   ,  &   !: Stickiness
38      xkr_nnano    = 2.337 ,  &   !: Nbr of cell in nano size class
39      xkr_ndiat    = 3.718 ,  &   !: Nbr of cell in diatoms size class
40      xkr_nmeso    = 7.147 ,  &   !: Nbr of cell in mesozoo  size class
41      xkr_naggr    = 9.877        !: Nbr of cell in aggregates  size class
42
43   REAL(wp)          ::       &   
44      xkr_frac
45
46   REAL(wp), PUBLIC ::        &
47      xkr_dnano            ,  &   !: Size of particles in nano pool
48      xkr_ddiat            ,  &   !: Size of particles in diatoms pool
49      xkr_dmeso            ,  &   !: Size of particles in mesozoo pool
50      xkr_daggr            ,  &   !: Size of particles in aggregates pool
51      xkr_wsbio_min        ,  &   !: min vertical particle speed
52      xkr_wsbio_max               !: max vertical particle speed
53
54   REAL(wp), PUBLIC, DIMENSION(jpk) ::   &   !:
55      xnumm                       !:     maximum number of particles in aggregates
56
57#endif
58
59#if ! defined key_kriest
60   REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &   !:
61     sinkfer2                  !: Big Fe sinking flux
62#endif 
63
64   !!* Substitution
65#  include "domzgr_substitute.h90"
66   !!----------------------------------------------------------------------
67   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
68   !! $Id$
69   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71
72CONTAINS
73
74#if defined key_kriest
75
76   SUBROUTINE p4z_sink ( kt, jnt )
77      !!---------------------------------------------------------------------
78      !!                ***  ROUTINE p4z_sink  ***
79      !!
80      !! ** Purpose :   Compute vertical flux of particulate matter due to
81      !!              gravitational sinking - Kriest parameterization
82      !!
83      !! ** Method  : - ???
84      !!---------------------------------------------------------------------
85
86      INTEGER, INTENT(in) :: kt, jnt
87      INTEGER  :: ji, jj, jk
88      INTEGER  :: iksed
89      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zaggsi, zaggsh
90      REAL(wp) :: zagg , zaggdoc, znumdoc
91      REAL(wp) :: znum , zeps, zfm, zgm, zsm
92      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
93      REAL(wp) :: zval1, zval2, zval3, zval4
94      REAL(wp) :: zstep
95#if defined key_trc_dia3d
96      REAL(wp) ::   zrfact2
97#endif
98      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znum3d
99      CHARACTER (len=25) :: charout
100
101      !!---------------------------------------------------------------------
102
103      IF( ( kt * jnt ) == nittrc000  )   CALL p4z_sink_init   ! Initialization (first time-step only)
104
105       zstep = rfact2 / rjjss      ! Time step duration for biology
106
107
108!     Initialisation of variables used to compute Sinking Speed
109!     ---------------------------------------------------------
110
111       znum3d(:,:,:) = 0.e0
112       iksed = 10
113       zval1 = 1. + xkr_zeta
114       zval2 = 1. + xkr_zeta + xkr_eta
115       zval3 = 1. + xkr_eta
116
117!     Computation of the vertical sinking speed : Kriest et Evans, 2000
118!     -----------------------------------------------------------------
119
120      DO jk = 1, jpkm1
121         DO jj = 1, jpj
122            DO ji = 1, jpi
123               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
124                  znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
125! -------------- To avoid sinking speed over 50 m/day -------
126                  znum  = MIN( xnumm(jk), znum )
127                  znum  = MAX( 1.1      , znum )
128                  znum3d(ji,jj,jk) = znum
129!------------------------------------------------------------
130                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
131                  zfm   = xkr_frac**( 1. - zeps )
132                  zgm   = xkr_frac**( zval1 - zeps )
133                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
134                  zdiv1 = zeps - zval3
135                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
136     &                             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
137                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
138     &                             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
139                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
140               ENDIF
141            END DO
142         END DO
143      END DO
144
145      wscal(:,:,:) = MAX( wsbio3(:,:,:), 50. )
146
147
148!   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
149!   -----------------------------------------
150
151      sinking (:,:,:) = 0.e0
152      sinking2(:,:,:) = 0.e0
153      sinkcal (:,:,:) = 0.e0
154      sinkfer (:,:,:) = 0.e0
155      sinksil (:,:,:) = 0.e0
156
157!   Compute the sedimentation term using p4zsink2 for all
158!   the sinking particles
159!   -----------------------------------------------------
160
161      CALL p4z_sink2( wsbio3, sinking , jppoc )
162      CALL p4z_sink2( wsbio4, sinking2, jpnum )
163      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
164      CALL p4z_sink2( wscal , sinksil , jpdsi )
165      CALL p4z_sink2( wscal , sinkcal , jpcal )
166
167!  Exchange between organic matter compartments due to
168!  coagulation/disaggregation
169!  ---------------------------------------------------
170
171      zval1 = 1. + xkr_zeta
172      zval2 = 1. + xkr_eta
173      zval3 = 3. + xkr_eta
174      zval4 = 4. + xkr_eta
175
176      DO jk = 1,jpkm1
177         DO jj = 1,jpj
178            DO ji = 1,jpi
179               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
180
181                  znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp
182! -------------- To avoid sinking speed over 50 m/day -------
183                  znum  = min(xnumm(jk),znum)
184                  znum  = MAX( 1.1,znum)
185!------------------------------------------------------------
186                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
187                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
188                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
189                  zdiv2 = zeps - 2.
190                  zdiv3 = zeps - 3.
191                  zdiv4 = zeps - zval2
192                  zdiv5 = 2.* zeps - zval4
193                  zfm   = xkr_frac**( 1.- zeps )
194                  zsm   = xkr_frac**xkr_eta
195
196!    Part I : Coagulation dependant on turbulence
197!    ----------------------------------------------
198
199                  zagg1 = ( 0.163 * trn(ji,jj,jk,jpnum)**2               &
200                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
201                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
202                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
203                     &            * (zeps-1.)**2/(zdiv2*zdiv3))            &
204# if defined key_off_degrad
205                     &                 *facvol(ji,jj,jk)       &
206# endif
207                     &    )
208
209                  zagg2 = (  2*0.163*trn(ji,jj,jk,jpnum)**2*zfm*                       &
210                     &                   ((xkr_mass_max**3+3.*(xkr_mass_max**2          &
211                     &                    *xkr_mass_min*(zeps-1.)/zdiv2                 &
212                     &                    +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
213                     &                    +xkr_mass_min**3*(zeps-1)/zdiv1)                  &
214                     &                    -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/           &
215                     &                    (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))      &
216#    if defined key_off_degrad
217                     &                 *facvol(ji,jj,jk)             &
218#    endif
219                     &    )
220
221                  zagg3 = (  0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3   &
222#    if defined key_off_degrad
223                     &                 *facvol(ji,jj,jk)             &
224#    endif
225                     &    )
226
227                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
228
229!    Aggregation of small into large particles
230!    Part II : Differential settling
231!    ----------------------------------------------
232
233                  zagg4 = (  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2*                       &
234                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
235                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
236                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
237                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
238                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )                     &
239# if defined key_off_degrad
240                     &                 *facvol(ji,jj,jk)        &
241# endif
242                     &    )
243
244                  zagg5 = (  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2                         &
245                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
246                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
247                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
248                     &                 /zdiv)                   &
249# if defined key_off_degrad
250                     &                 *facvol(ji,jj,jk)        &
251# endif
252                     &    )
253
254                  zaggsi = ( zagg4 + zagg5 ) * zstep / 10.
255
256                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
257
258!     Aggregation of DOC to small particles
259!     --------------------------------------
260
261                  zaggdoc = ( 0.4 * trn(ji,jj,jk,jpdoc)               &
262                     &        + 1018.  * trn(ji,jj,jk,jppoc)  ) * zstep    &
263# if defined key_off_degrad
264                     &        * facvol(ji,jj,jk)                              &
265# endif
266                     &        * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
267
268                  znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
269                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc
270                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zaggdoc * znumdoc - zagg
271                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc
272
273               ENDIF
274            END DO
275         END DO
276      END DO
277
278#    if defined key_trc_dia3d
279      zrfact2 = 1.e3 * rfact2r
280      trc2d(:,:,  jp_pcs0_2d + 4)   = sinking (:,:,iksed+1) * zrfact2
281      trc2d(:,:,  jp_pcs0_2d + 5)   = sinking2(:,:,iksed+1) * zrfact2
282      trc2d(:,:,  jp_pcs0_2d + 6)   = sinkfer (:,:,iksed+1) * zrfact2
283      trc2d(:,:,  jp_pcs0_2d + 8)   = sinksil (:,:,iksed+1) * zrfact2
284      trc2d(:,:,  jp_pcs0_2d + 9)   = sinkcal (:,:,iksed+1) * zrfact2
285      trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)       * zrfact2
286      trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)       * zrfact2
287      trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)       * zrfact2
288      trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)       * zrfact2
289      trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)
290      trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)
291      trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)
292#    endif
293      !
294       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
295         WRITE(charout, FMT="('sink')")
296         CALL prt_ctl_trc_info(charout)
297         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
298       ENDIF
299
300   END SUBROUTINE p4z_sink
301
302   SUBROUTINE p4z_sink_init
303      !!----------------------------------------------------------------------
304      !!                  ***  ROUTINE p4z_sink_init  ***
305      !!
306      !! ** Purpose :   Initialization of sinking parameters
307      !!                Kriest parameterization only
308      !!
309      !! ** Method  :   Read the nampiskrs namelist and check the parameters
310      !!      called at the first timestep (nittrc000)
311      !!
312      !! ** input   :   Namelist nampiskrs
313      !!
314      !!----------------------------------------------------------------------
315      INTEGER  ::   jk, jn, kiter
316      REAL(wp) ::   znum, zdiv
317      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
318      REAL(wp) ::   zmin, zmax, zl, zr, xacc
319
320      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
321         &                xkr_nnano, xkr_ndiat, xkr_nmeso, xkr_naggr
322
323      !!----------------------------------------------------------------------
324      REWIND( numnat )                     ! read nampiskrs
325      READ  ( numnat, nampiskrs )
326
327      IF(lwp) THEN
328         WRITE(numout,*)
329         WRITE(numout,*) ' Namelist : nampiskrs'
330         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
331         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
332         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
333         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
334         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
335         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
336     ENDIF
337
338
339     ! max and min vertical particle speed
340     xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
341     xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
342     WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
343
344     !
345     !    effect of the sizes of the different living pools on particle numbers
346     !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
347     !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
348     !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
349     !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
350     !    doc aggregates = 1um
351     ! ----------------------------------------------------------
352
353     xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
354     xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
355     xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
356     xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
357
358      !!---------------------------------------------------------------------
359      !!    'key_kriest'                                                  ???
360      !!---------------------------------------------------------------------
361      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
362      !  Search of the maximum number of particles in aggregates for each k-level.
363      !  Bissection Method
364      !--------------------------------------------------------------------
365      WRITE(numout,*)
366      WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
367
368      xacc     =  0.001
369      kiter    = 50
370      zmin     =  1.10
371      zmax     = xkr_mass_max / xkr_mass_min
372      xkr_frac = zmax
373
374      DO jk = 1,jpk
375         zl = zmin
376         zr = zmax
377         wmax = 0.5 * fse3t(1,1,jk) * rjjss / rfact2
378         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
379         znum = zl - 1.
380         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
381            & - ( xkr_wsbio_max * xkr_eta * znum * &
382            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
383            & - wmax
384
385         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
386         znum = zr - 1.
387         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
388            & - ( xkr_wsbio_max * xkr_eta * znum * &
389            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
390            & - wmax
391iflag:  DO jn = 1, kiter
392           IF( zwl == 0.e0 ) THEN
393              znummax = zl
394           ELSE IF ( zwr == 0.e0 ) THEN
395              znummax = zr
396           ELSE
397              znummax = ( zr + zl ) / 2.
398              zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
399              znum = znummax - 1.
400              zws =  xkr_wsbio_min * xkr_zeta / zdiv &
401                 & - ( xkr_wsbio_max * xkr_eta * znum * &
402                 &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
403                 & - wmax
404              IF( zws * zwl < 0. ) THEN
405                 zr = znummax
406              ELSE
407                 zl = znummax
408              ENDIF
409              zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
410              znum = zl - 1.
411              zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
412                 & - ( xkr_wsbio_max * xkr_eta * znum * &
413                 &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
414                 & - wmax
415
416              zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
417              znum = zr - 1.
418              zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
419                 & - ( xkr_wsbio_max * xkr_eta * znum * &
420                 &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
421                 & - wmax
422
423              IF ( ABS ( zws )  <= xacc ) EXIT iflag
424
425           ENDIF
426
427        END DO iflag
428
429        xnumm(jk) = znummax
430        WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
431
432     END DO
433
434  END SUBROUTINE p4z_sink_init
435
436#else
437
438   SUBROUTINE p4z_sink ( kt, jnt )
439      !!---------------------------------------------------------------------
440      !!                     ***  ROUTINE p4z_sink  ***
441      !!
442      !! ** Purpose :   Compute vertical flux of particulate matter due to
443      !!                gravitational sinking
444      !!
445      !! ** Method  : - ???
446      !!---------------------------------------------------------------------
447      INTEGER, INTENT(in) :: kt, jnt
448      INTEGER  ::   ji, jj, jk
449      INTEGER  ::   iksed
450      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
451      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2
452      REAL(wp) ::   zfact, zstep, zwsmax
453#if defined key_trc_dia3d
454      REAL(wp) ::   zrfact2
455#endif
456      CHARACTER (len=25) :: charout
457      !!---------------------------------------------------------------------
458
459       zstep = rfact2 / rjjss      ! Timestep duration for biology
460
461
462!    Sinking speeds of detritus is increased with depth as shown
463!    by data and from the coagulation theory
464!    -----------------------------------------------------------
465
466      iksed = 10
467
468      DO jk = 1, jpkm1
469         DO jj = 1, jpj
470            DO ji=1,jpi
471               zfact = MAX( 0., fsdepw(ji,jj,jk+1)-hmld(ji,jj) ) / 4000.
472               wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact
473            END DO
474         END DO
475      END DO
476
477!      LIMIT THE VALUES OF THE SINKING SPEEDS
478!      TO AVOID NUMERICAL INSTABILITIES
479
480      wsbio3(:,:,:) = wsbio
481!
482! OA Below, this is garbage. the ideal would be to find a time-splitting
483! OA algorithm that does not increase the computing cost by too much
484! OA In ROMS, I have included a time-splitting procedure. But it is
485! OA too expensive as the loop is computed globally. Thus, a small e3t
486! OA at one place determines the number of subtimesteps globally
487! OA AWFULLY EXPENSIVE !! Not able to find a better approach. Damned !!
488
489      DO jk = 1,jpkm1
490         DO jj = 1, jpj
491            DO ji = 1, jpi
492               zwsmax = 0.8 * fse3t(ji,jj,jk) / zstep
493               wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax )
494               wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax )
495            END DO
496         END DO
497      END DO
498
499      wscal(:,:,:) = wsbio4(:,:,:)
500
501!   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
502!   -----------------------------------------
503
504      sinking (:,:,:) = 0.e0
505      sinking2(:,:,:) = 0.e0
506      sinkcal (:,:,:) = 0.e0
507      sinkfer (:,:,:) = 0.e0
508      sinksil (:,:,:) = 0.e0
509      sinkfer2(:,:,:) = 0.e0
510
511!   Compute the sedimentation term using p4zsink2 for all
512!   the sinking particles
513!   -----------------------------------------------------
514
515      CALL p4z_sink2( wsbio3, sinking , jppoc )
516      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
517      CALL p4z_sink2( wsbio4, sinking2, jpgoc )
518      CALL p4z_sink2( wsbio4, sinkfer2, jpbfe )
519      CALL p4z_sink2( wsbio4, sinksil , jpdsi )
520      CALL p4z_sink2( wscal , sinkcal , jpcal )
521
522!  Exchange between organic matter compartments due to
523!  coagulation/disaggregation
524!  ---------------------------------------------------
525
526      DO jk = 1, jpkm1
527         DO jj = 1, jpj
528            DO ji = 1, jpi
529               zfact = zstep * xdiss(ji,jj,jk)
530
531!    Part I : Coagulation dependent on turbulence
532!    ----------------------------------------------
533
534# if defined key_off_degrad
535               zagg1 = 940.* zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc) * facvol(ji,jj,jk)
536# else
537               zagg1 = 940.* zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
538# endif
539
540# if defined key_off_degrad
541               zagg2 = 1.054e4 * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc) * facvol(ji,jj,jk)
542# else
543               zagg2 = 1.054e4 * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
544# endif
545
546!    Aggregation of small into large particles
547!    Part II : Differential settling
548!    ----------------------------------------------
549
550# if defined key_off_degrad
551               zagg3 = 0.66 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc) * facvol(ji,jj,jk)
552# else
553               zagg3 = 0.66 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
554# endif
555
556# if defined key_off_degrad
557               zagg4 = 0.e0 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc) * facvol(ji,jj,jk)
558# else
559               zagg4 = 0.e0 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
560# endif
561
562               zagg   = zagg1 + zagg2 + zagg3 + zagg4
563               zaggfe = zagg * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn )
564
565!     Aggregation of DOC to small particles
566!     --------------------------------------
567
568               zaggdoc = ( 80.* trn(ji,jj,jk,jpdoc) + 698. * trn(ji,jj,jk,jppoc) )       &
569# if defined key_off_degrad
570                  &      * facvol(ji,jj,jk)                           &
571# endif
572                  &      * zfact * trn(ji,jj,jk,jpdoc)
573
574               zaggdoc2 = 1.05e4 * zfact * trn(ji,jj,jk,jpgoc)   &
575# if defined key_off_degrad
576                  &        * facvol(ji,jj,jk)                            &
577# endif     
578                  &        * trn(ji,jj,jk,jpdoc)
579!
580!  Update the trends
581!  -----------------
582!
583               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc
584               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2
585               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
586               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
587               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2
588
589            END DO
590         END DO
591      END DO
592
593# if defined key_trc_diaadd
594      zrfact2 = 1.e3 * rfact2r
595      trc2d(:,:, jp_pcs0_2d + 4) = sinking (:,:,iksed+1) * zrfact2
596      trc2d(:,:, jp_pcs0_2d + 5) = sinking2(:,:,iksed+1) * zrfact2
597      trc2d(:,:, jp_pcs0_2d + 6) = sinkfer (:,:,iksed+1) * zrfact2
598      trc2d(:,:, jp_pcs0_2d + 7) = sinkfer2(:,:,iksed+1) * zrfact2
599      trc2d(:,:, jp_pcs0_2d + 8) = sinksil (:,:,iksed+1) * zrfact2
600      trc2d(:,:, jp_pcs0_2d + 9) = sinkcal (:,:,iksed+1) * zrfact2
601# endif
602      !
603       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
604         WRITE(charout, FMT="('sink')")
605         CALL prt_ctl_trc_info(charout)
606         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
607       ENDIF
608
609   END SUBROUTINE p4z_sink
610
611#endif
612
613   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra )
614      !!---------------------------------------------------------------------
615      !!                     ***  ROUTINE p4z_sink2  ***
616      !!
617      !! ** Purpose :   Compute the sedimentation terms for the various sinking
618      !!     particles. The scheme used to compute the trends is based
619      !!     on MUSCL.
620      !!
621      !! ** Method  : - this ROUTINE compute not exactly the advection but the
622      !!      transport term, i.e.  div(u*tra).
623      !!---------------------------------------------------------------------
624      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
625      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
626      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
627      !!
628      INTEGER  ::   ji, jj, jk, jn
629      REAL(wp) ::   zigma,zew,zstep,zign, zflx
630      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  ztraz, zakz
631      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zwsink2
632      !!---------------------------------------------------------------------
633
634      zstep  = rfact2 / 2.
635
636      ztraz(:,:,:) = 0.e0
637      zakz (:,:,:) = 0.e0
638
639      DO jk = 1, jpkm1
640# if defined key_off_degrad
641         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rjjss * tmask(:,:,jk+1) * facvol(:,:,jk)
642# else
643         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rjjss * tmask(:,:,jk+1)
644# endif
645      END DO
646      zwsink2(:,:,1) = 0.e0
647
648
649      ! Vertical advective flux
650      DO jn = 1, 2
651         !  first guess of the slopes interior values
652         DO jk = 2, jpkm1
653            ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk)
654         END DO
655         ztraz(:,:,1  ) = 0.0
656         ztraz(:,:,jpk) = 0.0
657
658         ! slopes
659         DO jk = 2, jpkm1
660            DO jj = 1,jpj
661               DO ji = 1, jpi
662                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
663                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
664               END DO
665            END DO
666         END DO
667         
668         ! Slopes limitation
669         DO jk = 2, jpkm1
670            DO jj = 1, jpj
671               DO ji = 1, jpi
672                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
673                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
674               END DO
675            END DO
676         END DO
677         
678         ! vertical advective flux
679         DO jk = 1, jpkm1
680            DO jj = 1, jpj     
681               DO ji = 1, jpi   
682                  zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1)
683                  zew   = zwsink2(ji,jj,jk+1)
684                  psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
685               END DO
686            END DO
687         END DO
688         !
689         ! Boundary conditions
690         psinkflx(:,:,1  ) = 0.e0
691         psinkflx(:,:,jpk) = 0.e0
692         
693         DO jk=1,jpkm1
694            DO jj = 1,jpj
695               DO ji = 1, jpi
696                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
697                  trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx
698               END DO
699            END DO
700         END DO
701
702      ENDDO
703
704      DO jk=1,jpkm1
705         DO jj = 1,jpj
706            DO ji = 1, jpi
707               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
708               trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + 2. * zflx
709            END DO
710         END DO
711      END DO
712
713      trn(:,:,:,jp_tra) = trb(:,:,:,jp_tra)
714      psinkflx(:,:,:)   = 2. * psinkflx(:,:,:)
715
716      !
717   END SUBROUTINE p4z_sink2
718
719#else
720   !!======================================================================
721   !!  Dummy module :                                   No PISCES bio-model
722   !!======================================================================
723CONTAINS
724   SUBROUTINE p4z_sink                    ! Empty routine
725   END SUBROUTINE p4z_sink
726#endif 
727
728   !!======================================================================
729END MODULE  p4zsink
Note: See TracBrowser for help on using the repository browser.