New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DYN/dynadv_cen2.F90 @ 8809

Last change on this file since 8809 was 6750, checked in by jchanut, 8 years ago

Reproducibility issue with flux form advection, ticket #1749
  • Property svn:keywords set to Id
File size: 7.5 KB
RevLine 
[643]1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
[1566]7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
[643]9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
[6140]12   !!   dyn_adv_cen2  : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme 
[643]13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
[4990]16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
[643]19   USE in_out_manager ! I/O manager
[2715]20   USE lib_mpp        ! MPP library
[1129]21   USE prtctl         ! Print control
[4990]22   USE wrk_nemo       ! Memory Allocation
23   USE timing         ! Timing
[643]24
25   IMPLICIT NONE
26   PRIVATE
27
[1566]28   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
[643]29
30   !! * Substitutions
31#  include "vectopt_loop_substitute.h90"
32   !!----------------------------------------------------------------------
[2715]33   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
[1152]34   !! $Id$
[2715]35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[643]36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE dyn_adv_cen2( kt )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE dyn_adv_cen2  ***
42      !!
43      !! ** Purpose :   Compute the now momentum advection trend in flux form
[1566]44      !!              and the general trend of the momentum equation.
[643]45      !!
46      !! ** Method  :   Trend evaluated using now fields (centered in time)
47      !!
[1566]48      !! ** Action  :   (ua,va) updated with the now vorticity term trend
[643]49      !!----------------------------------------------------------------------
[1566]50      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
[2715]51      !
[1566]52      INTEGER  ::   ji, jj, jk   ! dummy loop indices
[3294]53      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfw
54      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu, zfv
[643]55      !!----------------------------------------------------------------------
[3294]56      !
57      IF( nn_timing == 1 )  CALL timing_start('dyn_adv_cen2')
58      !
[6140]59      CALL wrk_alloc( jpi,jpj,jpk,   zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
[3294]60      !
[2715]61      IF( kt == nit000 .AND. lwp ) THEN
62         WRITE(numout,*)
63         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
64         WRITE(numout,*) '~~~~~~~~~~~~'
[643]65      ENDIF
[3294]66      !
[6140]67      IF( l_trddyn ) THEN           ! trends: store the input trends
[1129]68         zfu_uw(:,:,:) = ua(:,:,:)
69         zfv_vw(:,:,:) = va(:,:,:)
70      ENDIF
[6140]71      !
72      !                             !==  Horizontal advection  ==!
73      !
74      DO jk = 1, jpkm1                    ! horizontal transport
75         zfu(:,:,jk) = 0.25_wp * e2u(:,:) * e3u_n(:,:,jk) * un(:,:,jk)
76         zfv(:,:,jk) = 0.25_wp * e1v(:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
77         DO jj = 1, jpjm1                 ! horizontal momentum fluxes (at T- and F-point)
[643]78            DO ji = 1, fs_jpim1   ! vector opt.
[6140]79               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
80               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
81               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
82               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
[643]83            END DO
84         END DO
[6140]85         DO jj = 2, jpjm1                 ! divergence of horizontal momentum fluxes
[643]86            DO ji = fs_2, fs_jpim1   ! vector opt.
[6140]87               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj,jk) - zfu_t(ji,jj  ,jk)    &
88                  &                           + zfv_f(ji  ,jj,jk) - zfv_f(ji,jj-1,jk)  ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
89               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji,jj  ,jk) - zfu_f(ji-1,jj,jk)    &
90                  &                           + zfv_t(ji,jj+1,jk) - zfv_t(ji  ,jj,jk)  ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
[643]91            END DO
92         END DO
[1566]93      END DO
94      !
[6140]95      IF( l_trddyn ) THEN           ! trends: send trend to trddyn for diagnostic
[1129]96         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
97         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
[4990]98         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt )
[1129]99         zfu_t(:,:,:) = ua(:,:,:)
100         zfv_t(:,:,:) = va(:,:,:)
101      ENDIF
[1566]102      !
[6140]103      !                             !==  Vertical advection  ==!
104      !
105      DO jj = 2, jpjm1                    ! surface/bottom advective fluxes set to zero
106         DO ji = fs_2, fs_jpim1
107            zfu_uw(ji,jj,jpk) = 0._wp   ;   zfv_vw(jj,jj,jpk) = 0._wp
108            zfu_uw(ji,jj, 1 ) = 0._wp   ;   zfv_vw(jj,jj, 1 ) = 0._wp
109         END DO
110      END DO
111      IF( ln_linssh ) THEN                ! linear free surface: advection through the surface
112         DO jj = 2, jpjm1
113            DO ji = fs_2, fs_jpim1
114               zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * wn(ji,jj,1) + e1e2t(ji+1,jj) * wn(ji+1,jj,1) ) * un(ji,jj,1)
115               zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * wn(ji,jj,1) + e1e2t(ji,jj+1) * wn(ji,jj+1,1) ) * vn(ji,jj,1)
[643]116            END DO
[6140]117         END DO
118      ENDIF
119      DO jk = 2, jpkm1                    ! interior advective fluxes
[6750]120         DO jj = 2, jpj                       ! 1/4 * Vertical transport
121            DO ji = 2, jpi
[6140]122               zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * wn(ji,jj,jk)
123            END DO
124         END DO
125         DO jj = 2, jpjm1
126            DO ji = fs_2, fs_jpim1   ! vector opt.
127               zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
128               zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
129            END DO
130         END DO
[643]131      END DO
[6140]132      DO jk = 1, jpkm1                    ! divergence of vertical momentum flux divergence
[643]133         DO jj = 2, jpjm1 
134            DO ji = fs_2, fs_jpim1   ! vector opt.
[6140]135               ua(ji,jj,jk) = ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
136               va(ji,jj,jk) = va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
[643]137            END DO
138         END DO
139      END DO
[1566]140      !
[6140]141      IF( l_trddyn ) THEN                 ! trends: send trend to trddyn for diagnostic
[1129]142         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
143         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
[4990]144         CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt )
[1129]145      ENDIF
[6140]146      !                                   ! Control print
[1129]147      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
148         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
149      !
[3294]150      CALL wrk_dealloc( jpi, jpj, jpk, zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
[2715]151      !
[3294]152      IF( nn_timing == 1 )  CALL timing_stop('dyn_adv_cen2')
153      !
[643]154   END SUBROUTINE dyn_adv_cen2
155
156   !!==============================================================================
157END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.