New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zsink.F90 @ 2773

Last change on this file since 2773 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 32.0 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :   PISCES Compute vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8#if defined key_pisces
9   !!----------------------------------------------------------------------
10   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
11   !!----------------------------------------------------------------------
12   USE trc
13   USE oce_trc         !
14   USE sms_pisces
15   USE prtctl_trc
16   USE iom
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   p4z_sink         ! called in p4zbio.F90
22   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
23   PUBLIC   p4z_sink_alloc
24
25   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio3   !: POC sinking speed
26   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio4   !: GOC sinking speed
27   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wscal    !: Calcite and BSi sinking speeds
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
30   !                                                          !  (different meanings depending on the parameterization)
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
33#if ! defined key_kriest
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
35#endif
36
37   INTEGER  :: iksed  = 10
38
39#if  defined key_kriest
40   REAL(wp) ::  xkr_sfact    = 250.     !: Sinking factor
41   REAL(wp) ::  xkr_stick    = 0.2      !: Stickiness
42   REAL(wp) ::  xkr_nnano    = 2.337    !: Nbr of cell in nano size class
43   REAL(wp) ::  xkr_ndiat    = 3.718    !: Nbr of cell in diatoms size class
44   REAL(wp) ::  xkr_nmeso    = 7.147    !: Nbr of cell in mesozoo  size class
45   REAL(wp) ::  xkr_naggr    = 9.877    !: Nbr of cell in aggregates  size class
46
47   REAL(wp) ::  xkr_frac 
48
49   REAL(wp), PUBLIC ::  xkr_dnano       !: Size of particles in nano pool
50   REAL(wp), PUBLIC ::  xkr_ddiat       !: Size of particles in diatoms pool
51   REAL(wp), PUBLIC ::  xkr_dmeso       !: Size of particles in mesozoo pool
52   REAL(wp), PUBLIC ::  xkr_daggr       !: Size of particles in aggregates pool
53   REAL(wp), PUBLIC ::  xkr_wsbio_min   !: min vertical particle speed
54   REAL(wp), PUBLIC ::  xkr_wsbio_max   !: max vertical particle speed
55
56   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) ::   xnumm   !:  maximum number of particles in aggregates
57#endif
58
59   !!* Substitution
60#  include "top_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68#if defined key_kriest
69   !!----------------------------------------------------------------------
70   !!   'key_kriest'                                                    ???
71   !!----------------------------------------------------------------------
72
73   SUBROUTINE p4z_sink ( kt, jnt )
74      !!---------------------------------------------------------------------
75      !!                ***  ROUTINE p4z_sink  ***
76      !!
77      !! ** Purpose :   Compute vertical flux of particulate matter due to
78      !!              gravitational sinking - Kriest parameterization
79      !!
80      !! ** Method  : - ???
81      !!---------------------------------------------------------------------
82      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
83      USE wrk_nemo, ONLY:   znum3d => wrk_3d_2
84      !
85      INTEGER, INTENT(in) :: kt, jnt
86      !
87      INTEGER  :: ji, jj, jk
88      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zaggsi, zaggsh
89      REAL(wp) :: zagg , zaggdoc, znumdoc
90      REAL(wp) :: znum , zeps, zfm, zgm, zsm
91      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
92      REAL(wp) :: zval1, zval2, zval3, zval4
93#if defined key_diatrc
94      REAL(wp) :: zrfact2
95      INTEGER  :: ik1
96#endif
97      CHARACTER (len=25) :: charout
98      !!---------------------------------------------------------------------
99      !
100      IF( wrk_in_use(3, 2 ) ) THEN
101         CALL ctl_stop('p4z_sink: requested workspace arrays unavailable')   ;   RETURN
102      ENDIF
103     
104      !     Initialisation of variables used to compute Sinking Speed
105      !     ---------------------------------------------------------
106
107      znum3d(:,:,:) = 0.e0
108      zval1 = 1. + xkr_zeta
109      zval2 = 1. + xkr_zeta + xkr_eta
110      zval3 = 1. + xkr_eta
111
112      !     Computation of the vertical sinking speed : Kriest et Evans, 2000
113      !     -----------------------------------------------------------------
114
115      DO jk = 1, jpkm1
116         DO jj = 1, jpj
117            DO ji = 1, jpi
118               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
119                  znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
120                  ! -------------- To avoid sinking speed over 50 m/day -------
121                  znum  = MIN( xnumm(jk), znum )
122                  znum  = MAX( 1.1      , znum )
123                  znum3d(ji,jj,jk) = znum
124                  !------------------------------------------------------------
125                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
126                  zfm   = xkr_frac**( 1. - zeps )
127                  zgm   = xkr_frac**( zval1 - zeps )
128                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
129                  zdiv1 = zeps - zval3
130                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
131                     &             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
132                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
133                     &             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
134                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
135               ENDIF
136            END DO
137         END DO
138      END DO
139
140      wscal(:,:,:) = MAX( wsbio3(:,:,:), 50._wp )
141
142      !   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
143      !   -----------------------------------------
144
145      sinking (:,:,:) = 0.e0
146      sinking2(:,:,:) = 0.e0
147      sinkcal (:,:,:) = 0.e0
148      sinkfer (:,:,:) = 0.e0
149      sinksil (:,:,:) = 0.e0
150
151     !   Compute the sedimentation term using p4zsink2 for all the sinking particles
152     !   -----------------------------------------------------
153
154      CALL p4z_sink2( wsbio3, sinking , jppoc )
155      CALL p4z_sink2( wsbio4, sinking2, jpnum )
156      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
157      CALL p4z_sink2( wscal , sinksil , jpdsi )
158      CALL p4z_sink2( wscal , sinkcal , jpcal )
159
160     !  Exchange between organic matter compartments due to coagulation/disaggregation
161     !  ---------------------------------------------------
162
163      zval1 = 1. + xkr_zeta
164      zval2 = 1. + xkr_eta
165      zval3 = 3. + xkr_eta
166      zval4 = 4. + xkr_eta
167
168      DO jk = 1,jpkm1
169         DO jj = 1,jpj
170            DO ji = 1,jpi
171               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
172
173                  znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp
174                  !-------------- To avoid sinking speed over 50 m/day -------
175                  znum  = min(xnumm(jk),znum)
176                  znum  = MAX( 1.1,znum)
177                  !------------------------------------------------------------
178                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
179                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
180                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
181                  zdiv2 = zeps - 2.
182                  zdiv3 = zeps - 3.
183                  zdiv4 = zeps - zval2
184                  zdiv5 = 2.* zeps - zval4
185                  zfm   = xkr_frac**( 1.- zeps )
186                  zsm   = xkr_frac**xkr_eta
187
188                  !    Part I : Coagulation dependant on turbulence
189                  !    ----------------------------------------------
190
191                  zagg1 = ( 0.163 * trn(ji,jj,jk,jpnum)**2               &
192                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
193                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
194                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
195                     &            * (zeps-1.)**2/(zdiv2*zdiv3))            &
196# if defined key_degrad
197                     &                 *facvol(ji,jj,jk)       &
198# endif
199                     &    )
200
201                  zagg2 = (  2*0.163*trn(ji,jj,jk,jpnum)**2*zfm*                       &
202                     &                   ((xkr_mass_max**3+3.*(xkr_mass_max**2          &
203                     &                    *xkr_mass_min*(zeps-1.)/zdiv2                 &
204                     &                    +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
205                     &                    +xkr_mass_min**3*(zeps-1)/zdiv1)                  &
206                     &                    -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/           &
207                     &                    (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))      &
208#    if defined key_degrad
209                     &                 *facvol(ji,jj,jk)             &
210#    endif
211                     &    )
212
213                  zagg3 = (  0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3   &
214#    if defined key_degrad
215                     &                 *facvol(ji,jj,jk)             &
216#    endif
217                     &    )
218
219                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
220
221                 !    Aggregation of small into large particles
222                 !    Part II : Differential settling
223                 !    ----------------------------------------------
224
225                  zagg4 = (  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2*                       &
226                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
227                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
228                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
229                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
230                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )                     &
231# if defined key_degrad
232                     &                 *facvol(ji,jj,jk)        &
233# endif
234                     &    )
235
236                  zagg5 = (  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2                         &
237                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
238                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
239                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
240                     &                 /zdiv)                   &
241# if defined key_degrad
242                     &                 *facvol(ji,jj,jk)        &
243# endif
244                     &    )
245
246                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
247
248                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
249
250                  !     Aggregation of DOC to small particles
251                  !     --------------------------------------
252
253                  zaggdoc = ( 0.4 * trn(ji,jj,jk,jpdoc)               &
254                     &        + 1018.  * trn(ji,jj,jk,jppoc)  ) * xstep    &
255# if defined key_degrad
256                     &        * facvol(ji,jj,jk)                              &
257# endif
258                     &        * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
259
260                  znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
261                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc
262                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zaggdoc * znumdoc - zagg
263                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc
264
265               ENDIF
266            END DO
267         END DO
268      END DO
269
270#if defined key_diatrc
271      zrfact2 = 1.e3 * rfact2r
272      ik1 = iksed + 1
273#  if ! defined key_iomput
274      trc2d(:,:  ,jp_pcs0_2d + 4)  = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1)
275      trc2d(:,:  ,jp_pcs0_2d + 5)  = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1)
276      trc2d(:,:  ,jp_pcs0_2d + 6)  = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1)
277      trc2d(:,:  ,jp_pcs0_2d + 7)  = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1)
278      trc2d(:,:  ,jp_pcs0_2d + 8)  = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1)
279      trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)      * zrfact2 * tmask(:,:,:)
280      trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)      * zrfact2 * tmask(:,:,:)
281      trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)      * zrfact2 * tmask(:,:,:)
282      trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:)
283      trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)                * tmask(:,:,:)
284      trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)                * tmask(:,:,:)
285      trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)                * tmask(:,:,:)
286#else
287      IF( jnt == nrdttrc ) then
288        CALL iom_put( "POCFlx"  , sinking (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! POC export
289        CALL iom_put( "NumFlx"  , sinking2 (:,:,:)     * zrfact2 * tmask(:,:,:) )  ! Num export
290        CALL iom_put( "SiFlx"   , sinksil (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Silica export
291        CALL iom_put( "CaCO3Flx", sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Calcite export
292        CALL iom_put( "xnum"    , znum3d  (:,:,:)                * tmask(:,:,:) )  ! Number of particles in aggregats
293        CALL iom_put( "W1"      , wsbio3  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of POC
294        CALL iom_put( "W2"      , wsbio4  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of aggregats
295        CALL iom_put( "PMO"     , sinking (:,:,ik1) * zrfact2 * tmask(:,:,1) )  ! POC export at 100m
296        CALL iom_put( "PMO2"    , sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1) )  ! Num export at 100m
297        CALL iom_put( "ExpFe1"  , sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1) )  ! Export of iron at 100m
298        CALL iom_put( "ExpSi"   , sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1) )  ! export of silica at 100m
299        CALL iom_put( "ExpCaCO3", sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1) )  ! export of calcite at 100m
300     ENDIF
301#  endif
302
303#endif
304      !
305      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
306         WRITE(charout, FMT="('sink')")
307         CALL prt_ctl_trc_info(charout)
308         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
309      ENDIF
310      !
311      IF( wrk_not_released(3, 2 ) )   CALL ctl_stop('p4z_sink: failed to release workspace arrays')
312      !
313   END SUBROUTINE p4z_sink
314
315
316   SUBROUTINE p4z_sink_init
317      !!----------------------------------------------------------------------
318      !!                  ***  ROUTINE p4z_sink_init  ***
319      !!
320      !! ** Purpose :   Initialization of sinking parameters
321      !!                Kriest parameterization only
322      !!
323      !! ** Method  :   Read the nampiskrs namelist and check the parameters
324      !!      called at the first timestep
325      !!
326      !! ** input   :   Namelist nampiskrs
327      !!----------------------------------------------------------------------
328      INTEGER  ::   jk, jn, kiter
329      REAL(wp) ::   znum, zdiv
330      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
331      REAL(wp) ::   zmin, zmax, zl, zr, xacc
332      !
333      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
334         &                xkr_nnano, xkr_ndiat, xkr_nmeso, xkr_naggr
335      !!----------------------------------------------------------------------
336      !
337      REWIND( numnat )                     ! read nampiskrs
338      READ  ( numnat, nampiskrs )
339
340      IF(lwp) THEN
341         WRITE(numout,*)
342         WRITE(numout,*) ' Namelist : nampiskrs'
343         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
344         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
345         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
346         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
347         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
348         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
349      ENDIF
350
351
352      ! max and min vertical particle speed
353      xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
354      xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
355      WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
356
357      !
358      !    effect of the sizes of the different living pools on particle numbers
359      !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
360      !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
361      !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
362      !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
363      !    doc aggregates = 1um
364      ! ----------------------------------------------------------
365
366      xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
367      xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
368      xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
369      xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
370
371      !!---------------------------------------------------------------------
372      !!    'key_kriest'                                                  ???
373      !!---------------------------------------------------------------------
374      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
375      !  Search of the maximum number of particles in aggregates for each k-level.
376      !  Bissection Method
377      !--------------------------------------------------------------------
378      WRITE(numout,*)
379      WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
380
381      xacc     =  0.001_wp
382      kiter    = 50
383      zmin     =  1.10_wp
384      zmax     = xkr_mass_max / xkr_mass_min
385      xkr_frac = zmax
386
387      DO jk = 1,jpk
388         zl = zmin
389         zr = zmax
390         wmax = 0.5 * fse3t(1,1,jk) * rday / rfact2
391         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
392         znum = zl - 1.
393         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
394            & - ( xkr_wsbio_max * xkr_eta * znum * &
395            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
396            & - wmax
397
398         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
399         znum = zr - 1.
400         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
401            & - ( xkr_wsbio_max * xkr_eta * znum * &
402            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
403            & - wmax
404iflag:   DO jn = 1, kiter
405            IF    ( zwl == 0._wp ) THEN   ;   znummax = zl
406            ELSEIF( zwr == 0._wp ) THEN   ;   znummax = zr
407            ELSE
408               znummax = ( zr + zl ) / 2.
409               zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
410               znum = znummax - 1.
411               zws =  xkr_wsbio_min * xkr_zeta / zdiv &
412                  & - ( xkr_wsbio_max * xkr_eta * znum * &
413                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
414                  & - wmax
415               IF( zws * zwl < 0. ) THEN   ;   zr = znummax
416               ELSE                        ;   zl = znummax
417               ENDIF
418               zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
419               znum = zl - 1.
420               zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
421                  & - ( xkr_wsbio_max * xkr_eta * znum * &
422                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
423                  & - wmax
424
425               zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
426               znum = zr - 1.
427               zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
428                  & - ( xkr_wsbio_max * xkr_eta * znum * &
429                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
430                  & - wmax
431               !
432               IF ( ABS ( zws )  <= xacc ) EXIT iflag
433               !
434            ENDIF
435            !
436         END DO iflag
437
438         xnumm(jk) = znummax
439         WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
440         !
441      END DO
442      !
443  END SUBROUTINE p4z_sink_init
444
445#else
446
447   SUBROUTINE p4z_sink ( kt, jnt )
448      !!---------------------------------------------------------------------
449      !!                     ***  ROUTINE p4z_sink  ***
450      !!
451      !! ** Purpose :   Compute vertical flux of particulate matter due to
452      !!                gravitational sinking
453      !!
454      !! ** Method  : - ???
455      !!---------------------------------------------------------------------
456      INTEGER, INTENT(in) :: kt, jnt
457      INTEGER  ::   ji, jj, jk
458      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
459      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2
460      REAL(wp) ::   zfact, zwsmax, zstep
461#if defined key_diatrc
462      REAL(wp) ::   zrfact2
463      INTEGER  ::   ik1
464#endif
465      CHARACTER (len=25) :: charout
466      !!---------------------------------------------------------------------
467
468      !    Sinking speeds of detritus is increased with depth as shown
469      !    by data and from the coagulation theory
470      !    -----------------------------------------------------------
471      DO jk = 1, jpkm1
472         DO jj = 1, jpj
473            DO ji=1,jpi
474               zfact = MAX( 0., fsdepw(ji,jj,jk+1) - hmld(ji,jj) ) / 4000._wp
475               wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact
476            END DO
477         END DO
478      END DO
479
480      ! limit the values of the sinking speeds to avoid numerical instabilities 
481      wsbio3(:,:,:) = wsbio
482      !
483      ! OA Below, this is garbage. the ideal would be to find a time-splitting
484      ! OA algorithm that does not increase the computing cost by too much
485      ! OA In ROMS, I have included a time-splitting procedure. But it is
486      ! OA too expensive as the loop is computed globally. Thus, a small e3t
487      ! OA at one place determines the number of subtimesteps globally
488      ! OA AWFULLY EXPENSIVE !! Not able to find a better approach. Damned !!
489
490      DO jk = 1,jpkm1
491         DO jj = 1, jpj
492            DO ji = 1, jpi
493               zwsmax = 0.8 * fse3t(ji,jj,jk) / xstep
494               wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax )
495               wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax )
496            END DO
497         END DO
498      END DO
499
500      wscal(:,:,:) = wsbio4(:,:,:)
501
502      !  Initializa to zero all the sinking arrays
503      !   -----------------------------------------
504
505      sinking (:,:,:) = 0.e0
506      sinking2(:,:,:) = 0.e0
507      sinkcal (:,:,:) = 0.e0
508      sinkfer (:,:,:) = 0.e0
509      sinksil (:,:,:) = 0.e0
510      sinkfer2(:,:,:) = 0.e0
511
512      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
513      !   -----------------------------------------------------
514
515      CALL p4z_sink2( wsbio3, sinking , jppoc )
516      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
517      CALL p4z_sink2( wsbio4, sinking2, jpgoc )
518      CALL p4z_sink2( wsbio4, sinkfer2, jpbfe )
519      CALL p4z_sink2( wsbio4, sinksil , jpdsi )
520      CALL p4z_sink2( wscal , sinkcal , jpcal )
521
522      !  Exchange between organic matter compartments due to coagulation/disaggregation
523      !  ---------------------------------------------------
524
525      DO jk = 1, jpkm1
526         DO jj = 1, jpj
527            DO ji = 1, jpi
528# if defined key_degrad
529               zstep = xstep * facvol(ji,jj,jk)
530# else
531               zstep = xstep 
532# endif
533               zfact = zstep * xdiss(ji,jj,jk)
534               !  Part I : Coagulation dependent on turbulence
535               zagg1 = 940.* zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
536               zagg2 = 1.054e4 * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
537
538               ! Part II : Differential settling
539
540               !  Aggregation of small into large particles
541               zagg3 = 0.66 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
542               zagg4 = 0.e0 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
543
544               zagg   = zagg1 + zagg2 + zagg3 + zagg4
545               zaggfe = zagg * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn )
546
547               ! Aggregation of DOC to small particles
548               zaggdoc = ( 80.* trn(ji,jj,jk,jpdoc) + 698. * trn(ji,jj,jk,jppoc) ) *  zfact * trn(ji,jj,jk,jpdoc) 
549               zaggdoc2 = 1.05e4 * zfact * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpdoc)
550
551               !  Update the trends
552               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc
553               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2
554               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
555               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
556               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2
557               !
558            END DO
559         END DO
560      END DO
561
562#if defined key_diatrc
563      zrfact2 = 1.e3 * rfact2r
564      ik1  = iksed + 1
565#  if ! defined key_iomput
566      trc2d(:,:,jp_pcs0_2d + 4) = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1)
567      trc2d(:,:,jp_pcs0_2d + 5) = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1)
568      trc2d(:,:,jp_pcs0_2d + 6) = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1)
569      trc2d(:,:,jp_pcs0_2d + 7) = sinkfer2(:,:,ik1) * zrfact2 * tmask(:,:,1)
570      trc2d(:,:,jp_pcs0_2d + 8) = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1)
571      trc2d(:,:,jp_pcs0_2d + 9) = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1)
572#  else
573      IF( jnt == nrdttrc )  then
574         CALL iom_put( "EPC100"  , ( sinking(:,:,ik1) + sinking2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of carbon at 100m
575         CALL iom_put( "EPFE100" , ( sinkfer(:,:,ik1) + sinkfer2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of iron at 100m
576         CALL iom_put( "EPCAL100",   sinkcal(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of calcite  at 100m
577         CALL iom_put( "EPSI100" ,   sinksil(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of biogenic silica at 100m
578      ENDIF
579#endif
580#endif
581      !
582      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
583         WRITE(charout, FMT="('sink')")
584         CALL prt_ctl_trc_info(charout)
585         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
586      ENDIF
587      !
588   END SUBROUTINE p4z_sink
589
590
591   SUBROUTINE p4z_sink_init
592      !!----------------------------------------------------------------------
593      !!                  ***  ROUTINE p4z_sink_init  ***
594      !!----------------------------------------------------------------------
595   END SUBROUTINE p4z_sink_init
596
597#endif
598
599   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra )
600      !!---------------------------------------------------------------------
601      !!                     ***  ROUTINE p4z_sink2  ***
602      !!
603      !! ** Purpose :   Compute the sedimentation terms for the various sinking
604      !!     particles. The scheme used to compute the trends is based
605      !!     on MUSCL.
606      !!
607      !! ** Method  : - this ROUTINE compute not exactly the advection but the
608      !!      transport term, i.e.  div(u*tra).
609      !!---------------------------------------------------------------------
610      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
611      USE wrk_nemo, ONLY: ztraz => wrk_3d_2, zakz => wrk_3d_3, zwsink2 => wrk_3d_4
612      !
613      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
614      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
615      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
616      !!
617      INTEGER  ::   ji, jj, jk, jn
618      REAL(wp) ::   zigma,zew,zign, zflx, zstep
619      !!---------------------------------------------------------------------
620
621      IF(  wrk_in_use(3, 2,3,4 ) ) THEN
622         CALL ctl_stop('p4z_sink2: requested workspace arrays unavailable')
623         RETURN
624      END IF
625
626      zstep = rfact2 / 2.
627
628      ztraz(:,:,:) = 0.e0
629      zakz (:,:,:) = 0.e0
630
631      DO jk = 1, jpkm1
632# if defined key_degrad
633         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) * facvol(:,:,jk)
634# else
635         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1)
636# endif
637      END DO
638      zwsink2(:,:,1) = 0.e0
639
640
641      ! Vertical advective flux
642      DO jn = 1, 2
643         !  first guess of the slopes interior values
644         DO jk = 2, jpkm1
645            ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk)
646         END DO
647         ztraz(:,:,1  ) = 0.0
648         ztraz(:,:,jpk) = 0.0
649
650         ! slopes
651         DO jk = 2, jpkm1
652            DO jj = 1,jpj
653               DO ji = 1, jpi
654                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
655                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
656               END DO
657            END DO
658         END DO
659         
660         ! Slopes limitation
661         DO jk = 2, jpkm1
662            DO jj = 1, jpj
663               DO ji = 1, jpi
664                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
665                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
666               END DO
667            END DO
668         END DO
669         
670         ! vertical advective flux
671         DO jk = 1, jpkm1
672            DO jj = 1, jpj     
673               DO ji = 1, jpi   
674                  zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1)
675                  zew   = zwsink2(ji,jj,jk+1)
676                  psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
677               END DO
678            END DO
679         END DO
680         !
681         ! Boundary conditions
682         psinkflx(:,:,1  ) = 0.e0
683         psinkflx(:,:,jpk) = 0.e0
684         
685         DO jk=1,jpkm1
686            DO jj = 1,jpj
687               DO ji = 1, jpi
688                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
689                  trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx
690               END DO
691            END DO
692         END DO
693
694      ENDDO
695
696      DO jk=1,jpkm1
697         DO jj = 1,jpj
698            DO ji = 1, jpi
699               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
700               trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + 2. * zflx
701            END DO
702         END DO
703      END DO
704
705      trn     (:,:,:,jp_tra) = trb(:,:,:,jp_tra)
706      psinkflx(:,:,:)        = 2. * psinkflx(:,:,:)
707      !
708      IF( wrk_not_released(3, 2,3,4) )   CALL ctl_stop('p4z_sink2: failed to release workspace arrays')
709      !
710   END SUBROUTINE p4z_sink2
711
712
713   INTEGER FUNCTION p4z_sink_alloc()
714      !!----------------------------------------------------------------------
715      !!                     ***  ROUTINE p4z_sink_alloc  ***
716      !!----------------------------------------------------------------------
717      ALLOCATE( wsbio3 (jpi,jpj,jpk) , wsbio4  (jpi,jpj,jpk) , wscal(jpi,jpj,jpk) ,     &
718         &      sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                      ,     &               
719         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                      ,     &               
720#if defined key_kriest
721         &      xnumm(jpk)                                                        ,     &               
722#else
723         &      sinkfer2(jpi,jpj,jpk)                                             ,     &               
724#endif
725         &      sinkfer(jpi,jpj,jpk)                                              , STAT=p4z_sink_alloc )               
726         !
727      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
728      !
729   END FUNCTION p4z_sink_alloc
730   
731#else
732   !!======================================================================
733   !!  Dummy module :                                   No PISCES bio-model
734   !!======================================================================
735CONTAINS
736   SUBROUTINE p4z_sink                    ! Empty routine
737   END SUBROUTINE p4z_sink
738#endif 
739
740   !!======================================================================
741END MODULE  p4zsink
Note: See TracBrowser for help on using the repository browser.