New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk
  • Property svn:keywords set to Id
File size: 8.2 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  87-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  91-11  (G. Madec)
8   !!                 !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  96-01  (G. Madec)  statement function for e3
10   !!            NEMO !  02-06  (G. Madec)  F90: Free form and module
11   !!            1.0  !  04-08  (C. Talandier) New trends organization
12   !!                 !  05-11  (G. Madec)  add zps case
13   !!            3.0  !  10-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
18   !!                 using a iso-level harmonic (laplacien) operator.
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE ldftra_oce      ! ocean active tracers: lateral physics
23   USE in_out_manager  ! I/O manager
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26   USE lib_mpp         ! MPP library
27   USE timing          ! Timing
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_ldf_lap   ! routine called by step.F90
33
34   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:) ::   e1ur, e2vr   ! scale factor coefficients
35
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "ldftra_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_ldf_lap( kt, kit000, cdtype, pgu, pgv,      &
48      &                                ptb, pta, kjpt ) 
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE tra_ldf_lap  ***
51      !!                   
52      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
53      !!      trend and add it to the general trend of tracer equation.
54      !!
55      !! ** Method  :   Second order diffusive operator evaluated using before
56      !!      fields (forward time scheme). The horizontal diffusive trends of
57      !!      the tracer is given by:
58      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
59      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
60      !!      Add this trend to the general tracer trend pta :
61      !!          pta = pta + difft
62      !!
63      !! ** Action  : - Update pta arrays with the before iso-level
64      !!                harmonic mixing trend.
65      !!----------------------------------------------------------------------
66      USE oce, ONLY:   ztu => ua , ztv => va  ! (ua,va) used as workspace
67      !
68      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
69      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
70      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
71      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
72      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
73      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
74      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
75      !
76      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
77      INTEGER  ::   iku, ikv, ierr       ! local integers
78      REAL(wp) ::   zabe1, zabe2, zbtr   ! local scalars
79      !!----------------------------------------------------------------------
80      !
81      CALL timing_start('tra_ldf_lap')
82      !
83      IF( kt == kit000 )  THEN
84         IF(lwp) WRITE(numout,*)
85         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype
86         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
87         !
88         IF( .NOT. ALLOCATED( e1ur ) ) THEN
89            ! This routine may be called for both active and passive tracers.
90            ! Allocate and set saved arrays on first call only.
91            ALLOCATE( e1ur(jpi,jpj), e2vr(jpi,jpj), STAT=ierr )
92            IF( lk_mpp    )   CALL mpp_sum( ierr )
93            IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'tra_ldf_lap : unable to allocate arrays' )
94            !
95            e1ur(:,:) = e2u(:,:) / e1u(:,:)
96            e2vr(:,:) = e1v(:,:) / e2v(:,:)
97         ENDIF
98      ENDIF
99
100      !                                                          ! =========== !
101      DO jn = 1, kjpt                                            ! tracer loop !
102         !                                                       ! =========== !   
103         DO jk = 1, jpkm1                                            ! slab loop
104            !                                           
105            ! 1. First derivative (gradient)
106            ! -------------------
107            DO jj = 1, jpjm1
108               DO ji = 1, fs_jpim1   ! vector opt.
109                  zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * e1ur(ji,jj) * fse3u(ji,jj,jk)
110                  zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * e2vr(ji,jj) * fse3v(ji,jj,jk)
111                  ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
112                  ztv(ji,jj,jk) = zabe2 * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
113               END DO
114            END DO
115            IF( ln_zps ) THEN      ! set gradient at partial step level
116               DO jj = 1, jpjm1
117                  DO ji = 1, fs_jpim1   ! vector opt.
118                     ! last level
119                     iku = mbku(ji,jj)
120                     ikv = mbkv(ji,jj)
121                     IF( iku == jk ) THEN
122                        zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * e1ur(ji,jj) * fse3u(ji,jj,iku)
123                        ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn)
124                     ENDIF
125                     IF( ikv == jk ) THEN
126                        zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * e2vr(ji,jj) * fse3v(ji,jj,ikv)
127                        ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn)
128                     ENDIF
129                  END DO
130               END DO
131            ENDIF
132         
133         
134            ! 2. Second derivative (divergence) added to the general tracer trends
135            ! ---------------------------------------------------------------------
136            DO jj = 2, jpjm1
137               DO ji = fs_2, fs_jpim1   ! vector opt.
138                  zbtr = 1._wp / ( e1t(ji,jj) *e2t(ji,jj) * fse3t(ji,jj,jk) )
139                  ! horizontal diffusive trends added to the general tracer trends
140                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
141                     &                                          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
142               END DO
143            END DO
144            !
145         END DO                                             !  End of slab 
146         !
147         ! "Poleward" diffusive heat or salt transports
148         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
149            IF( jn  == jp_tem)   htr_ldf(:) = ptr_vj( ztv(:,:,:) )
150            IF( jn  == jp_sal)   str_ldf(:) = ptr_vj( ztv(:,:,:) )
151         ENDIF
152         !                                                  ! ==================
153      END DO                                                ! end of tracer loop
154      !                                                     ! ==================
155      CALL timing_stop('tra_ldf_lap')
156      !
157   END SUBROUTINE tra_ldf_lap
158
159   !!==============================================================================
160END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.