New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_iso_zps.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_iso_zps.F90 @ 247

Last change on this file since 247 was 247, checked in by opalod, 19 years ago

CL : Add CVS Header and CeCILL licence information
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 11.8 KB
Line 
1MODULE trcldf_iso_zps
2   !!==============================================================================
3   !!                   ***  MODULE  trcldf_iso_zps  ***
4   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if key_passivetrc && ( defined key_ldfslp   &&   defined key_partial_steps )
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'               slope of the lateral diffusive direction
9   !!----------------------------------------------------------------------
10   !!   trc_ldf_iso_zps : update the tracer trend with the horizontal
11   !!                     component of a iso-neutral laplacian operator
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce_trc             ! ocean dynamics and active tracers variables
15   USE trc                 ! ocean passive tracers variables
16
17   IMPLICIT NONE
18   PRIVATE
19
20   !! * Accessibility
21   PUBLIC trc_ldf_iso_zps  ! routine called by step.F90
22
23   !! * Substitutions
24#  include "passivetrc_substitute.h90"
25   !!----------------------------------------------------------------------
26   !!   TOP 1.0 , LOCEAN-IPSL (2005)
27   !! $Header$
28   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
29   !!----------------------------------------------------------------------
30
31CONTAINS
32
33   SUBROUTINE trc_ldf_iso_zps( kt )
34      !!----------------------------------------------------------------------
35      !!                  ***  ROUTINE trc_ldf_iso_zps  ***
36      !!
37      !! ** Purpose :   Compute the before horizontal tracer  diffusive
38      !!      trend and add it to the general trend of tracer equation.
39      !!
40      !! ** Method  :   The horizontal component of the lateral diffusive trends
41      !!      is provided by a 2nd order operator rotated along neural or geopo-
42      !!      tential surfaces to which an eddy induced advection can be added
43      !!      It is computed using before fields (forward in time) and isopyc-
44      !!      nal or geopotential slopes computed in routine ldfslp.
45      !!
46      !!      horizontal fluxes associated with the rotated lateral mixing:
47      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
48      !!               - aht       e2u*uslp    dk[ mi(mk(trb)) ]
49      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
50      !!               - aht       e2u*vslp    dk[ mj(mk(trb)) ]
51      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
52      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( trb )
53      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( trb )
54      !!      take the horizontal divergence of the fluxes:
55      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
56      !!      Add this trend to the general trend tra :
57      !!         tra = tra + difft
58      !!
59      !!      'key_trdtra' defined: the trend is saved for diagnostics.
60      !!
61      !!      macro-tasked on horizontal slab (jk-loop).
62      !!
63      !! ** Action :
64      !!         Update tra arrays with the before along level biharmonic
65      !!      mixing trend.
66      !!         Save in trtrd arrays the trends if 'key_trc_diatrd' defined
67      !!
68      !! History :
69      !!        !  94-08  (G. Madec, M. Imbard)
70      !!        !  97-05  (G. Madec)  split into traldf and trazdf
71      !!   8.5  !  02-08  (G. Madec)  Free form, F90
72      !!   9.0  !  04-03  (C. Ethe)  adapted for passive tracers
73      !!----------------------------------------------------------------------
74      !! * Modules used
75      USE oce_trc       , zftu => ua,  &  ! use ua as workspace
76         &                zfsu => va      ! use va as workspace
77
78      !! * Arguments
79      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
80
81      !! * Local declarations
82      INTEGER ::   ji, jj, jk,jn          ! dummy loop indices
83      INTEGER ::   iku, ikv               ! temporary integer
84      REAL(wp) ::   &
85         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
86         zmsku, zmskv, zbtr, ztra,     &
87         ztagu, ztagv
88
89      REAL(wp), DIMENSION(jpi,jpj) ::   &
90         zdkt , zdk1t                     ! temporary workspace
91
92      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
93         zftv, zgtbu, zgtbv               ! temporary workspace
94
95#if defined key_trcldf_eiv
96      REAL(wp), DIMENSION(jpi,jpj) ::   &
97         zftug, zftvg                    ! temporary workspace
98
99      REAL(wp) ::   &
100         zuwk, zvwk,                   &
101         zuwk1, zvwk1,                 &
102         zcg1,zcg2
103#endif
104
105      !!----------------------------------------------------------------------
106
107      IF( kt == nittrc000 ) THEN
108         IF(lwp) WRITE(numout,*)
109         IF(lwp) WRITE(numout,*) 'trc_ldf_iso_zps : iso neutral laplacian diffusion in '
110         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~   z-coordinates with partial steps'
111#if defined key_trcldf_eiv && defined key_diaeiv
112         u_trc_eiv(:,:,:) = 0.e0
113         v_trc_eiv(:,:,:) = 0.e0
114#endif
115      ENDIF
116
117      DO jn = 1, jptra
118
119         ztagu = 0.e0
120         ztagv = 0.e0
121
122         ! Horizontal passive tracer gradient
123         DO jk = 1, jpk
124            DO jj = 1, jpj-1
125               DO ji = 1, fs_jpim1   ! vector opt.
126                  zgtbu(ji,jj,jk) = tmask(ji,jj,jk) * ( trb(ji+1,jj  ,jk,jn) - trb(ji,jj,jk,jn) )
127                  zgtbv(ji,jj,jk) = tmask(ji,jj,jk) * ( trb(ji  ,jj+1,jk,jn) - trb(ji,jj,jk,jn) )
128               END DO
129            END DO
130         END DO
131         ! partial steps correction at the last level
132         DO jj = 1, jpj-1
133            DO ji = 1, jpi-1
134               ! last level
135               iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
136               ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
137               zgtbu(ji,jj,iku) = gtru(ji,jj,jn)               
138               zgtbv(ji,jj,ikv) = gtrv(ji,jj,jn)               
139            END DO
140         END DO
141
142         !                                                ! ===============
143         DO jk = 1, jpkm1                                 ! Horizontal slab
144            !                                             ! ===============
145            ! 1. Vertical tracer gradient at level jk and jk+1
146            ! ------------------------------------------------
147            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
148
149            zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
150
151            IF( jk == 1 ) THEN
152               zdkt(:,:) = zdk1t(:,:)
153            ELSE
154               zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk)
155            ENDIF
156
157
158            ! 2. Horizontal fluxes
159            ! --------------------
160
161            DO jj = 1 , jpjm1
162               DO ji = 1, fs_jpim1   ! vector opt.
163                  zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
164                  zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
165
166                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
167                     + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
168
169                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
170                     + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
171
172                  zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
173                  zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
174
175                  zftu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgtbu(ji,jj,jk)   &
176                     &                                + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
177                     &                                           + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
178                  zftv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgtbv(ji,jj,jk)   &
179                     &                                + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
180                     &                                           + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
181               END DO
182            END DO
183
184# if defined key_trcldf_eiv
185            ! ---------------------------------------!
186            ! Eddy induced vertical advective fluxes !
187            ! ---------------------------------------!
188            DO jj = 1, jpjm1
189               DO ji = 1, fs_jpim1   ! vector opt.
190                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj  ,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
191                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj  ,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
192                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji  ,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
193                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji  ,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
194
195                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
196                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
197
198                  zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
199                  zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
200
201                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
202                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
203
204#   if defined key_diaeiv
205                  u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
206                  v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
207#   endif
208               END DO
209            END DO
210# endif
211
212            ! II.4 Second derivative (divergence) and add to the general trend
213            ! ----------------------------------------------------------------
214
215            DO jj = 2 , jpjm1
216               DO ji = fs_2, fs_jpim1   ! vector opt.
217                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
218                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
219                  tra (ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra
220#if defined key_trc_diatrd
221                  trtrd (ji,jj,jk,jn,4) = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,  jj,jk) )
222                  trtrd (ji,jj,jk,jn,5) = zbtr * ( zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk) )
223#endif
224               END DO
225            END DO
226#if defined key_trc_diatrd
227#   if defined key_trcldf_eiv
228            DO jj = 2 , jpjm1
229               DO ji = fs_2, fs_jpim1   ! vector opt.
230                  zbtr= 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
231                  ztagu = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
232                  ztagv = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
233                  trtrd (ji,jj,jk,jn,4) = trtrd(ji,jj,jk,jn,4) - ztagu
234                  trtrd (ji,jj,jk,jn,5) = trtrd(ji,jj,jk,jn,5) - ztagv
235               END DO
236            END DO
237#   endif
238#endif
239            !                                          ! ===============
240         END DO                                        !   End of slab 
241         !                                             ! ===============
242         IF(l_ctl) THEN         ! print mean trends (used for debugging)
243            ztra = SUM( tra(2:nictl,2:njctl,1:jpkm1,jn) * tmask(2:nictl,2:njctl,1:jpkm1) )
244            WRITE(numout,*) ' trc/ldf  - ',ctrcnm(jn),' : ', ztra-tra_ctl(jn)
245            tra_ctl(jn) = ztra 
246         ENDIF
247
248      END DO
249
250   END SUBROUTINE trc_ldf_iso_zps
251
252#else
253   !!----------------------------------------------------------------------
254   !!   default option :   Dummy code   NO rotation of the diffusive tensor
255   !!----------------------------------------------------------------------
256CONTAINS
257   SUBROUTINE trc_ldf_iso_zps( kt )               ! Empty routine
258      INTEGER, INTENT(in) :: kt
259      WRITE(*,*) 'trc_ldf_iso_zps: You should not have seen this print! error?', kt
260   END SUBROUTINE trc_ldf_iso_zps
261#endif
262
263   !!==============================================================================
264END MODULE trcldf_iso_zps
Note: See TracBrowser for help on using the repository browser.