New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_iso_zps.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_iso_zps.F90 @ 202

Last change on this file since 202 was 202, checked in by opalod, 19 years ago

CT : UPDATE142 : Check the consistency between passive tracers transport modules (in TRP directory) and those used for the active tracers
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 11.7 KB
Line 
1MODULE trcldf_iso_zps
2   !!==============================================================================
3   !!                   ***  MODULE  trcldf_iso_zps  ***
4   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if key_passivetrc && ( defined key_ldfslp   &&   defined key_partial_steps )
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'               slope of the lateral diffusive direction
9   !!----------------------------------------------------------------------
10   !!   trc_ldf_iso_zps : update the tracer trend with the horizontal
11   !!                     component of a iso-neutral laplacian operator
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce_trc             ! ocean dynamics and active tracers variables
15   USE trc                 ! ocean passive tracers variables
16
17   IMPLICIT NONE
18   PRIVATE
19
20   !! * Accessibility
21   PUBLIC trc_ldf_iso_zps  ! routine called by step.F90
22
23   !! * Substitutions
24#  include "passivetrc_substitute.h90"
25   !!----------------------------------------------------------------------
26   !!   OPA 9.0 , LODYC-IPSL (2003)
27   !!----------------------------------------------------------------------
28
29CONTAINS
30
31   SUBROUTINE trc_ldf_iso_zps( kt )
32      !!----------------------------------------------------------------------
33      !!                  ***  ROUTINE trc_ldf_iso_zps  ***
34      !!
35      !! ** Purpose :   Compute the before horizontal tracer  diffusive
36      !!      trend and add it to the general trend of tracer equation.
37      !!
38      !! ** Method  :   The horizontal component of the lateral diffusive trends
39      !!      is provided by a 2nd order operator rotated along neural or geopo-
40      !!      tential surfaces to which an eddy induced advection can be added
41      !!      It is computed using before fields (forward in time) and isopyc-
42      !!      nal or geopotential slopes computed in routine ldfslp.
43      !!
44      !!      horizontal fluxes associated with the rotated lateral mixing:
45      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
46      !!               - aht       e2u*uslp    dk[ mi(mk(trb)) ]
47      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
48      !!               - aht       e2u*vslp    dk[ mj(mk(trb)) ]
49      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
50      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( trb )
51      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( trb )
52      !!      take the horizontal divergence of the fluxes:
53      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
54      !!      Add this trend to the general trend tra :
55      !!         tra = tra + difft
56      !!
57      !!      'key_trdtra' defined: the trend is saved for diagnostics.
58      !!
59      !!      macro-tasked on horizontal slab (jk-loop).
60      !!
61      !! ** Action :
62      !!         Update tra arrays with the before along level biharmonic
63      !!      mixing trend.
64      !!         Save in trtrd arrays the trends if 'key_trc_diatrd' defined
65      !!
66      !! History :
67      !!        !  94-08  (G. Madec, M. Imbard)
68      !!        !  97-05  (G. Madec)  split into traldf and trazdf
69      !!   8.5  !  02-08  (G. Madec)  Free form, F90
70      !!   9.0  !  04-03  (C. Ethe)  adapted for passive tracers
71      !!----------------------------------------------------------------------
72      !! * Modules used
73      USE oce_trc       , zftu => ua,  &  ! use ua as workspace
74         &                zfsu => va      ! use va as workspace
75
76      !! * Arguments
77      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
78
79      !! * Local declarations
80      INTEGER ::   ji, jj, jk,jn          ! dummy loop indices
81      INTEGER ::   iku, ikv               ! temporary integer
82      REAL(wp) ::   &
83         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
84         zmsku, zmskv, zbtr, ztra,     &
85         ztagu, ztagv
86
87      REAL(wp), DIMENSION(jpi,jpj) ::   &
88         zdkt , zdk1t                     ! temporary workspace
89
90      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
91         zftv, zgtbu, zgtbv               ! temporary workspace
92
93#if defined key_trcldf_eiv
94      REAL(wp), DIMENSION(jpi,jpj) ::   &
95         zftug, zftvg                    ! temporary workspace
96
97      REAL(wp) ::   &
98         zuwk, zvwk,                   &
99         zuwk1, zvwk1,                 &
100         zcg1,zcg2
101#endif
102
103      !!----------------------------------------------------------------------
104
105      IF( kt == nittrc000 ) THEN
106         IF(lwp) WRITE(numout,*)
107         IF(lwp) WRITE(numout,*) 'trc_ldf_iso_zps : iso neutral laplacian diffusion in '
108         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~   z-coordinates with partial steps'
109#if defined key_trcldf_eiv && defined key_diaeiv
110         u_trc_eiv(:,:,:) = 0.e0
111         v_trc_eiv(:,:,:) = 0.e0
112#endif
113      ENDIF
114
115      DO jn = 1, jptra
116
117         ztagu = 0.e0
118         ztagv = 0.e0
119
120         ! Horizontal passive tracer gradient
121         DO jk = 1, jpk
122            DO jj = 1, jpj-1
123               DO ji = 1, fs_jpim1   ! vector opt.
124                  zgtbu(ji,jj,jk) = tmask(ji,jj,jk) * ( trb(ji+1,jj  ,jk,jn) - trb(ji,jj,jk,jn) )
125                  zgtbv(ji,jj,jk) = tmask(ji,jj,jk) * ( trb(ji  ,jj+1,jk,jn) - trb(ji,jj,jk,jn) )
126               END DO
127            END DO
128         END DO
129         ! partial steps correction at the last level
130         DO jj = 1, jpj-1
131            DO ji = 1, jpi-1
132               ! last level
133               iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
134               ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
135               zgtbu(ji,jj,iku) = gtru(ji,jj,jn)               
136               zgtbv(ji,jj,ikv) = gtrv(ji,jj,jn)               
137            END DO
138         END DO
139
140         !                                                ! ===============
141         DO jk = 1, jpkm1                                 ! Horizontal slab
142            !                                             ! ===============
143            ! 1. Vertical tracer gradient at level jk and jk+1
144            ! ------------------------------------------------
145            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
146
147            zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
148
149            IF( jk == 1 ) THEN
150               zdkt(:,:) = zdk1t(:,:)
151            ELSE
152               zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk)
153            ENDIF
154
155
156            ! 2. Horizontal fluxes
157            ! --------------------
158
159            DO jj = 1 , jpjm1
160               DO ji = 1, fs_jpim1   ! vector opt.
161                  zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
162                  zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
163
164                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
165                     + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
166
167                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
168                     + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
169
170                  zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
171                  zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
172
173                  zftu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgtbu(ji,jj,jk)   &
174                     &                                + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
175                     &                                           + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
176                  zftv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgtbv(ji,jj,jk)   &
177                     &                                + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
178                     &                                           + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
179               END DO
180            END DO
181
182# if defined key_trcldf_eiv
183            ! ---------------------------------------!
184            ! Eddy induced vertical advective fluxes !
185            ! ---------------------------------------!
186            DO jj = 1, jpjm1
187               DO ji = 1, fs_jpim1   ! vector opt.
188                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj  ,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
189                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj  ,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
190                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji  ,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
191                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji  ,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
192
193                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
194                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
195
196                  zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
197                  zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
198
199                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
200                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
201
202#   if defined key_diaeiv
203                  u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
204                  v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
205#   endif
206               END DO
207            END DO
208# endif
209
210            ! II.4 Second derivative (divergence) and add to the general trend
211            ! ----------------------------------------------------------------
212
213            DO jj = 2 , jpjm1
214               DO ji = fs_2, fs_jpim1   ! vector opt.
215                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
216                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
217                  tra (ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra
218#if defined key_trc_diatrd
219                  trtrd (ji,jj,jk,jn,4) = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,  jj,jk) )
220                  trtrd (ji,jj,jk,jn,5) = zbtr * ( zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk) )
221#endif
222               END DO
223            END DO
224#if defined key_trc_diatrd
225#   if defined key_trcldf_eiv
226            DO jj = 2 , jpjm1
227               DO ji = fs_2, fs_jpim1   ! vector opt.
228                  zbtr= 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
229                  ztagu = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
230                  ztagv = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
231                  trtrd (ji,jj,jk,jn,4) = trtrd(ji,jj,jk,jn,4) - ztagu
232                  trtrd (ji,jj,jk,jn,5) = trtrd(ji,jj,jk,jn,5) - ztagv
233               END DO
234            END DO
235#   endif
236#endif
237            !                                          ! ===============
238         END DO                                        !   End of slab 
239         !                                             ! ===============
240         IF(l_ctl) THEN         ! print mean trends (used for debugging)
241            ztra = SUM( tra(2:nictl,2:njctl,1:jpkm1,jn) * tmask(2:nictl,2:njctl,1:jpkm1) )
242            WRITE(numout,*) ' trc/ldf  - ',ctrcnm(jn),' : ', ztra-tra_ctl(jn)
243            tra_ctl(jn) = ztra 
244         ENDIF
245
246      END DO
247
248   END SUBROUTINE trc_ldf_iso_zps
249
250#else
251   !!----------------------------------------------------------------------
252   !!   default option :   Dummy code   NO rotation of the diffusive tensor
253   !!----------------------------------------------------------------------
254CONTAINS
255   SUBROUTINE trc_ldf_iso_zps( kt )               ! Empty routine
256      INTEGER, INTENT(in) :: kt
257      WRITE(*,*) 'trc_ldf_iso_zps: You should not have seen this print! error?', kt
258   END SUBROUTINE trc_ldf_iso_zps
259#endif
260
261   !!==============================================================================
262END MODULE trcldf_iso_zps
Note: See TracBrowser for help on using the repository browser.