New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_lap_blp.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DYN/dynldf_lap_blp.F90 @ 5836

Last change on this file since 5836 was 5836, checked in by cetlod, 9 years ago

merge the simplification branch onto the trunk, see ticket #1612
  • Property svn:keywords set to Id
File size: 8.8 KB
Line 
1MODULE dynldf_lap_blp
2   !!======================================================================
3   !!                   ***  MODULE  dynldf_lap_blp  ***
4   !! Ocean dynamics:  lateral viscosity trend (laplacian and bilaplacian)
5   !!======================================================================
6   !! History :  OPA  ! 1990-09 (G. Madec) Original code
7   !!            4.0  ! 1991-11 (G. Madec)
8   !!            6.0  ! 1996-01 (G. Madec) statement function for e3 and ahm
9   !!   NEMO     1.0  ! 2002-06 (G. Madec)  F90: Free form and module
10   !!             -   ! 2004-08 (C. Talandier) New trends organization
11   !!            3.7  ! 2014-01  (F. Lemarie, G. Madec)  restructuration/simplification of ahm specification,
12   !!                 !                                  add velocity dependent coefficient and optional read in file
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   dyn_ldf_lap   : update the momentum trend with the lateral viscosity using an iso-level   laplacian operator
17   !!   dyn_ldf_blp   : update the momentum trend with the lateral viscosity using an iso-level bilaplacian operator
18   !!----------------------------------------------------------------------
19   USE oce            ! ocean dynamics and tracers
20   USE dom_oce        ! ocean space and time domain
21   USE ldfdyn         ! lateral diffusion: eddy viscosity coef.
22   USE ldfslp         ! iso-neutral slopes
23   USE zdf_oce        ! ocean vertical physics
24   !
25   USE in_out_manager ! I/O manager
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE wrk_nemo       ! Memory Allocation
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC dyn_ldf_lap  ! called by dynldf.F90
34   PUBLIC dyn_ldf_blp  ! called by dynldf.F90
35
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE dyn_ldf_lap( kt, pub, pvb, pua, pva, kpass )
47      !!----------------------------------------------------------------------
48      !!                     ***  ROUTINE dyn_ldf_lap  ***
49      !!                       
50      !! ** Purpose :   Compute the before horizontal momentum diffusive
51      !!      trend and add it to the general trend of momentum equation.
52      !!
53      !! ** Method  :   The Laplacian operator apply on horizontal velocity is
54      !!      writen as :   grad_h( ahmt div_h(U )) - curl_h( ahmf curl_z(U) )
55      !!
56      !! ** Action : - pua, pva increased by the harmonic operator applied on pub, pvb.
57      !!----------------------------------------------------------------------
58      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
59      INTEGER                         , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
60      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pub, pvb   ! before velocity  [m/s]
61      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! velocity trend   [m/s2]
62      !
63      INTEGER  ::   ji, jj, jk   ! dummy loop indices
64      REAL(wp) ::   zsign        ! local scalars
65      REAL(wp) ::   zua, zva     ! local scalars
66      REAL(wp), POINTER, DIMENSION(:,:) ::  zcur, zdiv
67      !!----------------------------------------------------------------------
68      !
69      IF( kt == nit000 .AND. lwp ) THEN
70         WRITE(numout,*)
71         WRITE(numout,*) 'dyn_ldf : iso-level harmonic (laplacian) operator, pass=', kpass
72         WRITE(numout,*) '~~~~~~~ '
73      ENDIF
74      !
75      IF( nn_timing == 1 )   CALL timing_start('dyn_ldf_lap')
76      !
77      CALL wrk_alloc( jpi, jpj, zcur, zdiv ) 
78      !
79      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign
80      ELSE                    ;   zsign = -1._wp      !  (eddy viscosity coef. >0)
81      ENDIF
82      !
83      !                                                ! ===============
84      DO jk = 1, jpkm1                                 ! Horizontal slab
85         !                                             ! ===============
86         DO jj = 2, jpj
87            DO ji = fs_2, jpi   ! vector opt.
88               !                                      ! ahm * e3 * curl  (computed from 1 to jpim1/jpjm1)
89               zcur(ji-1,jj-1) = ahmf(ji-1,jj-1,jk) * fse3f(ji-1,jj-1,jk) * r1_e1e2f(ji-1,jj-1)      &
90                  &     * (  e2v(ji  ,jj-1) * pvb(ji  ,jj-1,jk) - e2v(ji-1,jj-1) * pvb(ji-1,jj-1,jk)                &
91                  &        - e1u(ji-1,jj  ) * pub(ji-1,jj  ,jk) + e1u(ji-1,jj-1) * pub(ji-1,jj-1,jk)  ) * fmask(ji-1,jj-1,jk)
92               !                                      ! ahm * div        (computed from 2 to jpi/jpj)
93               zdiv(ji,jj)     = ahmt(ji,jj,jk) / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )                     * tmask(ji,jj,jk)    &
94                  &     * (  e2u(ji,jj)*fse3u(ji,jj,jk) * pub(ji,jj,jk) - e2u(ji-1,jj)*fse3u(ji-1,jj,jk) * pub(ji-1,jj,jk)    &
95                  &        + e1v(ji,jj)*fse3v(ji,jj,jk) * pvb(ji,jj,jk) - e1v(ji,jj-1)*fse3v(ji,jj-1,jk) * pvb(ji,jj-1,jk)  )
96            END DO 
97         END DO 
98         !
99         DO jj = 2, jpjm1                             ! - curl( curl) + grad( div )
100            DO ji = fs_2, fs_jpim1   ! vector opt.
101               pua(ji,jj,jk) = pua(ji,jj,jk) + zsign * (                                                   &
102                  &              - ( zcur(ji  ,jj) - zcur(ji,jj-1) ) /  ( e2u(ji,jj) * fse3u(ji,jj,jk) )   &
103                  &              + ( zdiv(ji+1,jj) - zdiv(ji,jj  ) ) * r1_e1u(ji,jj)                     )
104                  !
105               pva(ji,jj,jk) = pva(ji,jj,jk) + zsign * (                                                   &
106                  &                ( zcur(ji,jj  ) - zcur(ji-1,jj) ) /  ( e1v(ji,jj) * fse3v(ji,jj,jk) )   &
107                  &              + ( zdiv(ji,jj+1) - zdiv(ji  ,jj) ) * r1_e2v(ji,jj)                     )
108            END DO
109         END DO
110         !                                             ! ===============
111      END DO                                           !   End of slab
112      !                                                ! ===============
113      CALL wrk_dealloc( jpi, jpj, zcur, zdiv ) 
114      !
115      IF( nn_timing == 1 )  CALL timing_stop('dyn_ldf_lap')
116      !
117   END SUBROUTINE dyn_ldf_lap
118
119
120   SUBROUTINE dyn_ldf_blp( kt, pub, pvb, pua, pva )
121      !!----------------------------------------------------------------------
122      !!                 ***  ROUTINE dyn_ldf_blp  ***
123      !!                   
124      !! ** Purpose :   Compute the before lateral momentum viscous trend
125      !!              and add it to the general trend of momentum equation.
126      !!
127      !! ** Method  :   The lateral viscous trends is provided by a bilaplacian
128      !!      operator applied to before field (forward in time).
129      !!      It is computed by two successive calls to dyn_ldf_lap routine
130      !!
131      !! ** Action :   pta   updated with the before rotated bilaplacian diffusion
132      !!----------------------------------------------------------------------
133      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
134      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pub, pvb   ! before velocity fields
135      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! momentum trend
136      !
137      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zulap, zvlap   ! laplacian at u- and v-point
138      !!----------------------------------------------------------------------
139      !
140      IF( nn_timing == 1 )  CALL timing_start('dyn_ldf_blp')
141      !
142      CALL wrk_alloc( jpi, jpj, jpk, zulap, zvlap ) 
143      !
144      IF( kt == nit000 )  THEN
145         IF(lwp) WRITE(numout,*)
146         IF(lwp) WRITE(numout,*) 'dyn_ldf_blp : bilaplacian operator momentum '
147         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
148      ENDIF
149      !
150      zulap(:,:,:) = 0._wp
151      zvlap(:,:,:) = 0._wp
152      !
153      CALL dyn_ldf_lap( kt, pub, pvb, zulap, zvlap, 1 )   ! rotated laplacian applied to ptb (output in zlap)
154      !
155      CALL lbc_lnk( zulap(:,:,:) , 'U', -1. )             ! Lateral boundary conditions
156      CALL lbc_lnk( zvlap(:,:,:) , 'V', -1. )
157      !
158      CALL dyn_ldf_lap( kt, zulap, zvlap, pua, pva, 2 )   ! rotated laplacian applied to zlap (output in pta)
159      !
160      CALL wrk_dealloc( jpi, jpj, jpk, zulap, zvlap ) 
161      !
162      IF( nn_timing == 1 )  CALL timing_stop('dyn_ldf_blp')
163      !
164   END SUBROUTINE dyn_ldf_blp
165
166   !!======================================================================
167END MODULE dynldf_lap_blp
Note: See TracBrowser for help on using the repository browser.