New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in trunk/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMO/TOP_SRC/PISCES/p4zsink.F90 @ 1264

Last change on this file since 1264 was 1264, checked in by cetlod, 15 years ago

clean TOP model routines to avoid warning when compiling, see ticket:303
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 28.3 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :   PISCES Compute vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8#if defined key_pisces
9   !!----------------------------------------------------------------------
10   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
11   !!----------------------------------------------------------------------
12   USE trc
13   USE oce_trc         !
14   USE sms_pisces
15   USE prtctl_trc
16
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   p4z_sink    ! called in p4zbio.F90
22
23   !! * Shared module variables
24   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   &   !:
25     wsbio3, wsbio4,      &    !: POC and GOC sinking speeds
26     wscal                     !: Calcite and BSi sinking speeds
27
28   !! * Module variables
29   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   &   !:
30     sinking, sinking2,   &    !: POC sinking fluxes (different meanings depending on the parameterization
31     sinkcal, sinksil,    &    !: CaCO3 and BSi sinking fluxes
32     sinkfer                   !: Small BFe sinking flux
33
34   REAL(wp) ::   &
35     xstep , xstep2            !: Time step duration for biology
36
37#if  defined key_kriest
38   REAL(wp)          ::       &   
39      xkr_sfact    = 250.  ,  &   !: Sinking factor
40      xkr_stick    = 0.2   ,  &   !: Stickiness
41      xkr_nnano    = 2.337 ,  &   !: Nbr of cell in nano size class
42      xkr_ndiat    = 3.718 ,  &   !: Nbr of cell in diatoms size class
43      xkr_nmeso    = 7.147 ,  &   !: Nbr of cell in mesozoo  size class
44      xkr_naggr    = 9.877        !: Nbr of cell in aggregates  size class
45
46   REAL(wp)          ::       &   
47      xkr_frac
48
49   REAL(wp), PUBLIC ::        &
50      xkr_dnano            ,  &   !: Size of particles in nano pool
51      xkr_ddiat            ,  &   !: Size of particles in diatoms pool
52      xkr_dmeso            ,  &   !: Size of particles in mesozoo pool
53      xkr_daggr            ,  &   !: Size of particles in aggregates pool
54      xkr_wsbio_min        ,  &   !: min vertical particle speed
55      xkr_wsbio_max               !: max vertical particle speed
56
57   REAL(wp), PUBLIC, DIMENSION(jpk) ::   &   !:
58      xnumm                       !:     maximum number of particles in aggregates
59
60#endif
61
62#if ! defined key_kriest
63   REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &   !:
64     sinkfer2                  !: Big Fe sinking flux
65#endif 
66
67   !!* Substitution
68#  include "domzgr_substitute.h90"
69   !!----------------------------------------------------------------------
70   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
71   !! $Id$
72   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
73   !!----------------------------------------------------------------------
74
75CONTAINS
76
77#if defined key_kriest
78
79   SUBROUTINE p4z_sink ( kt, jnt )
80      !!---------------------------------------------------------------------
81      !!                ***  ROUTINE p4z_sink  ***
82      !!
83      !! ** Purpose :   Compute vertical flux of particulate matter due to
84      !!              gravitational sinking - Kriest parameterization
85      !!
86      !! ** Method  : - ???
87      !!---------------------------------------------------------------------
88
89      INTEGER, INTENT(in) :: kt, jnt
90      INTEGER  :: ji, jj, jk
91      INTEGER  :: iksed
92      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zaggsi, zaggsh
93      REAL(wp) :: zagg , zaggdoc, znumdoc
94      REAL(wp) :: znum , zeps, zfm, zgm, zsm
95      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
96      REAL(wp) :: zval1, zval2, zval3, zval4
97#if defined key_trc_dia3d
98      REAL(wp) ::   zrfact2
99#endif
100      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znum3d
101      CHARACTER (len=25) :: charout
102
103      !!---------------------------------------------------------------------
104
105      IF( ( kt * jnt ) == nittrc000  )  THEN
106          CALL p4z_sink_init   ! Initialization (first time-step only)
107          xstep  = rfact2 / rjjss      ! Time step duration for biology
108          xstep2 = rfact2 /  2.
109      ENDIF
110
111!     Initialisation of variables used to compute Sinking Speed
112!     ---------------------------------------------------------
113
114       znum3d(:,:,:) = 0.e0
115       iksed = 10
116       zval1 = 1. + xkr_zeta
117       zval2 = 1. + xkr_zeta + xkr_eta
118       zval3 = 1. + xkr_eta
119
120!     Computation of the vertical sinking speed : Kriest et Evans, 2000
121!     -----------------------------------------------------------------
122
123      DO jk = 1, jpkm1
124         DO jj = 1, jpj
125            DO ji = 1, jpi
126               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
127                  znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
128! -------------- To avoid sinking speed over 50 m/day -------
129                  znum  = MIN( xnumm(jk), znum )
130                  znum  = MAX( 1.1      , znum )
131                  znum3d(ji,jj,jk) = znum
132!------------------------------------------------------------
133                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
134                  zfm   = xkr_frac**( 1. - zeps )
135                  zgm   = xkr_frac**( zval1 - zeps )
136                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
137                  zdiv1 = zeps - zval3
138                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
139     &                             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
140                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
141     &                             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
142                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
143               ENDIF
144            END DO
145         END DO
146      END DO
147
148      wscal(:,:,:) = MAX( wsbio3(:,:,:), 50. )
149
150
151!   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
152!   -----------------------------------------
153
154      sinking (:,:,:) = 0.e0
155      sinking2(:,:,:) = 0.e0
156      sinkcal (:,:,:) = 0.e0
157      sinkfer (:,:,:) = 0.e0
158      sinksil (:,:,:) = 0.e0
159
160!   Compute the sedimentation term using p4zsink2 for all
161!   the sinking particles
162!   -----------------------------------------------------
163
164      CALL p4z_sink2( wsbio3, sinking , jppoc )
165      CALL p4z_sink2( wsbio4, sinking2, jpnum )
166      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
167      CALL p4z_sink2( wscal , sinksil , jpdsi )
168      CALL p4z_sink2( wscal , sinkcal , jpcal )
169
170!  Exchange between organic matter compartments due to
171!  coagulation/disaggregation
172!  ---------------------------------------------------
173
174      zval1 = 1. + xkr_zeta
175      zval2 = 1. + xkr_eta
176      zval3 = 3. + xkr_eta
177      zval4 = 4. + xkr_eta
178
179      DO jk = 1,jpkm1
180         DO jj = 1,jpj
181            DO ji = 1,jpi
182               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
183
184                  znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp
185! -------------- To avoid sinking speed over 50 m/day -------
186                  znum  = min(xnumm(jk),znum)
187                  znum  = MAX( 1.1,znum)
188!------------------------------------------------------------
189                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
190                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
191                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
192                  zdiv2 = zeps - 2.
193                  zdiv3 = zeps - 3.
194                  zdiv4 = zeps - zval2
195                  zdiv5 = 2.* zeps - zval4
196                  zfm   = xkr_frac**( 1.- zeps )
197                  zsm   = xkr_frac**xkr_eta
198
199!    Part I : Coagulation dependant on turbulence
200!    ----------------------------------------------
201
202                  zagg1 = ( 0.163 * trn(ji,jj,jk,jpnum)**2               &
203                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
204                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
205                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
206                     &            * (zeps-1.)**2/(zdiv2*zdiv3))            &
207# if defined key_off_degrad
208                     &                 *facvol(ji,jj,jk)       &
209# endif
210                     &    )
211
212                  zagg2 = (  2*0.163*trn(ji,jj,jk,jpnum)**2*zfm*                       &
213                     &                   ((xkr_mass_max**3+3.*(xkr_mass_max**2          &
214                     &                    *xkr_mass_min*(zeps-1.)/zdiv2                 &
215                     &                    +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
216                     &                    +xkr_mass_min**3*(zeps-1)/zdiv1)                  &
217                     &                    -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/           &
218                     &                    (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))      &
219#    if defined key_off_degrad
220                     &                 *facvol(ji,jj,jk)             &
221#    endif
222                     &    )
223
224                  zagg3 = (  0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3   &
225#    if defined key_off_degrad
226                     &                 *facvol(ji,jj,jk)             &
227#    endif
228                     &    )
229
230                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
231
232!    Aggregation of small into large particles
233!    Part II : Differential settling
234!    ----------------------------------------------
235
236                  zagg4 = (  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2*                       &
237                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
238                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
239                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
240                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
241                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )                     &
242# if defined key_off_degrad
243                     &                 *facvol(ji,jj,jk)        &
244# endif
245                     &    )
246
247                  zagg5 = (  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2                         &
248                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
249                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
250                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
251                     &                 /zdiv)                   &
252# if defined key_off_degrad
253                     &                 *facvol(ji,jj,jk)        &
254# endif
255                     &    )
256
257                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
258
259                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
260
261!     Aggregation of DOC to small particles
262!     --------------------------------------
263
264                  zaggdoc = ( 0.4 * trn(ji,jj,jk,jpdoc)               &
265                     &        + 1018.  * trn(ji,jj,jk,jppoc)  ) * xstep    &
266# if defined key_off_degrad
267                     &        * facvol(ji,jj,jk)                              &
268# endif
269                     &        * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
270
271                  znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
272                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc
273                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zaggdoc * znumdoc - zagg
274                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc
275
276               ENDIF
277            END DO
278         END DO
279      END DO
280
281#    if defined key_trc_dia3d
282      zrfact2 = 1.e3 * rfact2r
283      trc2d(:,:,  jp_pcs0_2d + 4)   = sinking (:,:,iksed+1) * zrfact2
284      trc2d(:,:,  jp_pcs0_2d + 5)   = sinking2(:,:,iksed+1) * zrfact2
285      trc2d(:,:,  jp_pcs0_2d + 6)   = sinkfer (:,:,iksed+1) * zrfact2
286      trc2d(:,:,  jp_pcs0_2d + 8)   = sinksil (:,:,iksed+1) * zrfact2
287      trc2d(:,:,  jp_pcs0_2d + 9)   = sinkcal (:,:,iksed+1) * zrfact2
288      trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)       * zrfact2
289      trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)       * zrfact2
290      trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)       * zrfact2
291      trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)       * zrfact2
292      trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)
293      trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)
294      trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)
295#    endif
296      !
297       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
298         WRITE(charout, FMT="('sink')")
299         CALL prt_ctl_trc_info(charout)
300         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
301       ENDIF
302
303   END SUBROUTINE p4z_sink
304
305   SUBROUTINE p4z_sink_init
306      !!----------------------------------------------------------------------
307      !!                  ***  ROUTINE p4z_sink_init  ***
308      !!
309      !! ** Purpose :   Initialization of sinking parameters
310      !!                Kriest parameterization only
311      !!
312      !! ** Method  :   Read the nampiskrs namelist and check the parameters
313      !!      called at the first timestep (nittrc000)
314      !!
315      !! ** input   :   Namelist nampiskrs
316      !!
317      !!----------------------------------------------------------------------
318      INTEGER  ::   jk, jn, kiter
319      REAL(wp) ::   znum, zdiv
320      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
321      REAL(wp) ::   zmin, zmax, zl, zr, xacc
322
323      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
324         &                xkr_nnano, xkr_ndiat, xkr_nmeso, xkr_naggr
325
326      !!----------------------------------------------------------------------
327      REWIND( numnat )                     ! read nampiskrs
328      READ  ( numnat, nampiskrs )
329
330      IF(lwp) THEN
331         WRITE(numout,*)
332         WRITE(numout,*) ' Namelist : nampiskrs'
333         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
334         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
335         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
336         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
337         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
338         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
339     ENDIF
340
341
342     ! max and min vertical particle speed
343     xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
344     xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
345     WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
346
347     !
348     !    effect of the sizes of the different living pools on particle numbers
349     !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
350     !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
351     !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
352     !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
353     !    doc aggregates = 1um
354     ! ----------------------------------------------------------
355
356     xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
357     xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
358     xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
359     xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
360
361      !!---------------------------------------------------------------------
362      !!    'key_kriest'                                                  ???
363      !!---------------------------------------------------------------------
364      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
365      !  Search of the maximum number of particles in aggregates for each k-level.
366      !  Bissection Method
367      !--------------------------------------------------------------------
368      WRITE(numout,*)
369      WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
370
371      xacc     =  0.001
372      kiter    = 50
373      zmin     =  1.10
374      zmax     = xkr_mass_max / xkr_mass_min
375      xkr_frac = zmax
376
377      DO jk = 1,jpk
378         zl = zmin
379         zr = zmax
380         wmax = 0.5 * fse3t(1,1,jk) * rjjss / rfact2
381         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
382         znum = zl - 1.
383         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
384            & - ( xkr_wsbio_max * xkr_eta * znum * &
385            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
386            & - wmax
387
388         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
389         znum = zr - 1.
390         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
391            & - ( xkr_wsbio_max * xkr_eta * znum * &
392            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
393            & - wmax
394iflag:  DO jn = 1, kiter
395           IF( zwl == 0.e0 ) THEN
396              znummax = zl
397           ELSE IF ( zwr == 0.e0 ) THEN
398              znummax = zr
399           ELSE
400              znummax = ( zr + zl ) / 2.
401              zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
402              znum = znummax - 1.
403              zws =  xkr_wsbio_min * xkr_zeta / zdiv &
404                 & - ( xkr_wsbio_max * xkr_eta * znum * &
405                 &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
406                 & - wmax
407              IF( zws * zwl < 0. ) THEN
408                 zr = znummax
409              ELSE
410                 zl = znummax
411              ENDIF
412              zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
413              znum = zl - 1.
414              zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
415                 & - ( xkr_wsbio_max * xkr_eta * znum * &
416                 &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
417                 & - wmax
418
419              zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
420              znum = zr - 1.
421              zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
422                 & - ( xkr_wsbio_max * xkr_eta * znum * &
423                 &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
424                 & - wmax
425
426              IF ( ABS ( zws )  <= xacc ) EXIT iflag
427
428           ENDIF
429
430        END DO iflag
431
432        xnumm(jk) = znummax
433        WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
434
435     END DO
436
437  END SUBROUTINE p4z_sink_init
438
439#else
440
441   SUBROUTINE p4z_sink ( kt, jnt )
442      !!---------------------------------------------------------------------
443      !!                     ***  ROUTINE p4z_sink  ***
444      !!
445      !! ** Purpose :   Compute vertical flux of particulate matter due to
446      !!                gravitational sinking
447      !!
448      !! ** Method  : - ???
449      !!---------------------------------------------------------------------
450      INTEGER, INTENT(in) :: kt, jnt
451      INTEGER  ::   ji, jj, jk
452      INTEGER  ::   iksed
453      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
454      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2
455      REAL(wp) ::   zfact, zwsmax
456#if defined key_trc_dia3d
457      REAL(wp) ::   zrfact2
458#endif
459      CHARACTER (len=25) :: charout
460      !!---------------------------------------------------------------------
461
462      IF( ( kt * jnt ) == nittrc000  )  THEN
463          xstep  = rfact2 / rjjss      ! Timestep duration for biology
464          xstep2 = rfact2 /  2.
465      ENDIF
466
467!    Sinking speeds of detritus is increased with depth as shown
468!    by data and from the coagulation theory
469!    -----------------------------------------------------------
470
471      iksed = 10
472
473      DO jk = 1, jpkm1
474         DO jj = 1, jpj
475            DO ji=1,jpi
476               zfact = MAX( 0., fsdepw(ji,jj,jk+1)-hmld(ji,jj) ) / 4000.
477               wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact
478            END DO
479         END DO
480      END DO
481
482!      LIMIT THE VALUES OF THE SINKING SPEEDS
483!      TO AVOID NUMERICAL INSTABILITIES
484
485      wsbio3(:,:,:) = wsbio
486!
487! OA Below, this is garbage. the ideal would be to find a time-splitting
488! OA algorithm that does not increase the computing cost by too much
489! OA In ROMS, I have included a time-splitting procedure. But it is
490! OA too expensive as the loop is computed globally. Thus, a small e3t
491! OA at one place determines the number of subtimesteps globally
492! OA AWFULLY EXPENSIVE !! Not able to find a better approach. Damned !!
493
494      DO jk = 1,jpkm1
495         DO jj = 1, jpj
496            DO ji = 1, jpi
497               zwsmax = 0.8 * fse3t(ji,jj,jk) / xstep
498               wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax )
499               wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax )
500            END DO
501         END DO
502      END DO
503
504      wscal(:,:,:) = wsbio4(:,:,:)
505
506!   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
507!   -----------------------------------------
508
509      sinking (:,:,:) = 0.e0
510      sinking2(:,:,:) = 0.e0
511      sinkcal (:,:,:) = 0.e0
512      sinkfer (:,:,:) = 0.e0
513      sinksil (:,:,:) = 0.e0
514      sinkfer2(:,:,:) = 0.e0
515
516!   Compute the sedimentation term using p4zsink2 for all
517!   the sinking particles
518!   -----------------------------------------------------
519
520      CALL p4z_sink2( wsbio3, sinking , jppoc )
521      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
522      CALL p4z_sink2( wsbio4, sinking2, jpgoc )
523      CALL p4z_sink2( wsbio4, sinkfer2, jpbfe )
524      CALL p4z_sink2( wsbio4, sinksil , jpdsi )
525      CALL p4z_sink2( wscal , sinkcal , jpcal )
526
527!  Exchange between organic matter compartments due to
528!  coagulation/disaggregation
529!  ---------------------------------------------------
530
531      DO jk = 1, jpkm1
532         DO jj = 1, jpj
533            DO ji = 1, jpi
534               zfact = xstep * xdiss(ji,jj,jk)
535
536!    Part I : Coagulation dependent on turbulence
537!    ----------------------------------------------
538
539# if defined key_off_degrad
540               zagg1 = 940.* zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc) * facvol(ji,jj,jk)
541# else
542               zagg1 = 940.* zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
543# endif
544
545# if defined key_off_degrad
546               zagg2 = 1.054e4 * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc) * facvol(ji,jj,jk)
547# else
548               zagg2 = 1.054e4 * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
549# endif
550
551!    Aggregation of small into large particles
552!    Part II : Differential settling
553!    ----------------------------------------------
554
555# if defined key_off_degrad
556               zagg3 = 0.66 * xstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc) * facvol(ji,jj,jk)
557# else
558               zagg3 = 0.66 * xstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
559# endif
560
561# if defined key_off_degrad
562               zagg4 = 0.e0 * xstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc) * facvol(ji,jj,jk)
563# else
564               zagg4 = 0.e0 * xstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
565# endif
566
567               zagg   = zagg1 + zagg2 + zagg3 + zagg4
568               zaggfe = zagg * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn )
569
570!     Aggregation of DOC to small particles
571!     --------------------------------------
572
573               zaggdoc = ( 80.* trn(ji,jj,jk,jpdoc) + 698. * trn(ji,jj,jk,jppoc) )       &
574# if defined key_off_degrad
575                  &      * facvol(ji,jj,jk)                           &
576# endif
577                  &      * zfact * trn(ji,jj,jk,jpdoc)
578
579               zaggdoc2 = 1.05e4 * zfact * trn(ji,jj,jk,jpgoc)   &
580# if defined key_off_degrad
581                  &        * facvol(ji,jj,jk)                            &
582# endif     
583                  &        * trn(ji,jj,jk,jpdoc)
584!
585!  Update the trends
586!  -----------------
587!
588               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc
589               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2
590               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
591               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
592               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2
593
594            END DO
595         END DO
596      END DO
597
598# if defined key_trc_diaadd
599      zrfact2 = 1.e3 * rfact2r
600      trc2d(:,:, jp_pcs0_2d + 4) = sinking (:,:,iksed+1) * zrfact2
601      trc2d(:,:, jp_pcs0_2d + 5) = sinking2(:,:,iksed+1) * zrfact2
602      trc2d(:,:, jp_pcs0_2d + 6) = sinkfer (:,:,iksed+1) * zrfact2
603      trc2d(:,:, jp_pcs0_2d + 7) = sinkfer2(:,:,iksed+1) * zrfact2
604      trc2d(:,:, jp_pcs0_2d + 8) = sinksil (:,:,iksed+1) * zrfact2
605      trc2d(:,:, jp_pcs0_2d + 9) = sinkcal (:,:,iksed+1) * zrfact2
606# endif
607      !
608       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
609         WRITE(charout, FMT="('sink')")
610         CALL prt_ctl_trc_info(charout)
611         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
612       ENDIF
613
614   END SUBROUTINE p4z_sink
615
616#endif
617
618   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra )
619      !!---------------------------------------------------------------------
620      !!                     ***  ROUTINE p4z_sink2  ***
621      !!
622      !! ** Purpose :   Compute the sedimentation terms for the various sinking
623      !!     particles. The scheme used to compute the trends is based
624      !!     on MUSCL.
625      !!
626      !! ** Method  : - this ROUTINE compute not exactly the advection but the
627      !!      transport term, i.e.  div(u*tra).
628      !!---------------------------------------------------------------------
629      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
630      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
631      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
632      !!
633      INTEGER  ::   ji, jj, jk, jn
634      REAL(wp) ::   zigma,zew,zign, zflx
635      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  ztraz, zakz
636      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zwsink2
637      !!---------------------------------------------------------------------
638
639
640      ztraz(:,:,:) = 0.e0
641      zakz (:,:,:) = 0.e0
642
643      DO jk = 1, jpkm1
644# if defined key_off_degrad
645         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rjjss * tmask(:,:,jk+1) * facvol(:,:,jk)
646# else
647         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rjjss * tmask(:,:,jk+1)
648# endif
649      END DO
650      zwsink2(:,:,1) = 0.e0
651
652
653      ! Vertical advective flux
654      DO jn = 1, 2
655         !  first guess of the slopes interior values
656         DO jk = 2, jpkm1
657            ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk)
658         END DO
659         ztraz(:,:,1  ) = 0.0
660         ztraz(:,:,jpk) = 0.0
661
662         ! slopes
663         DO jk = 2, jpkm1
664            DO jj = 1,jpj
665               DO ji = 1, jpi
666                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
667                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
668               END DO
669            END DO
670         END DO
671         
672         ! Slopes limitation
673         DO jk = 2, jpkm1
674            DO jj = 1, jpj
675               DO ji = 1, jpi
676                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
677                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
678               END DO
679            END DO
680         END DO
681         
682         ! vertical advective flux
683         DO jk = 1, jpkm1
684            DO jj = 1, jpj     
685               DO ji = 1, jpi   
686                  zigma = zwsink2(ji,jj,jk+1) * xstep2 / fse3w(ji,jj,jk+1)
687                  zew   = zwsink2(ji,jj,jk+1)
688                  psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * xstep2
689               END DO
690            END DO
691         END DO
692         !
693         ! Boundary conditions
694         psinkflx(:,:,1  ) = 0.e0
695         psinkflx(:,:,jpk) = 0.e0
696         
697         DO jk=1,jpkm1
698            DO jj = 1,jpj
699               DO ji = 1, jpi
700                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
701                  trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx
702               END DO
703            END DO
704         END DO
705
706      ENDDO
707
708      DO jk=1,jpkm1
709         DO jj = 1,jpj
710            DO ji = 1, jpi
711               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
712               trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + 2. * zflx
713            END DO
714         END DO
715      END DO
716
717      trn(:,:,:,jp_tra) = trb(:,:,:,jp_tra)
718      psinkflx(:,:,:)   = 2. * psinkflx(:,:,:)
719
720      !
721   END SUBROUTINE p4z_sink2
722
723#else
724   !!======================================================================
725   !!  Dummy module :                                   No PISCES bio-model
726   !!======================================================================
727CONTAINS
728   SUBROUTINE p4z_sink                    ! Empty routine
729   END SUBROUTINE p4z_sink
730#endif 
731
732   !!======================================================================
733END MODULE  p4zsink
Note: See TracBrowser for help on using the repository browser.