source: trunk/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 6701

Last change on this file since 6701 was 6701, checked in by lovato, 4 years ago

#1677 - trunk: Update code for passive tracers data input and restoring

  • Property svn:keywords set to Id
File size: 12.1 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcnam          ! Namelist read
21   USE daymod          ! calendar manager
22   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
23   USE trcsub          ! variables to substep passive tracers
24   USE trcrst
25   USE lib_mpp         ! distribued memory computing library
26   USE sbc_oce
27   USE trcice          ! tracers in sea ice
28   USE trcbc,   only : trc_bc_init ! generalized Boundary Conditions
29 
30   IMPLICIT NONE
31   PRIVATE
32   
33   PUBLIC   trc_init   ! called by opa
34
35   !!----------------------------------------------------------------------
36   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41   
42   SUBROUTINE trc_init
43      !!---------------------------------------------------------------------
44      !!                     ***  ROUTINE trc_init  ***
45      !!
46      !! ** Purpose :   Initialization of the passive tracer fields
47      !!
48      !! ** Method  : - read namelist
49      !!              - control the consistancy
50      !!              - compute specific initialisations
51      !!              - set initial tracer fields (either read restart
52      !!                or read data or analytical formulation
53      !!---------------------------------------------------------------------
54      !
55      IF( nn_timing == 1 )   CALL timing_start('trc_init')
56      !
57      IF(lwp) WRITE(numout,*)
58      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
59      IF(lwp) WRITE(numout,*) '~~~~~~~'
60
61      !
62      CALL top_alloc()   ! allocate TOP arrays
63      !
64      CALL trc_ini_ctl   ! control
65      !
66      CALL trc_nam       ! read passive tracers namelists
67      !
68      IF(lwp) WRITE(numout,*)
69      !
70      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
71      !
72      IF(lwp) WRITE(numout,*)
73      !
74      CALL trc_ini_sms   ! SMS
75      !
76      CALL trc_ini_trp   ! passive tracers transport
77      !
78      CALL trc_ice_ini   ! Tracers in sea ice
79      !
80      IF( lwp )  &
81         &  CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp , narea )
82      !
83      CALL trc_ini_state  !  passive tracers initialisation : from a restart or from clim
84      !
85      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
86      !
87      CALL trc_ini_inv   ! Inventories
88      !
89      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
90      !
91   END SUBROUTINE trc_init
92
93
94   SUBROUTINE trc_ini_ctl
95      !!----------------------------------------------------------------------
96      !!                     ***  ROUTINE trc_ini_ctl  ***
97      !! ** Purpose :        Control  + ocean volume
98      !!----------------------------------------------------------------------
99      INTEGER ::   jk    ! dummy loop indices
100      !
101      ! Define logical parameter ton control dirunal cycle in TOP
102      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
103      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. lk_offline
104      IF( l_trcdm2dc .AND. lwp )   CALL ctl_warn( 'Coupling with passive tracers and used of diurnal cycle.',   &
105         &                           'Computation of a daily mean shortwave for some biogeochemical models ' )
106      !
107   END SUBROUTINE trc_ini_ctl
108
109
110   SUBROUTINE trc_ini_inv
111      !!----------------------------------------------------------------------
112      !!                     ***  ROUTINE trc_ini_stat  ***
113      !! ** Purpose :      passive tracers inventories at initialsation phase
114      !!----------------------------------------------------------------------
115      INTEGER ::  jk, jn    ! dummy loop indices
116      CHARACTER (len=25) :: charout
117      !!----------------------------------------------------------------------
118      !                                                              ! masked grid volume
119      DO jk = 1, jpk
120         cvol(:,:,jk) = e1e2t(:,:) * e3t_n(:,:,jk) * tmask(:,:,jk)
121      END DO
122      IF( lk_degrad )   cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)    ! degrad option: reduction by facvol
123      !                                                              ! total volume of the ocean
124      areatot = glob_sum( cvol(:,:,:) )
125      !
126      trai(:) = 0._wp                                                   ! initial content of all tracers
127      DO jn = 1, jptra
128         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
129      END DO
130
131      IF(lwp) THEN               ! control print
132         WRITE(numout,*)
133         WRITE(numout,*)
134         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
135         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
136         WRITE(numout,*) '          *** Total inital content of all tracers '
137         WRITE(numout,*)
138         DO jn = 1, jptra
139            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
140         ENDDO
141         WRITE(numout,*)
142      ENDIF
143      IF(lwp) WRITE(numout,*)
144      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
145         CALL prt_ctl_trc_init
146         WRITE(charout, FMT="('ini ')")
147         CALL prt_ctl_trc_info( charout )
148         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
149      ENDIF
1509000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
151      !
152   END SUBROUTINE trc_ini_inv
153
154
155   SUBROUTINE trc_ini_sms
156      !!----------------------------------------------------------------------
157      !!                     ***  ROUTINE trc_ini_sms  ***
158      !! ** Purpose :   SMS initialisation
159      !!----------------------------------------------------------------------
160      USE trcini_cfc      ! CFC      initialisation
161      USE trcini_pisces   ! PISCES   initialisation
162      USE trcini_c14b     ! C14 bomb initialisation
163      USE trcini_my_trc   ! MY_TRC   initialisation
164      !!----------------------------------------------------------------------
165      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
166      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC     tracers
167      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
168      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC  tracers
169      !
170   END SUBROUTINE trc_ini_sms
171
172   SUBROUTINE trc_ini_trp
173      !!----------------------------------------------------------------------
174      !!                     ***  ROUTINE trc_ini_trp  ***
175      !!
176      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
177      !!----------------------------------------------------------------------
178      USE trcdmp , ONLY:  trc_dmp_ini
179      USE trcadv , ONLY:  trc_adv_ini
180      USE trcldf , ONLY:  trc_ldf_ini
181      USE trczdf , ONLY:  trc_zdf_ini
182      USE trcrad , ONLY:  trc_rad_ini
183      !
184      INTEGER :: ierr
185      !!----------------------------------------------------------------------
186      !
187      IF( ln_trcdmp )  CALL  trc_dmp_ini          ! damping
188                       CALL  trc_adv_ini          ! advection
189                       CALL  trc_ldf_ini          ! lateral diffusion
190                       CALL  trc_zdf_ini          ! vertical diffusion
191                       CALL  trc_rad_ini          ! positivity of passive tracers
192      !
193   END SUBROUTINE trc_ini_trp
194
195
196   SUBROUTINE trc_ini_state
197      !!----------------------------------------------------------------------
198      !!                     ***  ROUTINE trc_ini_state ***
199      !! ** Purpose :          Initialisation of passive tracer concentration
200      !!----------------------------------------------------------------------
201      USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
202      USE trcrst          ! passive tracers restart
203      USE trcdta          ! initialisation from files
204      !
205      INTEGER :: jn, jl   ! dummy loop indices
206      !!----------------------------------------------------------------------
207      !
208      ! Initialisation of tracers Initial Conditions
209      IF( ln_trcdta )      CALL trc_dta_init(jptra)
210
211      ! Initialisation of tracers Boundary Conditions
212      IF( lk_my_trc )     CALL trc_bc_init(jptra)
213
214      IF( ln_rsttr ) THEN
215        !
216        CALL trc_rst_read              ! restart from a file
217        !
218      ELSE
219        !
220        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
221            !
222            DO jn = 1, jptra
223               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
224                  jl = n_trc_index(jn) 
225                  CALL trc_dta( nit000, sf_trcdta(jl), rf_trfac(jl) )   ! read tracer data at nit000
226                  trn(:,:,:,jn) = sf_trcdta(jl)%fnow(:,:,:) 
227                  !
228                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN      !== deallocate data structure   ==!
229                     !                                                    (data used only for initialisation)
230                     IF(lwp) WRITE(numout,*) 'trc_dta: deallocate data arrays as they are only used to initialize the run'
231                                                  DEALLOCATE( sf_trcdta(jl)%fnow )     !  arrays in the structure
232                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
233                     !
234                  ENDIF
235               ENDIF
236            ENDDO
237            !
238        ENDIF
239        !
240        trb(:,:,:,:) = trn(:,:,:,:)
241        !
242      ENDIF
243 
244      tra(:,:,:,:) = 0._wp
245      !                                                         ! Partial top/bottom cell: GRADh(trn)
246   END SUBROUTINE trc_ini_state
247
248   SUBROUTINE top_alloc
249      !!----------------------------------------------------------------------
250      !!                     ***  ROUTINE top_alloc  ***
251      !!
252      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
253      !!----------------------------------------------------------------------
254      USE trc           , ONLY:   trc_alloc
255      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
256#if defined key_trdmxl_trc 
257      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
258#endif
259      !
260      INTEGER :: ierr
261      !!----------------------------------------------------------------------
262      !
263      ierr =        trc_alloc()
264      ierr = ierr + trd_trc_oce_alloc()
265#if defined key_trdmxl_trc 
266      ierr = ierr + trd_mxl_trc_alloc()
267#endif
268      !
269      IF( lk_mpp    )   CALL mpp_sum( ierr )
270      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
271      !
272   END SUBROUTINE top_alloc
273
274#else
275   !!----------------------------------------------------------------------
276   !!  Empty module :                                     No passive tracer
277   !!----------------------------------------------------------------------
278CONTAINS
279   SUBROUTINE trc_init                      ! Dummy routine   
280   END SUBROUTINE trc_init
281#endif
282
283   !!======================================================================
284END MODULE trcini
Note: See TracBrowser for help on using the repository browser.