New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 7.8 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  87-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  91-11  (G. Madec)
8   !!                 !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  96-01  (G. Madec)  statement function for e3
10   !!            NEMO !  02-06  (G. Madec)  F90: Free form and module
11   !!            1.0  !  04-08  (C. Talandier) New trends organization
12   !!                 !  05-11  (G. Madec)  add zps case
13   !!            3.0  !  10-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
18   !!                 using a iso-level harmonic (laplacien) operator.
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE ldftra_oce      ! ocean active tracers: lateral physics
23   USE in_out_manager  ! I/O manager
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   tra_ldf_lap   ! routine called by step.F90
32
33   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:) ::   e1ur, e2vr   ! scale factor coefficients
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "ldftra_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE tra_ldf_lap( kt, cdtype, pgu, pgv,      &
47      &                                ptb, pta, kjpt ) 
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE tra_ldf_lap  ***
50      !!                   
51      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
52      !!      trend and add it to the general trend of tracer equation.
53      !!
54      !! ** Method  :   Second order diffusive operator evaluated using before
55      !!      fields (forward time scheme). The horizontal diffusive trends of
56      !!      the tracer is given by:
57      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
58      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
59      !!      Add this trend to the general tracer trend pta :
60      !!          pta = pta + difft
61      !!
62      !! ** Action  : - Update pta arrays with the before iso-level
63      !!                harmonic mixing trend.
64      !!----------------------------------------------------------------------
65      USE oce, ONLY:   ztu => ua , ztv => va  ! (ua,va) used as workspace
66      !
67      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
70      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
71      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
73      !
74      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
75      INTEGER  ::   iku, ikv, ierr       ! local integers
76      REAL(wp) ::   zabe1, zabe2, zbtr   ! local scalars
77      !!----------------------------------------------------------------------
78     
79      IF( kt == nit000 )  THEN
80         IF(lwp) WRITE(numout,*)
81         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype
82         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
83         !
84         ALLOCATE( e1ur(jpi,jpj), e2vr(jpi,jpj), STAT=ierr )
85         IF( lk_mpp    )   CALL mpp_sum( ierr )
86         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'tra_ldf_lap : unable to allocate arrays' )
87         !
88         e1ur(:,:) = e2u(:,:) / e1u(:,:)
89         e2vr(:,:) = e1v(:,:) / e2v(:,:)
90      ENDIF
91
92      !                                                          ! =========== !
93      DO jn = 1, kjpt                                            ! tracer loop !
94         !                                                       ! =========== !   
95         DO jk = 1, jpkm1                                            ! slab loop
96            !                                           
97            ! 1. First derivative (gradient)
98            ! -------------------
99            DO jj = 1, jpjm1
100               DO ji = 1, fs_jpim1   ! vector opt.
101                  zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * e1ur(ji,jj) * fse3u(ji,jj,jk)
102                  zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * e2vr(ji,jj) * fse3v(ji,jj,jk)
103                  ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
104                  ztv(ji,jj,jk) = zabe2 * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
105               END DO
106            END DO
107            IF( ln_zps ) THEN      ! set gradient at partial step level
108               DO jj = 1, jpjm1
109                  DO ji = 1, fs_jpim1   ! vector opt.
110                     ! last level
111                     iku = mbku(ji,jj)
112                     ikv = mbkv(ji,jj)
113                     IF( iku == jk ) THEN
114                        zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * e1ur(ji,jj) * fse3u(ji,jj,iku)
115                        ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn)
116                     ENDIF
117                     IF( ikv == jk ) THEN
118                        zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * e2vr(ji,jj) * fse3v(ji,jj,ikv)
119                        ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn)
120                     ENDIF
121                  END DO
122               END DO
123            ENDIF
124         
125         
126            ! 2. Second derivative (divergence) added to the general tracer trends
127            ! ---------------------------------------------------------------------
128            DO jj = 2, jpjm1
129               DO ji = fs_2, fs_jpim1   ! vector opt.
130                  zbtr = 1._wp / ( e1t(ji,jj) *e2t(ji,jj) * fse3t(ji,jj,jk) )
131                  ! horizontal diffusive trends added to the general tracer trends
132                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
133                     &                                          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
134               END DO
135            END DO
136            !
137         END DO                                             !  End of slab 
138         !
139         ! "Poleward" diffusive heat or salt transports
140         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
141            IF( jn  == jp_tem)   htr_ldf(:) = ptr_vj( ztv(:,:,:) )
142            IF( jn  == jp_sal)   str_ldf(:) = ptr_vj( ztv(:,:,:) )
143         ENDIF
144         !                                                  ! ==================
145      END DO                                                ! end of tracer loop
146      !                                                     ! ==================
147   END SUBROUTINE tra_ldf_lap
148
149   !!==============================================================================
150END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.