New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv_tvd.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcadv_tvd.F90 @ 1193

Last change on this file since 1193 was 1193, checked in by cetlod, 16 years ago

Correction of transport module to ensure reproductibility for TOP configurations, see ticket:253
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 26.5 KB
Line 
1MODULE trcadv_tvd
2   !!======================================================================
3   !!                       ***  MODULE  trcadv_tvd  ***
4   !! Ocean passive tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  95-12  (L. Mortier)  Original code
7   !!                 !  00-01  (H. Loukos)  adapted to ORCA
8   !!                 !  00-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  01-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            9.0  !  02-06  (C. Ethe, G. Madec)  F90: Free form and module
12   !!                 !  07-02  (C. Deltel) Diagnose ML trends for passive tracers
13   !!----------------------------------------------------------------------
14#if defined key_top
15   !!----------------------------------------------------------------------
16   !!   trc_adv_tvd  : update the passive tracer trend with the horizontal
17   !!                  and vertical advection trends using a TVD scheme
18   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
19   !!                  algorithm
20   !!----------------------------------------------------------------------
21   USE oce_trc             ! ocean dynamics and active tracers variables
22   USE trc                 ! ocean passive tracers variables
23   USE trp_trc
24   USE lbclnk              ! ocean lateral boundary conditions (or mpp link)
25   USE trcbbl              ! advective passive tracers in the BBL
26   USE prtctl_trc      ! Print control for debbuging
27   USE trdmld_trc
28   USE trdmld_trc_oce     
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC trc_adv_tvd    ! routine called by trcstp.F90
34
35   !! * Substitutions
36#  include "top_substitute.h90"
37   !!----------------------------------------------------------------------
38   !!   TOP 1.0 , LOCEAN-IPSL (2005)
39   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcadv_tvd.F90,v 1.12 2006/04/10 15:38:54 opalod Exp $
40   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE trc_adv_tvd( kt )
46      !!----------------------------------------------------------------------
47      !!                  ***  ROUTINE trc_adv_tvd  ***
48      !!
49      !! **  Purpose :   Compute the now trend due to total advection of
50      !!       tracers and add it to the general trend of tracer equations
51      !!
52      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
53      !!       corrected flux (monotonic correction)
54      !!       note: - this advection scheme needs a leap-frog time scheme
55      !!
56      !! ** Action : - update tra with the now advective tracer trends
57      !!             - save the trends ('key_trdmld_trc)
58      !!----------------------------------------------------------------------
59#if defined key_trcbbl_adv
60      USE oce_trc            , zun => ua,  &  ! use ua as workspace
61           &                   zvn => va      ! use va as workspace
62      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
63#else
64      USE oce_trc            , zun => un,  &  ! When no bbl, zun == un
65           &                   zvn => vn,  &  !             zvn == vn
66           &                   zwn => wn      !             zwn == wn
67#endif
68      INTEGER, INTENT( in ) ::   kt                        ! ocean time-step
69      INTEGER  ::   ji, jj, jk, jn                         ! dummy loop indices
70      !!
71      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztu, ztv
72      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zti, ztw
73      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd  ! trends
74      !!
75      REAL(wp) ::   z_hdivn_x, z_hdivn_y                   ! temporary scalars
76      REAL(wp) ::   z2dtt, zbtr, zeu, zev, zew, z2
77      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk
78      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk
79      REAL(wp) ::   zgm, zgz
80      CHARACTER (len=22) :: charout
81      !!----------------------------------------------------------------------
82
83      zti(:,:,:) = 0.e0
84
85      IF( kt == nittrc000  .AND. lwp ) THEN
86         WRITE(numout,*)
87         WRITE(numout,*) 'trc_adv_tvd : TVD advection scheme'
88         WRITE(numout,*) '~~~~~~~~~~~'
89      ENDIF
90
91      IF( l_trdtrc ) ALLOCATE( ztrtrd(jpi,jpj,jpk) )
92
93      IF( neuler == 0 .AND. kt == nittrc000 ) THEN
94         z2=1.
95      ELSE
96         z2=2.
97      ENDIF
98
99#if defined key_trcbbl_adv
100      ! Advective Bottom boundary layer: add the velocity
101      ! -------------------------------------------------
102      zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:)
103      zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:)
104      zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:)
105#endif
106
107      !                                                          ! ===========
108      DO jn = 1, jptra                                           ! tracer loop
109         !                                                       ! ===========
110
111         ! ============================================================
112         ! I.              Intermediate advective trends
113         ! ============================================================
114
115         ! 1. Bottom value : flux set to zero
116         ! ----------------------------------
117         ztu(:,:,jpk) = 0.e0    ;    ztv(:,:,jpk) = 0.e0
118         ztw(:,:,jpk) = 0.e0    ;    zti(:,:,jpk) = 0.e0
119
120
121         ! 2. Upstream advection with initial mass fluxes & intermediate update
122         ! --------------------------------------------------------------------
123
124         ! ... Upstream tracer flux in the i and j direction
125         DO jk = 1, jpkm1
126            DO jj = 1, jpjm1
127               DO ji = 1, fs_jpim1   ! vector opt.
128               !??? CD DO ji = fs_2, fs_jpim1    ! Vector opt.
129                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
130                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
131                  zfp_ui = zeu + ABS( zeu )   ! upstream scheme
132                  zfm_ui = zeu - ABS( zeu )
133                  zfp_vj = zev + ABS( zev )
134                  zfm_vj = zev - ABS( zev )
135                  ztu(ji,jj,jk) = zfp_ui * trb(ji,jj,jk,jn) + zfm_ui * trb(ji+1,jj  ,jk,jn)
136                  ztv(ji,jj,jk) = zfp_vj * trb(ji,jj,jk,jn) + zfm_vj * trb(ji  ,jj+1,jk,jn)
137               END DO
138            END DO
139         END DO
140
141         ! ... Upstream tracer flux in the k direction
142         ! Surface value
143         IF( lk_dynspg_rl ) THEN   ! rigid lid : flux set to zero
144            ztw(:,:,1) = 0.e0
145         ELSE                      ! free surface
146            DO jj = 1, jpj
147               DO ji = 1, jpi
148                  zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1)
149                  ztw(ji,jj,1) = zew * trb(ji,jj,1,jn)
150               END DO
151            END DO
152         ENDIF
153
154         ! Interior value
155         DO jk = 2, jpkm1
156            DO jj = 1, jpj
157               DO ji = 1, jpi   ! CD ??? Vector opt.
158                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
159                  zfp_wk = zew + ABS( zew )
160                  zfm_wk = zew - ABS( zew )
161                  ztw(ji,jj,jk) = zfp_wk * trb(ji,jj,jk,jn) + zfm_wk * trb(ji,jj,jk-1,jn)
162               END DO
163            END DO
164         END DO
165
166         ! ... Total intermediate advective trend (flux divergence)
167         DO jk = 1, jpkm1
168            DO jj = 2, jpjm1
169               DO ji = fs_2, fs_jpim1   ! vector opt.
170                  zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
171                  zti(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
172                     &              + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
173                     &              + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
174#if defined key_trc_diatrd
175                  IF ( luttrd(jn) ) &
176                     trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) -  &
177                        &                          zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) )
178                  IF ( luttrd(jn) ) &
179                     trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) -  &
180                        &                          zbtr * ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )
181                  IF ( luttrd(jn) ) &
182                     trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) -  &
183                        &                          zbtr * ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) )
184#endif
185               END DO
186            END DO
187         END DO
188         
189         ! 3. Save the intermediate i / j / k advective trends for diagnostics
190         ! -------------------------------------------------------------------
191
192         IF( l_trdtrc ) THEN
193
194            ! 3.1) Passive tracer ZONAL advection trends
195            ztrtrd(:,:,:) = 0.e0
196
197            DO jk = 1, jpkm1
198               DO jj = 2, jpjm1
199                  DO ji = fs_2, fs_jpim1   ! vector opt.
200
201                     !-- Compute zonal divergence by splitting hdivn (see divcur.F90)
202                     !   N.B. This computation is not valid along OBCs (if any)
203                     zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
204                     z_hdivn_x = (  e2u(ji  ,jj) * fse3u(ji  ,jj,jk) * un(ji  ,jj,jk)          &
205                          &       - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * un(ji-1,jj,jk) ) * zbtr
206
207                     !-- Compute zonal advection trends
208                     ztrtrd(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr &
209                          &             + trb(ji,jj,jk,jn) * z_hdivn_x
210                  END DO
211               END DO
212            END DO
213
214            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_xad, kt)    ! save the trends
215
216            ! 3.2) Passive tracer MERIDIONAL advection trends
217            ztrtrd(:,:,:) = 0.e0
218 
219            DO jk = 1, jpkm1
220               DO jj = 2, jpjm1
221                  DO ji = fs_2, fs_jpim1   ! vector opt.
222
223                     !-- Compute merid. divergence by splitting hdivn (see divcur.F90)
224                     !   N.B. This computation is not valid along OBCs (if any)
225                     zbtr      = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
226                     z_hdivn_y = (  e1v(ji,  jj) * fse3v(ji,jj  ,jk) * vn(ji,jj  ,jk)          &
227                          &       - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk) ) * zbtr
228
229                     !-- Compute merid. advection trends
230                     ztrtrd(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zbtr &
231                          &             + trb(ji,jj,jk,jn) * z_hdivn_y
232                  END DO
233               END DO
234            END DO
235
236            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_yad, kt)     ! save the trends
237
238            ! 3.3) Passive tracer VERTICAL advection trends
239            ztrtrd(:,:,:) = 0.e0
240            DO jk = 1, jpkm1
241               DO jj = 2, jpjm1
242                  DO ji = fs_2, fs_jpim1   ! Vector opt.
243                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
244                     ztrtrd(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr   &
245                          &             - trb(ji,jj,jk,jn) * hdivn(ji,jj,jk)
246                  END DO
247               END DO
248            END DO
249
250            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt)     ! save the trends
251
252         ENDIF
253
254         ! 4. Update and guess with monotonic sheme
255         ! ----------------------------------------
256         DO jk = 1, jpkm1
257            z2dtt = z2 * rdttra(jk) * FLOAT(ndttrc)
258            DO jj = 2, jpjm1
259               DO ji = fs_2, fs_jpim1   ! vector opt.
260                  tra(ji,jj,jk,jn) =  tra(ji,jj,jk,jn) + zti(ji,jj,jk)
261                  zti (ji,jj,jk) = ( trb(ji,jj,jk,jn) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk)
262               END DO
263            END DO
264         END DO
265
266         ! 5. Lateral boundary conditions on zti, zsi (unchanged sign)
267         ! -----------------------------------------------------------
268         CALL lbc_lnk( zti, 'T', 1. )
269
270
271         ! ============================================================
272         ! II.              Corrected advective trends
273         ! ============================================================
274
275         ! 1. Antidiffusive flux : high order minus low order
276         ! --------------------------------------------------
277         ! Antidiffusive flux on i and j
278         DO jk = 1, jpkm1
279            DO jj = 1, jpjm1
280               DO ji = 1, fs_jpim1   ! vector opt.
281                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
282                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
283                  ztu(ji,jj,jk) = zeu * ( trn(ji,jj,jk,jn) + trn(ji+1,jj,jk,jn) ) - ztu(ji,jj,jk)
284                  ztv(ji,jj,jk) = zev * ( trn(ji,jj,jk,jn) + trn(ji,jj+1,jk,jn) ) - ztv(ji,jj,jk)
285               END DO
286            END DO
287         END DO
288
289         ! Antidiffusive flux on k
290         ztw(:,:,1) = 0.e0    ! surface value
291         DO jk = 2, jpkm1     ! interior value
292            DO jj = 1, jpj
293               DO ji = 1, jpi
294                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
295                  ztw(ji,jj,jk) = zew * ( trn(ji,jj,jk,jn) + trn(ji,jj,jk-1,jn) ) - ztw(ji,jj,jk)
296               END DO
297            END DO
298         END DO
299
300         ! Lateral bondary conditions
301         CALL lbc_lnk( ztu, 'U', -1. )
302         CALL lbc_lnk( ztv, 'V', -1. )
303         CALL lbc_lnk( ztw, 'W',  1. )
304
305         ! 2. Monotonicity algorithm
306         ! -------------------------
307         CALL nonosc( trb(:,:,:,jn), ztu, ztv, ztw, zti, z2 )
308
309
310         ! 3. Final trend with corrected fluxes
311         ! ------------------------------------
312         DO jk = 1, jpkm1
313            DO jj = 2, jpjm1
314               DO ji = fs_2, fs_jpim1   ! vector opt.
315                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
316                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn)   &
317                     &         - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
318                     &           + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
319                     &           + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
320#if defined key_trc_diatrd
321                  IF ( luttrd(jn) ) &
322                     trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) -  &
323                        &                          zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) )
324                  IF ( luttrd(jn) ) &
325                     trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) -  &
326                        &                          zbtr * ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )
327                  IF ( luttrd(jn) ) &
328                     trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) -  &
329                        &                          zbtr * ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) )
330#endif
331
332               END DO
333            END DO
334         END DO
335
336#if defined key_trc_diatrd
337         DO jk = 1,jpk
338            DO jj = 2,jpjm1
339               DO  ji = 2,jpim1
340                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
341                  zgm = zbtr * trn(ji,jj,jk,jn) *     &
342                     &         (  zun(ji  ,jj,jk) * e2u(ji  ,jj) * fse3u(ji  ,jj,jk)    &
343                     &          - zun(ji-1,jj,jk) * e2u(ji-1,jj) * fse3u(ji-1,jj,jk) )
344
345                  zgz = zbtr * trn(ji,jj,jk,jn) *     &
346                     &         (  zvn(ji,jj  ,jk) * e1v(ji,jj  ) * fse3v(ji,jj  ,jk)    &
347                     &          - zvn(ji,jj-1,jk) * e1v(ji,jj-1) * fse3v(ji,jj-1,jk) )
348
349                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) + zgm
350                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) + zgz
351                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3)    &
352                     &            - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk)
353               END DO
354            END DO
355         END DO
356
357         ! Lateral boundary conditions on trtrd:
358
359         IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),1), 'T', 1. )
360         IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),2), 'T', 1. )
361         IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),3), 'T', 1. )
362#endif
363
364         ! 4. Save the advective trends for diagnostics
365         ! --------------------------------------------
366         ! Warning : mass fluxes should probably be converted into advection
367         ! terms in the computations below ???
368
369         IF( l_trdtrc ) THEN
370           
371            ! 4.1) Passive tracer ZONAL advection trends
372            ztrtrd(:,:,:) = 0.e0
373            DO jk = 1, jpkm1
374               DO jj = 2, jpjm1
375                  DO ji = fs_2, fs_jpim1   ! vector opt.
376                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
377                     ztrtrd(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr
378                  END DO
379               END DO
380            END DO
381           
382            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_xad, kt)   ! <<< ADD TO PREVIOUSLY COMPUTED
383
384            ! 4.2) Passive tracer MERIDIONAL advection trends
385            ztrtrd(:,:,:) = 0.e0
386            DO jk = 1, jpkm1
387               DO jj = 2, jpjm1
388                  DO ji = fs_2, fs_jpim1   ! vector opt.
389                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
390                     ztrtrd(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zbtr 
391                  END DO
392               END DO
393            END DO
394           
395            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_yad, kt)   ! <<< ADD TO PREVIOUSLY COMPUTED
396           
397            ! 4.3) Passive tracer VERTICAL advection trends
398            ztrtrd(:,:,:) = 0.e0
399            DO jk = 1, jpkm1
400               DO jj = 2, jpjm1
401                  DO ji = fs_2, fs_jpim1   ! vector opt.
402                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
403                     ztrtrd(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) * zbtr
404                  END DO
405               END DO
406            END DO
407           
408            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt)   ! <<< ADD TO PREVIOUSLY COMPUTED
409           
410         ENDIF
411
412
413      END DO
414
415      IF( l_trdtrc ) DEALLOCATE( ztrtrd )
416
417      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
418         WRITE(charout, FMT="('tvd - adv')")
419         CALL prt_ctl_trc_info(charout)
420         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
421      ENDIF
422
423   END SUBROUTINE trc_adv_tvd
424
425
426   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
427      !!---------------------------------------------------------------------
428      !!                    ***  ROUTINE nonosc  ***
429      !!     
430      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
431      !!       scheme and the before field by a nonoscillatory algorithm
432      !!
433      !! **  Method  :   ... ???
434      !!       warning : pbef and paft must be masked, but the boundaries
435      !!       conditions on the fluxes are not necessary zalezak (1979)
436      !!       drange (1995) multi-dimensional forward-in-time and upstream-
437      !!       in-space based differencing for fluid
438      !!
439      !! History :
440      !!        !  97-04  (L. Mortier) Original code
441      !!        !  00-02  (H. Loukos)  rewritting for opa8
442      !!        !  00-10  (M.A Foujols, E. Kestenare)  lateral b.c.
443      !!        !  01-03  (E. Kestenare)  add key_passivetrc
444      !!        !  01-07  (E. Durand G. Madec)  adapted for T & S
445      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
446      !!----------------------------------------------------------------------
447      !! * Arguments
448      REAL(wp), INTENT( in ) ::   &
449         prdt                               ! ???
450      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
451         pbef,                            & ! before field
452         paft,                            & ! after field
453         paa,                             & ! monotonic flux in the i direction
454         pbb,                             & ! monotonic flux in the j direction
455         pcc                                ! monotonic flux in the k direction
456
457      !! * Local declarations
458      INTEGER ::   ji, jj, jk               ! dummy loop indices
459      INTEGER ::   ikm1
460      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
461      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
462      !!----------------------------------------------------------------------
463
464      zbig = 1.e+40
465      zrtrn = 1.e-15
466      zbetup(:,:,:) = 0.e0   ;   zbetdo(:,:,:) = 0.e0
467
468      ! Search local extrema
469      ! --------------------
470      ! large negative value (-zbig) inside land
471      ! large negative value (-zbig) inside land
472      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
473      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
474      ! search maximum in neighbourhood
475      DO jk = 1, jpkm1
476         ikm1 = MAX(jk-1,1)
477         DO jj = 2, jpjm1
478            DO ji = fs_2, fs_jpim1   ! vector opt.
479               zbetup(ji,jj,jk) = MAX(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
480                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
481                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
482                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
483                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
484                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
485                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
486            END DO
487         END DO
488      END DO
489      ! large positive value (+zbig) inside land
490      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
491      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
492      ! search minimum in neighbourhood
493      DO jk = 1, jpkm1
494         ikm1 = MAX(jk-1,1)
495         DO jj = 2, jpjm1
496            DO ji = fs_2, fs_jpim1   ! vector opt.
497               zbetdo(ji,jj,jk) = MIN(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
498                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
499                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
500                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
501                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
502                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
503                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
504            END DO
505         END DO
506      END DO
507
508      ! restore masked values to zero
509      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
510      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
511 
512
513      ! 2. Positive and negative part of fluxes and beta terms
514      ! ------------------------------------------------------
515
516      DO jk = 1, jpkm1
517         z2dtt = prdt * rdttra(jk) * FLOAT(ndttrc)
518         DO jj = 2, jpjm1
519            DO ji = fs_2, fs_jpim1   ! vector opt.
520               ! positive & negative part of the flux
521               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
522                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
523                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
524               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
525                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
526                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
527               ! up & down beta terms
528               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
529               zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
530               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
531            END DO
532         END DO
533      END DO
534
535      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
536      CALL lbc_lnk( zbetup, 'T', 1. )
537      CALL lbc_lnk( zbetdo, 'T', 1. )
538
539
540      ! 3. monotonic flux in the i direction, i.e. paa
541      ! ----------------------------------------------
542      DO jk = 1, jpkm1
543         DO jj = 2, jpjm1
544            DO ji = fs_2, fs_jpim1   ! vector opt.
545               zc = paa(ji,jj,jk)
546               IF( zc >= 0. ) THEN
547                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
548                  paa(ji,jj,jk) = za * zc
549               ELSE
550                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
551                  paa(ji,jj,jk) = zb * zc
552               ENDIF
553            END DO
554         END DO
555      END DO
556
557      ! lateral boundary condition on paa   (changed sign)
558      CALL lbc_lnk( paa, 'U', -1. )
559
560
561      ! 4. monotonic flux in the j direction, i.e. pbb
562      ! ----------------------------------------------
563      DO jk = 1, jpkm1
564         DO jj = 2, jpjm1
565            DO ji = fs_2, fs_jpim1   ! vector opt.
566               zc = pbb(ji,jj,jk)
567               IF( zc >= 0. ) THEN
568                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
569                  pbb(ji,jj,jk) = za * zc
570               ELSE
571                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
572                  pbb(ji,jj,jk) = zb * zc
573               ENDIF
574            END DO
575         END DO
576      END DO
577
578      ! lateral boundary condition on pbb   (changed sign)
579      CALL lbc_lnk( pbb, 'V', -1. )
580
581
582      ! monotonic flux in the k direction, i.e. pcc
583      ! -------------------------------------------
584      DO jk = 2, jpkm1
585         DO jj = 2, jpjm1
586            DO ji = fs_2, fs_jpim1   ! vector opt.
587               zc = pcc(ji,jj,jk)
588               IF( zc >= 0. ) THEN
589                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
590                  pcc(ji,jj,jk) = za * zc
591               ELSE
592                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
593                  pcc(ji,jj,jk) = zb * zc
594               ENDIF
595            END DO
596         END DO
597      END DO
598
599      ! lateral boundary condition on pcc   (unchanged sign)
600      CALL lbc_lnk( pcc, 'W', 1. )
601
602   END SUBROUTINE nonosc
603
604#else
605   !!----------------------------------------------------------------------
606   !!   Default option                                         Empty module
607   !!----------------------------------------------------------------------
608CONTAINS
609   SUBROUTINE trc_adv_tvd( kt ) 
610      INTEGER, INTENT(in) :: kt
611      WRITE(*,*) 'trc_adv_tvd: You should not have seen this print! error?', kt
612   END SUBROUTINE trc_adv_tvd
613#endif
614
615   !!======================================================================
616END MODULE trcadv_tvd
Note: See TracBrowser for help on using the repository browser.