| 1 | MODULE trcadv_tvd |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE trcadv_tvd *** |
|---|
| 4 | !! Ocean passive tracers: horizontal & vertical advective trend |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : ! 95-12 (L. Mortier) Original code |
|---|
| 7 | !! ! 00-01 (H. Loukos) adapted to ORCA |
|---|
| 8 | !! ! 00-10 (MA Foujols E.Kestenare) include file not routine |
|---|
| 9 | !! ! 00-12 (E. Kestenare M. Levy) fix bug in trtrd indexes |
|---|
| 10 | !! ! 01-07 (E. Durand G. Madec) adaptation to ORCA config |
|---|
| 11 | !! 9.0 ! 02-06 (C. Ethe, G. Madec) F90: Free form and module |
|---|
| 12 | !! ! 07-02 (C. Deltel) Diagnose ML trends for passive tracers |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | #if defined key_top |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! trc_adv_tvd : update the passive tracer trend with the horizontal |
|---|
| 17 | !! and vertical advection trends using a TVD scheme |
|---|
| 18 | !! nonosc : compute monotonic tracer fluxes by a nonoscillatory |
|---|
| 19 | !! algorithm |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce_trc ! ocean dynamics and active tracers variables |
|---|
| 22 | USE trc ! ocean passive tracers variables |
|---|
| 23 | USE trp_trc |
|---|
| 24 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 25 | USE trcbbl ! advective passive tracers in the BBL |
|---|
| 26 | USE prtctl_trc ! Print control for debbuging |
|---|
| 27 | USE trdmld_trc |
|---|
| 28 | USE trdmld_trc_oce |
|---|
| 29 | |
|---|
| 30 | IMPLICIT NONE |
|---|
| 31 | PRIVATE |
|---|
| 32 | |
|---|
| 33 | PUBLIC trc_adv_tvd ! routine called by trcstp.F90 |
|---|
| 34 | |
|---|
| 35 | !! * Substitutions |
|---|
| 36 | # include "top_substitute.h90" |
|---|
| 37 | !!---------------------------------------------------------------------- |
|---|
| 38 | !! TOP 1.0 , LOCEAN-IPSL (2005) |
|---|
| 39 | !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcadv_tvd.F90,v 1.12 2006/04/10 15:38:54 opalod Exp $ |
|---|
| 40 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 41 | !!---------------------------------------------------------------------- |
|---|
| 42 | |
|---|
| 43 | CONTAINS |
|---|
| 44 | |
|---|
| 45 | SUBROUTINE trc_adv_tvd( kt ) |
|---|
| 46 | !!---------------------------------------------------------------------- |
|---|
| 47 | !! *** ROUTINE trc_adv_tvd *** |
|---|
| 48 | !! |
|---|
| 49 | !! ** Purpose : Compute the now trend due to total advection of |
|---|
| 50 | !! tracers and add it to the general trend of tracer equations |
|---|
| 51 | !! |
|---|
| 52 | !! ** Method : TVD scheme, i.e. 2nd order centered scheme with |
|---|
| 53 | !! corrected flux (monotonic correction) |
|---|
| 54 | !! note: - this advection scheme needs a leap-frog time scheme |
|---|
| 55 | !! |
|---|
| 56 | !! ** Action : - update tra with the now advective tracer trends |
|---|
| 57 | !! - save the trends ('key_trdmld_trc) |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | #if defined key_trcbbl_adv |
|---|
| 60 | USE oce_trc , zun => ua, & ! use ua as workspace |
|---|
| 61 | & zvn => va ! use va as workspace |
|---|
| 62 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn |
|---|
| 63 | #else |
|---|
| 64 | USE oce_trc , zun => un, & ! When no bbl, zun == un |
|---|
| 65 | & zvn => vn, & ! zvn == vn |
|---|
| 66 | & zwn => wn ! zwn == wn |
|---|
| 67 | #endif |
|---|
| 68 | INTEGER, INTENT( in ) :: kt ! ocean time-step |
|---|
| 69 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 70 | !! |
|---|
| 71 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztu, ztv |
|---|
| 72 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zti, ztw |
|---|
| 73 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrtrd ! trends |
|---|
| 74 | !! |
|---|
| 75 | REAL(wp) :: z_hdivn_x, z_hdivn_y ! temporary scalars |
|---|
| 76 | REAL(wp) :: z2dtt, zbtr, zeu, zev, zew, z2 |
|---|
| 77 | REAL(wp) :: zfp_ui, zfp_vj, zfp_wk |
|---|
| 78 | REAL(wp) :: zfm_ui, zfm_vj, zfm_wk |
|---|
| 79 | #if defined key_trc_diatrd |
|---|
| 80 | REAL(wp) :: zgm, zgz |
|---|
| 81 | #endif |
|---|
| 82 | CHARACTER (len=22) :: charout |
|---|
| 83 | !!---------------------------------------------------------------------- |
|---|
| 84 | |
|---|
| 85 | zti(:,:,:) = 0.e0 |
|---|
| 86 | |
|---|
| 87 | IF( kt == nittrc000 .AND. lwp ) THEN |
|---|
| 88 | WRITE(numout,*) |
|---|
| 89 | WRITE(numout,*) 'trc_adv_tvd : TVD advection scheme' |
|---|
| 90 | WRITE(numout,*) '~~~~~~~~~~~' |
|---|
| 91 | ENDIF |
|---|
| 92 | |
|---|
| 93 | IF( l_trdtrc ) ALLOCATE( ztrtrd(jpi,jpj,jpk) ) |
|---|
| 94 | |
|---|
| 95 | IF( neuler == 0 .AND. kt == nittrc000 ) THEN |
|---|
| 96 | z2=1. |
|---|
| 97 | ELSE |
|---|
| 98 | z2=2. |
|---|
| 99 | ENDIF |
|---|
| 100 | |
|---|
| 101 | #if defined key_trcbbl_adv |
|---|
| 102 | ! Advective Bottom boundary layer: add the velocity |
|---|
| 103 | ! ------------------------------------------------- |
|---|
| 104 | zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:) |
|---|
| 105 | zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:) |
|---|
| 106 | zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:) |
|---|
| 107 | #endif |
|---|
| 108 | |
|---|
| 109 | ! ! =========== |
|---|
| 110 | DO jn = 1, jptra ! tracer loop |
|---|
| 111 | ! ! =========== |
|---|
| 112 | |
|---|
| 113 | ! ============================================================ |
|---|
| 114 | ! I. Intermediate advective trends |
|---|
| 115 | ! ============================================================ |
|---|
| 116 | |
|---|
| 117 | ! 1. Bottom value : flux set to zero |
|---|
| 118 | ! ---------------------------------- |
|---|
| 119 | ztu(:,:,jpk) = 0.e0 ; ztv(:,:,jpk) = 0.e0 |
|---|
| 120 | ztw(:,:,jpk) = 0.e0 ; zti(:,:,jpk) = 0.e0 |
|---|
| 121 | |
|---|
| 122 | |
|---|
| 123 | ! 2. Upstream advection with initial mass fluxes & intermediate update |
|---|
| 124 | ! -------------------------------------------------------------------- |
|---|
| 125 | |
|---|
| 126 | ! ... Upstream tracer flux in the i and j direction |
|---|
| 127 | DO jk = 1, jpkm1 |
|---|
| 128 | DO jj = 1, jpjm1 |
|---|
| 129 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 130 | !??? CD DO ji = fs_2, fs_jpim1 ! Vector opt. |
|---|
| 131 | zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk) |
|---|
| 132 | zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk) |
|---|
| 133 | zfp_ui = zeu + ABS( zeu ) ! upstream scheme |
|---|
| 134 | zfm_ui = zeu - ABS( zeu ) |
|---|
| 135 | zfp_vj = zev + ABS( zev ) |
|---|
| 136 | zfm_vj = zev - ABS( zev ) |
|---|
| 137 | ztu(ji,jj,jk) = zfp_ui * trb(ji,jj,jk,jn) + zfm_ui * trb(ji+1,jj ,jk,jn) |
|---|
| 138 | ztv(ji,jj,jk) = zfp_vj * trb(ji,jj,jk,jn) + zfm_vj * trb(ji ,jj+1,jk,jn) |
|---|
| 139 | END DO |
|---|
| 140 | END DO |
|---|
| 141 | END DO |
|---|
| 142 | |
|---|
| 143 | ! ... Upstream tracer flux in the k direction |
|---|
| 144 | ! Surface value |
|---|
| 145 | IF( lk_dynspg_rl ) THEN ! rigid lid : flux set to zero |
|---|
| 146 | ztw(:,:,1) = 0.e0 |
|---|
| 147 | ELSE ! free surface |
|---|
| 148 | DO jj = 1, jpj |
|---|
| 149 | DO ji = 1, jpi |
|---|
| 150 | zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1) |
|---|
| 151 | ztw(ji,jj,1) = zew * trb(ji,jj,1,jn) |
|---|
| 152 | END DO |
|---|
| 153 | END DO |
|---|
| 154 | ENDIF |
|---|
| 155 | |
|---|
| 156 | ! Interior value |
|---|
| 157 | DO jk = 2, jpkm1 |
|---|
| 158 | DO jj = 1, jpj |
|---|
| 159 | DO ji = 1, jpi ! CD ??? Vector opt. |
|---|
| 160 | zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk) |
|---|
| 161 | zfp_wk = zew + ABS( zew ) |
|---|
| 162 | zfm_wk = zew - ABS( zew ) |
|---|
| 163 | ztw(ji,jj,jk) = zfp_wk * trb(ji,jj,jk,jn) + zfm_wk * trb(ji,jj,jk-1,jn) |
|---|
| 164 | END DO |
|---|
| 165 | END DO |
|---|
| 166 | END DO |
|---|
| 167 | |
|---|
| 168 | ! ... Total intermediate advective trend (flux divergence) |
|---|
| 169 | DO jk = 1, jpkm1 |
|---|
| 170 | DO jj = 2, jpjm1 |
|---|
| 171 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 172 | zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 173 | zti(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj ,jk ) & |
|---|
| 174 | & + ztv(ji,jj,jk) - ztv(ji ,jj-1,jk ) & |
|---|
| 175 | & + ztw(ji,jj,jk) - ztw(ji ,jj ,jk+1) ) * zbtr |
|---|
| 176 | #if defined key_trc_diatrd |
|---|
| 177 | IF ( luttrd(jn) ) & |
|---|
| 178 | trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) - & |
|---|
| 179 | & zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) |
|---|
| 180 | IF ( luttrd(jn) ) & |
|---|
| 181 | trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) - & |
|---|
| 182 | & zbtr * ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) |
|---|
| 183 | IF ( luttrd(jn) ) & |
|---|
| 184 | trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) - & |
|---|
| 185 | & zbtr * ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) |
|---|
| 186 | #endif |
|---|
| 187 | END DO |
|---|
| 188 | END DO |
|---|
| 189 | END DO |
|---|
| 190 | |
|---|
| 191 | ! 3. Save the intermediate i / j / k advective trends for diagnostics |
|---|
| 192 | ! ------------------------------------------------------------------- |
|---|
| 193 | |
|---|
| 194 | IF( l_trdtrc ) THEN |
|---|
| 195 | |
|---|
| 196 | ! 3.1) Passive tracer ZONAL advection trends |
|---|
| 197 | ztrtrd(:,:,:) = 0.e0 |
|---|
| 198 | |
|---|
| 199 | DO jk = 1, jpkm1 |
|---|
| 200 | DO jj = 2, jpjm1 |
|---|
| 201 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 202 | |
|---|
| 203 | !-- Compute zonal divergence by splitting hdivn (see divcur.F90) |
|---|
| 204 | ! N.B. This computation is not valid along OBCs (if any) |
|---|
| 205 | zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 206 | z_hdivn_x = ( e2u(ji ,jj) * fse3u(ji ,jj,jk) * un(ji ,jj,jk) & |
|---|
| 207 | & - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * un(ji-1,jj,jk) ) * zbtr |
|---|
| 208 | |
|---|
| 209 | !-- Compute zonal advection trends |
|---|
| 210 | ztrtrd(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr & |
|---|
| 211 | & + trb(ji,jj,jk,jn) * z_hdivn_x |
|---|
| 212 | END DO |
|---|
| 213 | END DO |
|---|
| 214 | END DO |
|---|
| 215 | |
|---|
| 216 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_xad, kt) ! save the trends |
|---|
| 217 | |
|---|
| 218 | ! 3.2) Passive tracer MERIDIONAL advection trends |
|---|
| 219 | ztrtrd(:,:,:) = 0.e0 |
|---|
| 220 | |
|---|
| 221 | DO jk = 1, jpkm1 |
|---|
| 222 | DO jj = 2, jpjm1 |
|---|
| 223 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 224 | |
|---|
| 225 | !-- Compute merid. divergence by splitting hdivn (see divcur.F90) |
|---|
| 226 | ! N.B. This computation is not valid along OBCs (if any) |
|---|
| 227 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 228 | z_hdivn_y = ( e1v(ji, jj) * fse3v(ji,jj ,jk) * vn(ji,jj ,jk) & |
|---|
| 229 | & - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk) ) * zbtr |
|---|
| 230 | |
|---|
| 231 | !-- Compute merid. advection trends |
|---|
| 232 | ztrtrd(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zbtr & |
|---|
| 233 | & + trb(ji,jj,jk,jn) * z_hdivn_y |
|---|
| 234 | END DO |
|---|
| 235 | END DO |
|---|
| 236 | END DO |
|---|
| 237 | |
|---|
| 238 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_yad, kt) ! save the trends |
|---|
| 239 | |
|---|
| 240 | ! 3.3) Passive tracer VERTICAL advection trends |
|---|
| 241 | ztrtrd(:,:,:) = 0.e0 |
|---|
| 242 | DO jk = 1, jpkm1 |
|---|
| 243 | DO jj = 2, jpjm1 |
|---|
| 244 | DO ji = fs_2, fs_jpim1 ! Vector opt. |
|---|
| 245 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 246 | ztrtrd(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji ,jj ,jk+1) ) * zbtr & |
|---|
| 247 | & - trb(ji,jj,jk,jn) * hdivn(ji,jj,jk) |
|---|
| 248 | END DO |
|---|
| 249 | END DO |
|---|
| 250 | END DO |
|---|
| 251 | |
|---|
| 252 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt) ! save the trends |
|---|
| 253 | |
|---|
| 254 | ENDIF |
|---|
| 255 | |
|---|
| 256 | ! 4. Update and guess with monotonic sheme |
|---|
| 257 | ! ---------------------------------------- |
|---|
| 258 | DO jk = 1, jpkm1 |
|---|
| 259 | z2dtt = z2 * rdttra(jk) * FLOAT(ndttrc) |
|---|
| 260 | DO jj = 2, jpjm1 |
|---|
| 261 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 262 | tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + zti(ji,jj,jk) |
|---|
| 263 | zti (ji,jj,jk) = ( trb(ji,jj,jk,jn) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk) |
|---|
| 264 | END DO |
|---|
| 265 | END DO |
|---|
| 266 | END DO |
|---|
| 267 | |
|---|
| 268 | ! 5. Lateral boundary conditions on zti, zsi (unchanged sign) |
|---|
| 269 | ! ----------------------------------------------------------- |
|---|
| 270 | CALL lbc_lnk( zti, 'T', 1. ) |
|---|
| 271 | |
|---|
| 272 | |
|---|
| 273 | ! ============================================================ |
|---|
| 274 | ! II. Corrected advective trends |
|---|
| 275 | ! ============================================================ |
|---|
| 276 | |
|---|
| 277 | ! 1. Antidiffusive flux : high order minus low order |
|---|
| 278 | ! -------------------------------------------------- |
|---|
| 279 | ! Antidiffusive flux on i and j |
|---|
| 280 | DO jk = 1, jpkm1 |
|---|
| 281 | DO jj = 1, jpjm1 |
|---|
| 282 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 283 | zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk) |
|---|
| 284 | zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk) |
|---|
| 285 | ztu(ji,jj,jk) = zeu * ( trn(ji,jj,jk,jn) + trn(ji+1,jj,jk,jn) ) - ztu(ji,jj,jk) |
|---|
| 286 | ztv(ji,jj,jk) = zev * ( trn(ji,jj,jk,jn) + trn(ji,jj+1,jk,jn) ) - ztv(ji,jj,jk) |
|---|
| 287 | END DO |
|---|
| 288 | END DO |
|---|
| 289 | END DO |
|---|
| 290 | |
|---|
| 291 | ! Antidiffusive flux on k |
|---|
| 292 | ztw(:,:,1) = 0.e0 ! surface value |
|---|
| 293 | DO jk = 2, jpkm1 ! interior value |
|---|
| 294 | DO jj = 1, jpj |
|---|
| 295 | DO ji = 1, jpi |
|---|
| 296 | zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk) |
|---|
| 297 | ztw(ji,jj,jk) = zew * ( trn(ji,jj,jk,jn) + trn(ji,jj,jk-1,jn) ) - ztw(ji,jj,jk) |
|---|
| 298 | END DO |
|---|
| 299 | END DO |
|---|
| 300 | END DO |
|---|
| 301 | |
|---|
| 302 | ! Lateral bondary conditions |
|---|
| 303 | CALL lbc_lnk( ztu, 'U', -1. ) |
|---|
| 304 | CALL lbc_lnk( ztv, 'V', -1. ) |
|---|
| 305 | CALL lbc_lnk( ztw, 'W', 1. ) |
|---|
| 306 | |
|---|
| 307 | ! 2. Monotonicity algorithm |
|---|
| 308 | ! ------------------------- |
|---|
| 309 | CALL nonosc( trb(:,:,:,jn), ztu, ztv, ztw, zti, z2 ) |
|---|
| 310 | |
|---|
| 311 | |
|---|
| 312 | ! 3. Final trend with corrected fluxes |
|---|
| 313 | ! ------------------------------------ |
|---|
| 314 | DO jk = 1, jpkm1 |
|---|
| 315 | DO jj = 2, jpjm1 |
|---|
| 316 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 317 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 318 | tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) & |
|---|
| 319 | & - ( ztu(ji,jj,jk) - ztu(ji-1,jj ,jk ) & |
|---|
| 320 | & + ztv(ji,jj,jk) - ztv(ji ,jj-1,jk ) & |
|---|
| 321 | & + ztw(ji,jj,jk) - ztw(ji ,jj ,jk+1) ) * zbtr |
|---|
| 322 | #if defined key_trc_diatrd |
|---|
| 323 | IF ( luttrd(jn) ) & |
|---|
| 324 | trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) - & |
|---|
| 325 | & zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) |
|---|
| 326 | IF ( luttrd(jn) ) & |
|---|
| 327 | trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) - & |
|---|
| 328 | & zbtr * ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) |
|---|
| 329 | IF ( luttrd(jn) ) & |
|---|
| 330 | trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) - & |
|---|
| 331 | & zbtr * ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) |
|---|
| 332 | #endif |
|---|
| 333 | |
|---|
| 334 | END DO |
|---|
| 335 | END DO |
|---|
| 336 | END DO |
|---|
| 337 | |
|---|
| 338 | #if defined key_trc_diatrd |
|---|
| 339 | DO jk = 1,jpk |
|---|
| 340 | DO jj = 2,jpjm1 |
|---|
| 341 | DO ji = 2,jpim1 |
|---|
| 342 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 343 | zgm = zbtr * trn(ji,jj,jk,jn) * & |
|---|
| 344 | & ( zun(ji ,jj,jk) * e2u(ji ,jj) * fse3u(ji ,jj,jk) & |
|---|
| 345 | & - zun(ji-1,jj,jk) * e2u(ji-1,jj) * fse3u(ji-1,jj,jk) ) |
|---|
| 346 | |
|---|
| 347 | zgz = zbtr * trn(ji,jj,jk,jn) * & |
|---|
| 348 | & ( zvn(ji,jj ,jk) * e1v(ji,jj ) * fse3v(ji,jj ,jk) & |
|---|
| 349 | & - zvn(ji,jj-1,jk) * e1v(ji,jj-1) * fse3v(ji,jj-1,jk) ) |
|---|
| 350 | |
|---|
| 351 | IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) + zgm |
|---|
| 352 | IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) + zgz |
|---|
| 353 | IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) & |
|---|
| 354 | & - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk) |
|---|
| 355 | END DO |
|---|
| 356 | END DO |
|---|
| 357 | END DO |
|---|
| 358 | |
|---|
| 359 | ! Lateral boundary conditions on trtrd: |
|---|
| 360 | |
|---|
| 361 | IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),1), 'T', 1. ) |
|---|
| 362 | IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),2), 'T', 1. ) |
|---|
| 363 | IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),3), 'T', 1. ) |
|---|
| 364 | #endif |
|---|
| 365 | |
|---|
| 366 | ! 4. Save the advective trends for diagnostics |
|---|
| 367 | ! -------------------------------------------- |
|---|
| 368 | ! Warning : mass fluxes should probably be converted into advection |
|---|
| 369 | ! terms in the computations below ??? |
|---|
| 370 | |
|---|
| 371 | IF( l_trdtrc ) THEN |
|---|
| 372 | |
|---|
| 373 | ! 4.1) Passive tracer ZONAL advection trends |
|---|
| 374 | ztrtrd(:,:,:) = 0.e0 |
|---|
| 375 | DO jk = 1, jpkm1 |
|---|
| 376 | DO jj = 2, jpjm1 |
|---|
| 377 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 378 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 379 | ztrtrd(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr |
|---|
| 380 | END DO |
|---|
| 381 | END DO |
|---|
| 382 | END DO |
|---|
| 383 | |
|---|
| 384 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_xad, kt) ! <<< ADD TO PREVIOUSLY COMPUTED |
|---|
| 385 | |
|---|
| 386 | ! 4.2) Passive tracer MERIDIONAL advection trends |
|---|
| 387 | ztrtrd(:,:,:) = 0.e0 |
|---|
| 388 | DO jk = 1, jpkm1 |
|---|
| 389 | DO jj = 2, jpjm1 |
|---|
| 390 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 391 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 392 | ztrtrd(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zbtr |
|---|
| 393 | END DO |
|---|
| 394 | END DO |
|---|
| 395 | END DO |
|---|
| 396 | |
|---|
| 397 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_yad, kt) ! <<< ADD TO PREVIOUSLY COMPUTED |
|---|
| 398 | |
|---|
| 399 | ! 4.3) Passive tracer VERTICAL advection trends |
|---|
| 400 | ztrtrd(:,:,:) = 0.e0 |
|---|
| 401 | DO jk = 1, jpkm1 |
|---|
| 402 | DO jj = 2, jpjm1 |
|---|
| 403 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 404 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 405 | ztrtrd(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) * zbtr |
|---|
| 406 | END DO |
|---|
| 407 | END DO |
|---|
| 408 | END DO |
|---|
| 409 | |
|---|
| 410 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt) ! <<< ADD TO PREVIOUSLY COMPUTED |
|---|
| 411 | |
|---|
| 412 | ENDIF |
|---|
| 413 | |
|---|
| 414 | |
|---|
| 415 | END DO |
|---|
| 416 | |
|---|
| 417 | IF( l_trdtrc ) DEALLOCATE( ztrtrd ) |
|---|
| 418 | |
|---|
| 419 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 420 | WRITE(charout, FMT="('tvd - adv')") |
|---|
| 421 | CALL prt_ctl_trc_info(charout) |
|---|
| 422 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd') |
|---|
| 423 | ENDIF |
|---|
| 424 | |
|---|
| 425 | END SUBROUTINE trc_adv_tvd |
|---|
| 426 | |
|---|
| 427 | |
|---|
| 428 | SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt ) |
|---|
| 429 | !!--------------------------------------------------------------------- |
|---|
| 430 | !! *** ROUTINE nonosc *** |
|---|
| 431 | !! |
|---|
| 432 | !! ** Purpose : compute monotonic tracer fluxes from the upstream |
|---|
| 433 | !! scheme and the before field by a nonoscillatory algorithm |
|---|
| 434 | !! |
|---|
| 435 | !! ** Method : ... ??? |
|---|
| 436 | !! warning : pbef and paft must be masked, but the boundaries |
|---|
| 437 | !! conditions on the fluxes are not necessary zalezak (1979) |
|---|
| 438 | !! drange (1995) multi-dimensional forward-in-time and upstream- |
|---|
| 439 | !! in-space based differencing for fluid |
|---|
| 440 | !! |
|---|
| 441 | !! History : |
|---|
| 442 | !! ! 97-04 (L. Mortier) Original code |
|---|
| 443 | !! ! 00-02 (H. Loukos) rewritting for opa8 |
|---|
| 444 | !! ! 00-10 (M.A Foujols, E. Kestenare) lateral b.c. |
|---|
| 445 | !! ! 01-03 (E. Kestenare) add key_passivetrc |
|---|
| 446 | !! ! 01-07 (E. Durand G. Madec) adapted for T & S |
|---|
| 447 | !! 8.5 ! 02-06 (G. Madec) F90: Free form and module |
|---|
| 448 | !!---------------------------------------------------------------------- |
|---|
| 449 | !! * Arguments |
|---|
| 450 | REAL(wp), INTENT( in ) :: & |
|---|
| 451 | prdt ! ??? |
|---|
| 452 | REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) :: & |
|---|
| 453 | pbef, & ! before field |
|---|
| 454 | paft, & ! after field |
|---|
| 455 | paa, & ! monotonic flux in the i direction |
|---|
| 456 | pbb, & ! monotonic flux in the j direction |
|---|
| 457 | pcc ! monotonic flux in the k direction |
|---|
| 458 | |
|---|
| 459 | !! * Local declarations |
|---|
| 460 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 461 | INTEGER :: ikm1 |
|---|
| 462 | REAL(wp), DIMENSION (jpi,jpj,jpk) :: zbetup, zbetdo |
|---|
| 463 | REAL(wp) :: zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt |
|---|
| 464 | !!---------------------------------------------------------------------- |
|---|
| 465 | |
|---|
| 466 | zbig = 1.e+40 |
|---|
| 467 | zrtrn = 1.e-15 |
|---|
| 468 | zbetup(:,:,:) = 0.e0 ; zbetdo(:,:,:) = 0.e0 |
|---|
| 469 | |
|---|
| 470 | ! Search local extrema |
|---|
| 471 | ! -------------------- |
|---|
| 472 | ! large negative value (-zbig) inside land |
|---|
| 473 | ! large negative value (-zbig) inside land |
|---|
| 474 | pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) ) |
|---|
| 475 | paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) ) |
|---|
| 476 | ! search maximum in neighbourhood |
|---|
| 477 | DO jk = 1, jpkm1 |
|---|
| 478 | ikm1 = MAX(jk-1,1) |
|---|
| 479 | DO jj = 2, jpjm1 |
|---|
| 480 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 481 | zbetup(ji,jj,jk) = MAX( pbef(ji ,jj ,jk ), paft(ji ,jj ,jk ), & |
|---|
| 482 | & pbef(ji-1,jj ,jk ), pbef(ji+1,jj ,jk ), & |
|---|
| 483 | & paft(ji-1,jj ,jk ), paft(ji+1,jj ,jk ), & |
|---|
| 484 | & pbef(ji ,jj-1,jk ), pbef(ji ,jj+1,jk ), & |
|---|
| 485 | & paft(ji ,jj-1,jk ), paft(ji ,jj+1,jk ), & |
|---|
| 486 | & pbef(ji ,jj ,ikm1), pbef(ji ,jj ,jk+1), & |
|---|
| 487 | & paft(ji ,jj ,ikm1), paft(ji ,jj ,jk+1) ) |
|---|
| 488 | END DO |
|---|
| 489 | END DO |
|---|
| 490 | END DO |
|---|
| 491 | ! large positive value (+zbig) inside land |
|---|
| 492 | pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) ) |
|---|
| 493 | paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) ) |
|---|
| 494 | ! search minimum in neighbourhood |
|---|
| 495 | DO jk = 1, jpkm1 |
|---|
| 496 | ikm1 = MAX(jk-1,1) |
|---|
| 497 | DO jj = 2, jpjm1 |
|---|
| 498 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 499 | zbetdo(ji,jj,jk) = MIN( pbef(ji ,jj ,jk ), paft(ji ,jj ,jk ), & |
|---|
| 500 | & pbef(ji-1,jj ,jk ), pbef(ji+1,jj ,jk ), & |
|---|
| 501 | & paft(ji-1,jj ,jk ), paft(ji+1,jj ,jk ), & |
|---|
| 502 | & pbef(ji ,jj-1,jk ), pbef(ji ,jj+1,jk ), & |
|---|
| 503 | & paft(ji ,jj-1,jk ), paft(ji ,jj+1,jk ), & |
|---|
| 504 | & pbef(ji ,jj ,ikm1), pbef(ji ,jj ,jk+1), & |
|---|
| 505 | & paft(ji ,jj ,ikm1), paft(ji ,jj ,jk+1) ) |
|---|
| 506 | END DO |
|---|
| 507 | END DO |
|---|
| 508 | END DO |
|---|
| 509 | |
|---|
| 510 | ! restore masked values to zero |
|---|
| 511 | pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) |
|---|
| 512 | paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) |
|---|
| 513 | |
|---|
| 514 | |
|---|
| 515 | ! 2. Positive and negative part of fluxes and beta terms |
|---|
| 516 | ! ------------------------------------------------------ |
|---|
| 517 | |
|---|
| 518 | DO jk = 1, jpkm1 |
|---|
| 519 | z2dtt = prdt * rdttra(jk) * FLOAT(ndttrc) |
|---|
| 520 | DO jj = 2, jpjm1 |
|---|
| 521 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 522 | ! positive & negative part of the flux |
|---|
| 523 | zpos = MAX( 0., paa(ji-1,jj ,jk ) ) - MIN( 0., paa(ji ,jj ,jk ) ) & |
|---|
| 524 | & + MAX( 0., pbb(ji ,jj-1,jk ) ) - MIN( 0., pbb(ji ,jj ,jk ) ) & |
|---|
| 525 | & + MAX( 0., pcc(ji ,jj ,jk+1) ) - MIN( 0., pcc(ji ,jj ,jk ) ) |
|---|
| 526 | zneg = MAX( 0., paa(ji ,jj ,jk ) ) - MIN( 0., paa(ji-1,jj ,jk ) ) & |
|---|
| 527 | & + MAX( 0., pbb(ji ,jj ,jk ) ) - MIN( 0., pbb(ji ,jj-1,jk ) ) & |
|---|
| 528 | & + MAX( 0., pcc(ji ,jj ,jk ) ) - MIN( 0., pcc(ji ,jj ,jk+1) ) |
|---|
| 529 | ! up & down beta terms |
|---|
| 530 | zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt |
|---|
| 531 | zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt |
|---|
| 532 | zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt |
|---|
| 533 | END DO |
|---|
| 534 | END DO |
|---|
| 535 | END DO |
|---|
| 536 | |
|---|
| 537 | ! lateral boundary condition on zbetup & zbetdo (unchanged sign) |
|---|
| 538 | CALL lbc_lnk( zbetup, 'T', 1. ) |
|---|
| 539 | CALL lbc_lnk( zbetdo, 'T', 1. ) |
|---|
| 540 | |
|---|
| 541 | |
|---|
| 542 | ! 3. monotonic flux in the i direction, i.e. paa |
|---|
| 543 | ! ---------------------------------------------- |
|---|
| 544 | DO jk = 1, jpkm1 |
|---|
| 545 | DO jj = 2, jpjm1 |
|---|
| 546 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 547 | zc = paa(ji,jj,jk) |
|---|
| 548 | IF( zc >= 0. ) THEN |
|---|
| 549 | za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) ) |
|---|
| 550 | paa(ji,jj,jk) = za * zc |
|---|
| 551 | ELSE |
|---|
| 552 | zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) ) |
|---|
| 553 | paa(ji,jj,jk) = zb * zc |
|---|
| 554 | ENDIF |
|---|
| 555 | END DO |
|---|
| 556 | END DO |
|---|
| 557 | END DO |
|---|
| 558 | |
|---|
| 559 | ! lateral boundary condition on paa (changed sign) |
|---|
| 560 | CALL lbc_lnk( paa, 'U', -1. ) |
|---|
| 561 | |
|---|
| 562 | |
|---|
| 563 | ! 4. monotonic flux in the j direction, i.e. pbb |
|---|
| 564 | ! ---------------------------------------------- |
|---|
| 565 | DO jk = 1, jpkm1 |
|---|
| 566 | DO jj = 2, jpjm1 |
|---|
| 567 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 568 | zc = pbb(ji,jj,jk) |
|---|
| 569 | IF( zc >= 0. ) THEN |
|---|
| 570 | za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) ) |
|---|
| 571 | pbb(ji,jj,jk) = za * zc |
|---|
| 572 | ELSE |
|---|
| 573 | zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) ) |
|---|
| 574 | pbb(ji,jj,jk) = zb * zc |
|---|
| 575 | ENDIF |
|---|
| 576 | END DO |
|---|
| 577 | END DO |
|---|
| 578 | END DO |
|---|
| 579 | |
|---|
| 580 | ! lateral boundary condition on pbb (changed sign) |
|---|
| 581 | CALL lbc_lnk( pbb, 'V', -1. ) |
|---|
| 582 | |
|---|
| 583 | |
|---|
| 584 | ! monotonic flux in the k direction, i.e. pcc |
|---|
| 585 | ! ------------------------------------------- |
|---|
| 586 | DO jk = 2, jpkm1 |
|---|
| 587 | DO jj = 2, jpjm1 |
|---|
| 588 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 589 | zc = pcc(ji,jj,jk) |
|---|
| 590 | IF( zc >= 0. ) THEN |
|---|
| 591 | za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) ) |
|---|
| 592 | pcc(ji,jj,jk) = za * zc |
|---|
| 593 | ELSE |
|---|
| 594 | zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) ) |
|---|
| 595 | pcc(ji,jj,jk) = zb * zc |
|---|
| 596 | ENDIF |
|---|
| 597 | END DO |
|---|
| 598 | END DO |
|---|
| 599 | END DO |
|---|
| 600 | |
|---|
| 601 | ! lateral boundary condition on pcc (unchanged sign) |
|---|
| 602 | CALL lbc_lnk( pcc, 'W', 1. ) |
|---|
| 603 | |
|---|
| 604 | END SUBROUTINE nonosc |
|---|
| 605 | |
|---|
| 606 | #else |
|---|
| 607 | !!---------------------------------------------------------------------- |
|---|
| 608 | !! Default option Empty module |
|---|
| 609 | !!---------------------------------------------------------------------- |
|---|
| 610 | CONTAINS |
|---|
| 611 | SUBROUTINE trc_adv_tvd( kt ) |
|---|
| 612 | INTEGER, INTENT(in) :: kt |
|---|
| 613 | WRITE(*,*) 'trc_adv_tvd: You should not have seen this print! error?', kt |
|---|
| 614 | END SUBROUTINE trc_adv_tvd |
|---|
| 615 | #endif |
|---|
| 616 | |
|---|
| 617 | !!====================================================================== |
|---|
| 618 | END MODULE trcadv_tvd |
|---|
