New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
tide_mod.F90 in NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/TDE – NEMO

source: NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/TDE/tide_mod.F90 @ 10860

Last change on this file since 10860 was 10860, checked in by smueller, 5 years ago

Relocation of the time-of-day computation in subroutine upd_tide (module tide_mod) to its callers (ticket #2194)
  • Property svn:keywords set to Id
File size: 32.3 KB
Line 
1MODULE tide_mod
2   !!======================================================================
3   !!                       ***  MODULE  tide_mod  ***
4   !! Compute nodal modulations corrections and pulsations
5   !!======================================================================
6   !! History :  1.0  !  2007  (O. Le Galloudec)  Original code
7   !!----------------------------------------------------------------------
8   USE oce            ! ocean dynamics and tracers variables
9   USE dom_oce        ! ocean space and time domain
10   USE phycst         ! physical constant
11   USE daymod         ! calendar
12   !
13   USE in_out_manager ! I/O units
14   USE iom            ! xIOs server
15   USE ioipsl         ! NetCDF IPSL library
16   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   tide_init
22   PUBLIC   tide_update          ! called by stp
23   PUBLIC   tide_init_harmonics  ! called internally and by module diaharm
24   PUBLIC   upd_tide         ! called in dynspg_... modules
25
26   INTEGER, PUBLIC, PARAMETER ::   jpmax_harmo = 64   !: maximum number of harmonic components
27
28   TYPE ::    tide
29      CHARACTER(LEN=4) ::   cname_tide = ''
30      REAL(wp)         ::   equitide
31      INTEGER          ::   nutide
32      INTEGER          ::   nt, ns, nh, np, np1, shift
33      INTEGER          ::   nksi, nnu0, nnu1, nnu2, R
34      INTEGER          ::   nformula
35   END TYPE tide
36
37   TYPE(tide), DIMENSION(:), POINTER ::   tide_components !: Array of selected tidal component parameters
38
39   TYPE, PUBLIC ::   tide_harmonic       !:   Oscillation parameters of harmonic tidal components
40      CHARACTER(LEN=4) ::   cname_tide   !    Name of component
41      REAL(wp)         ::   equitide     !    Amplitude of equilibrium tide
42      REAL(wp)         ::   f            !    Node factor
43      REAL(wp)         ::   omega        !    Angular velocity
44      REAL(wp)         ::   v0           !    Initial phase at prime meridian
45      REAL(wp)         ::   u            !    Phase correction
46   END type tide_harmonic
47
48   TYPE(tide_harmonic), PUBLIC, DIMENSION(:), POINTER ::   tide_harmonics !: Oscillation parameters of selected tidal components
49
50   LOGICAL , PUBLIC ::   ln_tide         !:
51   LOGICAL , PUBLIC ::   ln_tide_pot     !:
52   LOGICAL          ::   ln_read_load    !:
53   LOGICAL , PUBLIC ::   ln_scal_load    !:
54   LOGICAL , PUBLIC ::   ln_tide_ramp    !:
55   INTEGER , PUBLIC ::   nb_harmo        !: Number of active tidal components
56   REAL(wp), PUBLIC ::   rn_tide_ramp_dt     !:
57   REAL(wp), PUBLIC ::   rn_scal_load    !:
58   CHARACTER(lc), PUBLIC ::   cn_tide_load   !:
59   REAL(wp)         ::   rn_tide_gamma   ! Tidal tilt factor
60
61   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   pot_astro !: tidal potential
62   REAL(wp),         ALLOCATABLE, DIMENSION(:,:,:) ::   amp_pot, phi_pot
63   REAL(wp),         ALLOCATABLE, DIMENSION(:,:,:) ::   amp_load, phi_load
64
65   REAL(wp) ::   rn_tide_ramp_t !   Elapsed time in seconds
66
67   REAL(wp) ::   sh_T, sh_s, sh_h, sh_p, sh_p1             ! astronomic angles
68   REAL(wp) ::   sh_xi, sh_nu, sh_nuprim, sh_nusec, sh_R   !
69   REAL(wp) ::   sh_I, sh_x1ra, sh_N                       !
70
71   !!----------------------------------------------------------------------
72   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
73   !! $Id$
74   !! Software governed by the CeCILL license (see ./LICENSE)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   SUBROUTINE tide_init
79      !!----------------------------------------------------------------------
80      !!                 ***  ROUTINE tide_init  ***
81      !!----------------------------------------------------------------------     
82      INTEGER  :: ji, jk
83      CHARACTER(LEN=4), DIMENSION(jpmax_harmo) :: sn_tide_cnames ! Names of selected tidal components
84      INTEGER  ::   ios                 ! Local integer output status for namelist read
85      !
86      NAMELIST/nam_tide/ln_tide, ln_tide_pot, rn_tide_gamma, ln_scal_load, ln_read_load, cn_tide_load, &
87                  &     ln_tide_ramp, rn_scal_load, rn_tide_ramp_dt, sn_tide_cnames
88      !!----------------------------------------------------------------------
89      !
90      ! Initialise all array elements of sn_tide_cnames, as some of them
91      ! typically do not appear in namelist_ref or namelist_cfg
92      sn_tide_cnames(:) = ''
93      ! Read Namelist nam_tide
94      REWIND( numnam_ref )              ! Namelist nam_tide in reference namelist : Tides
95      READ  ( numnam_ref, nam_tide, IOSTAT = ios, ERR = 901)
96901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nam_tide in reference namelist', lwp )
97      !
98      REWIND( numnam_cfg )              ! Namelist nam_tide in configuration namelist : Tides
99      READ  ( numnam_cfg, nam_tide, IOSTAT = ios, ERR = 902 )
100902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nam_tide in configuration namelist', lwp )
101      IF(lwm) WRITE ( numond, nam_tide )
102      !
103      IF( ln_tide ) THEN
104         IF (lwp) THEN
105            WRITE(numout,*)
106            WRITE(numout,*) 'tide_init : Initialization of the tidal components'
107            WRITE(numout,*) '~~~~~~~~~ '
108            WRITE(numout,*) '   Namelist nam_tide'
109            WRITE(numout,*) '      Use tidal components                       ln_tide         = ', ln_tide
110            WRITE(numout,*) '         Apply astronomical potential            ln_tide_pot     = ', ln_tide_pot
111            WRITE(numout,*) '         Tidal tilt factor                       rn_tide_gamma   = ', rn_tide_gamma
112            WRITE(numout,*) '         Use scalar approx. for load potential   ln_scal_load    = ', ln_scal_load
113            WRITE(numout,*) '         Read load potential from file           ln_read_load    = ', ln_read_load
114            WRITE(numout,*) '         Apply ramp on tides at startup          ln_tide_ramp    = ', ln_tide_ramp
115            WRITE(numout,*) '         Fraction of SSH used in scal. approx.   rn_scal_load    = ', rn_scal_load
116            WRITE(numout,*) '         Duration (days) of ramp                 rn_tide_ramp_dt = ', rn_tide_ramp_dt
117         ENDIF
118      ELSE
119         rn_scal_load = 0._wp 
120
121         IF(lwp) WRITE(numout,*)
122         IF(lwp) WRITE(numout,*) 'tide_init : tidal components not used (ln_tide = F)'
123         IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
124         RETURN
125      ENDIF
126      !
127      IF( ln_read_load.AND.(.NOT.ln_tide_pot) ) &
128          &   CALL ctl_stop('ln_read_load requires ln_tide_pot')
129      IF( ln_scal_load.AND.(.NOT.ln_tide_pot) ) &
130          &   CALL ctl_stop('ln_scal_load requires ln_tide_pot')
131      IF( ln_scal_load.AND.ln_read_load ) &
132          &   CALL ctl_stop('Choose between ln_scal_load and ln_read_load')
133      IF( ln_tide_ramp.AND.((nitend-nit000+1)*rdt/rday < rn_tide_ramp_dt) )   &
134         &   CALL ctl_stop('rn_tide_ramp_dt must be lower than run duration')
135      IF( ln_tide_ramp.AND.(rn_tide_ramp_dt<0.) ) &
136         &   CALL ctl_stop('rn_tide_ramp_dt must be positive')
137      !
138      ! Initialise array used to store tidal oscillation parameters (frequency,
139      ! amplitude, phase); also retrieve and store array of information about
140      ! selected tidal components
141      CALL tide_init_harmonics(sn_tide_cnames, tide_harmonics, tide_components)
142      !
143      ! Number of active tidal components
144      nb_harmo = size(tide_components)
145      !       
146      ! Ensure that tidal components have been set in namelist_cfg
147      IF( nb_harmo == 0 )   CALL ctl_stop( 'tide_init : No tidal components set in nam_tide' )
148      !
149      IF (.NOT.ln_scal_load ) rn_scal_load = 0._wp
150      !
151      ALLOCATE( amp_pot(jpi,jpj,nb_harmo),                      &
152           &      phi_pot(jpi,jpj,nb_harmo), pot_astro(jpi,jpj)   )
153      IF( ln_read_load ) THEN
154         ALLOCATE( amp_load(jpi,jpj,nb_harmo), phi_load(jpi,jpj,nb_harmo) )
155         CALL tide_init_load
156         amp_pot(:,:,:) = amp_load(:,:,:)
157         phi_pot(:,:,:) = phi_load(:,:,:)
158      ELSE     
159         amp_pot(:,:,:) = 0._wp
160         phi_pot(:,:,:) = 0._wp   
161      ENDIF
162      !
163   END SUBROUTINE tide_init
164
165
166   SUBROUTINE tide_init_components(pcnames, ptide_comp)
167      !!----------------------------------------------------------------------
168      !!                 ***  ROUTINE tide_init_components  ***
169      !!
170      !! Returns pointer to array of variables of type 'tide' that contain
171      !! information about the selected tidal components
172      !! ----------------------------------------------------------------------
173      CHARACTER(LEN=4),              DIMENSION(jpmax_harmo), INTENT(in)  ::   pcnames         ! Names of selected components
174      TYPE(tide),       POINTER,     DIMENSION(:),           INTENT(out) ::   ptide_comp      ! Selected components
175      INTEGER,          ALLOCATABLE, DIMENSION(:)                        ::   kcomppos        ! Indices of selected components
176      INTEGER                                                            ::   kcomp, jk, ji   ! Miscellaneous integers
177      TYPE(tide),       POINTER,     DIMENSION(:)                        ::   tide_components ! All available components
178     
179      ! Populate local array with information about all available tidal
180      ! components
181      !
182      ! Note, here 'tide_components' locally overrides the global module
183      ! variable of the same name to enable the use of the global name in the
184      ! include file that contains the initialisation of elements of array
185      ! 'tide_components'
186      ALLOCATE(tide_components(jpmax_harmo), kcomppos(jpmax_harmo))
187      ! Initialise array of indices of the selected componenents
188      kcomppos(:) = 0
189      ! Include tidal component parameters for all available components
190#include "tide.h90"
191     
192      ! Identify the selected components that are availble
193      kcomp = 0
194      DO jk = 1, jpmax_harmo
195         IF (TRIM(pcnames(jk)) /= '') THEN
196            DO ji = 1, jpmax_harmo
197               IF (TRIM(pcnames(jk)) == tide_components(ji)%cname_tide) THEN
198                  kcomp = kcomp + 1
199                  WRITE(numout, '(10X,"Tidal component #",I2.2,36X,"= ",A4)') kcomp, pcnames(jk)
200                  kcomppos(kcomp) = ji
201                  EXIT
202               END IF
203            END DO
204         END IF
205      END DO
206     
207      ! Allocate and populate reduced list of components
208      ALLOCATE(ptide_comp(kcomp))
209      DO jk = 1, kcomp
210         ptide_comp(jk) = tide_components(kcomppos(jk))
211      END DO
212     
213      ! Release local array of available components and list of selected
214      ! components
215      DEALLOCATE(tide_components, kcomppos)
216     
217   END SUBROUTINE tide_init_components
218
219
220   SUBROUTINE tide_init_harmonics(pcnames, ptide_harmo, ptide_comp)
221      !!----------------------------------------------------------------------
222      !!                 ***  ROUTINE tide_init_harmonics  ***
223      !!
224      !! Returns pointer to array of variables of type 'tide_harmonics' that
225      !! contain oscillation parameters of the selected harmonic tidal
226      !! components
227      !! ----------------------------------------------------------------------
228      CHARACTER(LEN=4),             DIMENSION(jpmax_harmo), INTENT(in) ::   pcnames     ! Names of selected components
229      TYPE(tide_harmonic), POINTER, DIMENSION(:)                       ::   ptide_harmo ! Oscillation parameters of tidal components
230      TYPE(tide),          POINTER, DIMENSION(:), OPTIONAL             ::   ptide_comp  ! Selected components
231      TYPE(tide),          POINTER, DIMENSION(:)                       ::   ztcomp      ! Selected components
232
233      ! Retrieve information about selected tidal components
234      ! If requested, prepare tidal component array for returning
235      IF (PRESENT(ptide_comp)) THEN
236         CALL tide_init_components(pcnames, ptide_comp)
237         ztcomp => ptide_comp
238      ELSE
239         CALL tide_init_components(pcnames, ztcomp)
240      END IF
241
242      ! Allocate and populate array of oscillation parameters
243      ALLOCATE(ptide_harmo(size(ztcomp)))
244      ptide_harmo(:)%cname_tide = ztcomp(:)%cname_tide
245      ptide_harmo(:)%equitide = ztcomp(:)%equitide
246      CALL tide_harmo(ztcomp, ptide_harmo)
247
248   END SUBROUTINE tide_init_harmonics
249
250
251   SUBROUTINE tide_init_potential
252      !!----------------------------------------------------------------------
253      !!                 ***  ROUTINE tide_init_potential  ***
254      !!----------------------------------------------------------------------
255      INTEGER  ::   ji, jj, jk   ! dummy loop indices
256      REAL(wp) ::   zcons, ztmp1, ztmp2, zlat, zlon, ztmp, zamp, zcs   ! local scalar
257      !!----------------------------------------------------------------------
258
259      IF( ln_read_load ) THEN
260    amp_pot(:,:,:) = amp_load(:,:,:)
261    phi_pot(:,:,:) = phi_load(:,:,:)
262      ELSE     
263         amp_pot(:,:,:) = 0._wp
264         phi_pot(:,:,:) = 0._wp   
265      ENDIF
266      DO jk = 1, nb_harmo
267         zcons = rn_tide_gamma * tide_components(jk)%equitide * tide_harmonics(jk)%f
268         DO ji = 1, jpi
269            DO jj = 1, jpj
270               ztmp1 =  tide_harmonics(jk)%f * amp_pot(ji,jj,jk) * COS( phi_pot(ji,jj,jk) &
271                  &                                                   + tide_harmonics(jk)%v0 + tide_harmonics(jk)%u )
272               ztmp2 = -tide_harmonics(jk)%f * amp_pot(ji,jj,jk) * SIN( phi_pot(ji,jj,jk) &
273                  &                                                   + tide_harmonics(jk)%v0 + tide_harmonics(jk)%u )
274               zlat = gphit(ji,jj)*rad !! latitude en radian
275               zlon = glamt(ji,jj)*rad !! longitude en radian
276               ztmp = tide_harmonics(jk)%v0 + tide_harmonics(jk)%u + tide_components(jk)%nutide * zlon
277               ! le potentiel est composé des effets des astres:
278               IF    ( tide_components(jk)%nutide == 1 )  THEN  ;  zcs = zcons * SIN( 2._wp*zlat )
279               ELSEIF( tide_components(jk)%nutide == 2 )  THEN  ;  zcs = zcons * COS( zlat )**2
280               ELSE                                         ;  zcs = 0._wp
281               ENDIF
282               ztmp1 = ztmp1 + zcs * COS( ztmp )
283               ztmp2 = ztmp2 - zcs * SIN( ztmp )
284               zamp = SQRT( ztmp1*ztmp1 + ztmp2*ztmp2 )
285               amp_pot(ji,jj,jk) = zamp
286               phi_pot(ji,jj,jk) = ATAN2( -ztmp2 / MAX( 1.e-10_wp , zamp ) ,   &
287                  &                        ztmp1 / MAX( 1.e-10_wp,  zamp )   )
288            END DO
289         END DO
290      END DO
291      !
292   END SUBROUTINE tide_init_potential
293
294
295   SUBROUTINE tide_init_load
296      !!----------------------------------------------------------------------
297      !!                 ***  ROUTINE tide_init_load  ***
298      !!----------------------------------------------------------------------
299      INTEGER :: inum                 ! Logical unit of input file
300      INTEGER :: ji, jj, itide        ! dummy loop indices
301      REAL(wp), DIMENSION(jpi,jpj) ::   ztr, zti   !: workspace to read in tidal harmonics data
302      !!----------------------------------------------------------------------
303      IF(lwp) THEN
304         WRITE(numout,*)
305         WRITE(numout,*) 'tide_init_load : Initialization of load potential from file'
306         WRITE(numout,*) '~~~~~~~~~~~~~~ '
307      ENDIF
308      !
309      CALL iom_open ( cn_tide_load , inum )
310      !
311      DO itide = 1, nb_harmo
312         CALL iom_get  ( inum, jpdom_data,TRIM(tide_components(itide)%cname_tide)//'_z1', ztr(:,:) )
313         CALL iom_get  ( inum, jpdom_data,TRIM(tide_components(itide)%cname_tide)//'_z2', zti(:,:) )
314         !
315         DO ji=1,jpi
316            DO jj=1,jpj
317               amp_load(ji,jj,itide) =  SQRT( ztr(ji,jj)**2. + zti(ji,jj)**2. )
318               phi_load(ji,jj,itide) = ATAN2(-zti(ji,jj), ztr(ji,jj) )
319            END DO
320         END DO
321         !
322      END DO
323      CALL iom_close( inum )
324      !
325   END SUBROUTINE tide_init_load
326
327
328   SUBROUTINE tide_update( kt )
329      !!----------------------------------------------------------------------
330      !!                 ***  ROUTINE tide_update  ***
331      !!----------------------------------------------------------------------     
332      INTEGER, INTENT( in ) ::   kt     ! ocean time-step
333      INTEGER               ::   jk     ! dummy loop index
334      !!----------------------------------------------------------------------
335     
336      IF( nsec_day == NINT(0.5_wp * rdt) .OR. kt == nit000 ) THEN      ! start a new day
337         !
338         CALL tide_harmo(tide_components, tide_harmonics, ndt05) ! Update oscillation parameters of tidal components for start of current day
339         !
340         !
341         IF(lwp) THEN
342            WRITE(numout,*)
343            WRITE(numout,*) 'tide_update : Update of the components and (re)Init. the potential at kt=', kt
344            WRITE(numout,*) '~~~~~~~~~~~ '
345            DO jk = 1, nb_harmo
346               WRITE(numout,*) tide_harmonics(jk)%cname_tide, tide_harmonics(jk)%u, &
347                  &            tide_harmonics(jk)%f,tide_harmonics(jk)%v0, tide_harmonics(jk)%omega
348            END DO
349         ENDIF
350         !
351         IF( ln_tide_pot )   CALL tide_init_potential
352         !
353         rn_tide_ramp_t = (kt - nit000)*rdt !   Elapsed time in seconds
354      ENDIF
355      !
356   END SUBROUTINE tide_update
357
358
359   SUBROUTINE tide_harmo( ptide_comp, ptide_harmo, psec_day )
360      !
361      TYPE(tide),          DIMENSION(:), POINTER ::   ptide_comp   ! Array of selected tidal component parameters
362      TYPE(tide_harmonic), DIMENSION(:), POINTER ::   ptide_harmo  ! Oscillation parameters of selected tidal components
363      INTEGER, OPTIONAL ::   psec_day                              ! Number of seconds since the start of the current day
364      !
365      IF (PRESENT(psec_day)) THEN
366         CALL astronomic_angle(psec_day)
367      ELSE
368         CALL astronomic_angle(nsec_day)
369      END IF
370      CALL tide_pulse( ptide_comp, ptide_harmo )
371      CALL tide_vuf(   ptide_comp, ptide_harmo )
372      !
373   END SUBROUTINE tide_harmo
374
375
376   SUBROUTINE astronomic_angle(psec_day)
377      !!----------------------------------------------------------------------
378      !!  tj is time elapsed since 1st January 1900, 0 hour, counted in julian
379      !!  century (e.g. time in days divide by 36525)
380      !!----------------------------------------------------------------------
381      INTEGER  ::   psec_day !   Number of seconds from midnight
382      REAL(wp) ::   cosI, p, q, t2, t4, sin2I, s2, tgI2, P1, sh_tgn2, at1, at2
383      REAL(wp) ::   zqy , zsy, zday, zdj, zhfrac
384      !!----------------------------------------------------------------------
385      !
386      zqy = AINT( (nyear-1901.)/4. )
387      zsy = nyear - 1900.
388      !
389      zdj  = dayjul( nyear, nmonth, nday )
390      zday = zdj + zqy - 1.
391      !
392      zhfrac = psec_day / 3600.
393      !
394      !----------------------------------------------------------------------
395      !  Sh_n Longitude of ascending lunar node
396      !----------------------------------------------------------------------
397      sh_N=(259.1560564-19.328185764*zsy-.0529539336*zday-.0022064139*zhfrac)*rad
398      !----------------------------------------------------------------------
399      ! T mean solar angle (Greenwhich time)
400      !----------------------------------------------------------------------
401      sh_T=(180.+zhfrac*(360./24.))*rad
402      !----------------------------------------------------------------------
403      ! h mean solar Longitude
404      !----------------------------------------------------------------------
405      sh_h=(280.1895014-.238724988*zsy+.9856473288*zday+.0410686387*zhfrac)*rad
406      !----------------------------------------------------------------------
407      ! s mean lunar Longitude
408      !----------------------------------------------------------------------
409      sh_s=(277.0256206+129.38482032*zsy+13.176396768*zday+.549016532*zhfrac)*rad
410      !----------------------------------------------------------------------
411      ! p1 Longitude of solar perigee
412      !----------------------------------------------------------------------
413      sh_p1=(281.2208569+.01717836*zsy+.000047064*zday+.000001961*zhfrac)*rad
414      !----------------------------------------------------------------------
415      ! p Longitude of lunar perigee
416      !----------------------------------------------------------------------
417      sh_p=(334.3837214+40.66246584*zsy+.111404016*zday+.004641834*zhfrac)*rad
418
419      sh_N = MOD( sh_N ,2*rpi )
420      sh_s = MOD( sh_s ,2*rpi )
421      sh_h = MOD( sh_h, 2*rpi )
422      sh_p = MOD( sh_p, 2*rpi )
423      sh_p1= MOD( sh_p1,2*rpi )
424
425      cosI = 0.913694997 -0.035692561 *cos(sh_N)
426
427      sh_I = ACOS( cosI )
428
429      sin2I   = sin(sh_I)
430      sh_tgn2 = tan(sh_N/2.0)
431
432      at1=atan(1.01883*sh_tgn2)
433      at2=atan(0.64412*sh_tgn2)
434
435      sh_xi=-at1-at2+sh_N
436
437      IF( sh_N > rpi )   sh_xi=sh_xi-2.0*rpi
438
439      sh_nu = at1 - at2
440
441      !----------------------------------------------------------------------
442      ! For constituents l2 k1 k2
443      !----------------------------------------------------------------------
444
445      tgI2 = tan(sh_I/2.0)
446      P1   = sh_p-sh_xi
447
448      t2 = tgI2*tgI2
449      t4 = t2*t2
450      sh_x1ra = sqrt( 1.0-12.0*t2*cos(2.0*P1)+36.0*t4 )
451
452      p = sin(2.0*P1)
453      q = 1.0/(6.0*t2)-cos(2.0*P1)
454      sh_R = atan(p/q)
455
456      p = sin(2.0*sh_I)*sin(sh_nu)
457      q = sin(2.0*sh_I)*cos(sh_nu)+0.3347
458      sh_nuprim = atan(p/q)
459
460      s2 = sin(sh_I)*sin(sh_I)
461      p  = s2*sin(2.0*sh_nu)
462      q  = s2*cos(2.0*sh_nu)+0.0727
463      sh_nusec = 0.5*atan(p/q)
464      !
465   END SUBROUTINE astronomic_angle
466
467
468   SUBROUTINE tide_pulse( ptide_comp, ptide_harmo )
469      !!----------------------------------------------------------------------
470      !!                     ***  ROUTINE tide_pulse  ***
471      !!                     
472      !! ** Purpose : Compute tidal frequencies
473      !!----------------------------------------------------------------------
474      TYPE(tide),          DIMENSION(:), POINTER ::   ptide_comp   ! Array of selected tidal component parameters
475      TYPE(tide_harmonic), DIMENSION(:), POINTER ::   ptide_harmo  ! Oscillation parameters of selected tidal components
476      !
477      INTEGER  ::   jh
478      REAL(wp) ::   zscale
479      REAL(wp) ::   zomega_T =  13149000.0_wp
480      REAL(wp) ::   zomega_s =    481267.892_wp
481      REAL(wp) ::   zomega_h =     36000.76892_wp
482      REAL(wp) ::   zomega_p =      4069.0322056_wp
483      REAL(wp) ::   zomega_n =      1934.1423972_wp
484      REAL(wp) ::   zomega_p1=         1.719175_wp
485      !!----------------------------------------------------------------------
486      !
487      zscale =  rad / ( 36525._wp * 86400._wp ) 
488      !
489      DO jh = 1, size(ptide_harmo)
490         ptide_harmo(jh)%omega = (  zomega_T * ptide_comp( jh )%nT   &
491            &                         + zomega_s * ptide_comp( jh )%ns   &
492            &                         + zomega_h * ptide_comp( jh )%nh   &
493            &                         + zomega_p * ptide_comp( jh )%np   &
494            &                         + zomega_p1* ptide_comp( jh )%np1  ) * zscale
495      END DO
496      !
497   END SUBROUTINE tide_pulse
498
499
500   SUBROUTINE tide_vuf( ptide_comp, ptide_harmo )
501      !!----------------------------------------------------------------------
502      !!                     ***  ROUTINE tide_vuf  ***
503      !!                     
504      !! ** Purpose : Compute nodal modulation corrections
505      !!
506      !! ** Outputs : vt: Phase of tidal potential relative to Greenwich (radians)
507      !!              ut: Phase correction u due to nodal motion (radians)
508      !!              ft: Nodal correction factor
509      !!----------------------------------------------------------------------
510      TYPE(tide),          DIMENSION(:), POINTER ::   ptide_comp   ! Array of selected tidal component parameters
511      TYPE(tide_harmonic), DIMENSION(:), POINTER ::   ptide_harmo  ! Oscillation parameters of selected tidal components
512      !
513      INTEGER ::   jh   ! dummy loop index
514      !!----------------------------------------------------------------------
515      !
516      DO jh = 1, size(ptide_harmo)
517         !  Phase of the tidal potential relative to the Greenwhich
518         !  meridian (e.g. the position of the fictuous celestial body). Units are radian:
519         ptide_harmo(jh)%v0 = sh_T * ptide_comp( jh )%nT    &
520            &                   + sh_s * ptide_comp( jh )%ns    &
521            &                   + sh_h * ptide_comp( jh )%nh    &
522            &                   + sh_p * ptide_comp( jh )%np    &
523            &                   + sh_p1* ptide_comp( jh )%np1   &
524            &                   +        ptide_comp( jh )%shift * rad
525         !
526         !  Phase correction u due to nodal motion. Units are radian:
527         ptide_harmo(jh)%u = sh_xi     * ptide_comp( jh )%nksi   &
528            &                  + sh_nu     * ptide_comp( jh )%nnu0   &
529            &                  + sh_nuprim * ptide_comp( jh )%nnu1   &
530            &                  + sh_nusec  * ptide_comp( jh )%nnu2   &
531            &                  + sh_R      * ptide_comp( jh )%R
532
533         !  Nodal correction factor:
534         ptide_harmo(jh)%f = nodal_factort( ptide_comp( jh )%nformula )
535      END DO
536      !
537   END SUBROUTINE tide_vuf
538
539
540   RECURSIVE FUNCTION nodal_factort( kformula ) RESULT( zf )
541      !!----------------------------------------------------------------------
542      !!----------------------------------------------------------------------
543      INTEGER, INTENT(in) :: kformula
544      !
545      REAL(wp) :: zf
546      REAL(wp) :: zs, zf1, zf2
547      !!----------------------------------------------------------------------
548      !
549      SELECT CASE( kformula )
550      !
551      CASE( 0 )                  !==  formule 0, solar waves
552         zf = 1.0
553         !
554      CASE( 1 )                  !==  formule 1, compound waves (78 x 78)
555         zf=nodal_factort(78)
556         zf = zf * zf
557         !
558      CASE ( 2 )                 !==  formule 2, compound waves (78 x 0)  ===  (78)
559       zf1= nodal_factort(78)
560       zf = nodal_factort( 0)
561       zf = zf1 * zf
562       !
563      CASE ( 4 )                 !==  formule 4,  compound waves (78 x 235)
564         zf1 = nodal_factort( 78)
565         zf  = nodal_factort(235)
566         zf  = zf1 * zf
567         !
568      CASE ( 5 )                 !==  formule 5,  compound waves (78 *78 x 235)
569         zf1 = nodal_factort( 78)
570         zf  = nodal_factort(235)
571         zf  = zf * zf1 * zf1
572         !
573      CASE ( 6 )                 !==  formule 6,  compound waves (78 *78 x 0)
574         zf1 = nodal_factort(78)
575         zf  = nodal_factort( 0)
576         zf  = zf * zf1 * zf1 
577         !
578      CASE( 7 )                  !==  formule 7, compound waves (75 x 75)
579         zf = nodal_factort(75)
580         zf = zf * zf
581         !
582      CASE( 8 )                  !==  formule 8,  compound waves (78 x 0 x 235)
583         zf  = nodal_factort( 78)
584         zf1 = nodal_factort(  0)
585         zf2 = nodal_factort(235)
586         zf  = zf * zf1 * zf2
587         !
588      CASE( 9 )                  !==  formule 9,  compound waves (78 x 0 x 227)
589         zf  = nodal_factort( 78)
590         zf1 = nodal_factort(  0)
591         zf2 = nodal_factort(227)
592         zf  = zf * zf1 * zf2
593         !
594      CASE( 10 )                 !==  formule 10,  compound waves (78 x 227)
595         zf  = nodal_factort( 78)
596         zf1 = nodal_factort(227)
597         zf  = zf * zf1
598         !
599      CASE( 11 )                 !==  formule 11,  compound waves (75 x 0)
600!!gm bug???? zf 2 fois !
601         zf = nodal_factort(75)
602         zf1 = nodal_factort( 0)
603         zf = zf * zf1
604         !
605      CASE( 12 )                 !==  formule 12,  compound waves (78 x 78 x 78 x 0)
606         zf1 = nodal_factort(78)
607         zf  = nodal_factort( 0)
608         zf  = zf * zf1 * zf1 * zf1
609         !
610      CASE( 13 )                 !==  formule 13, compound waves (78 x 75)
611         zf1 = nodal_factort(78)
612         zf  = nodal_factort(75)
613         zf  = zf * zf1
614         !
615      CASE( 14 )                 !==  formule 14, compound waves (235 x 0)  ===  (235)
616         zf  = nodal_factort(235)
617         zf1 = nodal_factort(  0)
618         zf  = zf * zf1
619         !
620      CASE( 15 )                 !==  formule 15, compound waves (235 x 75)
621         zf  = nodal_factort(235)
622         zf1 = nodal_factort( 75)
623         zf  = zf * zf1
624         !
625      CASE( 16 )                 !==  formule 16, compound waves (78 x 0 x 0)  ===  (78)
626         zf  = nodal_factort(78)
627         zf1 = nodal_factort( 0)
628         zf  = zf * zf1 * zf1
629         !
630      CASE( 17 )                 !==  formule 17,  compound waves (227 x 0)
631         zf1 = nodal_factort(227)
632         zf  = nodal_factort(  0)
633         zf  = zf * zf1
634         !
635      CASE( 18 )                 !==  formule 18,  compound waves (78 x 78 x 78 )
636         zf1 = nodal_factort(78)
637         zf  = zf1 * zf1 * zf1
638         !
639      CASE( 19 )                 !==  formule 19, compound waves (78 x 0 x 0 x 0)  ===  (78)
640!!gm bug2 ==>>>   here identical to formule 16,  a third multiplication by zf1 is missing
641         zf  = nodal_factort(78)
642         zf1 = nodal_factort( 0)
643         zf = zf * zf1 * zf1
644         !
645      CASE( 73 )                 !==  formule 73
646         zs = sin(sh_I)
647         zf = (2./3.-zs*zs)/0.5021
648         !
649      CASE( 74 )                 !==  formule 74
650         zs = sin(sh_I)
651         zf = zs * zs / 0.1578
652         !
653      CASE( 75 )                 !==  formule 75
654         zs = cos(sh_I/2)
655         zf = sin(sh_I) * zs * zs / 0.3800
656         !
657      CASE( 76 )                 !==  formule 76
658         zf = sin(2*sh_I) / 0.7214
659         !
660      CASE( 77 )                 !==  formule 77
661         zs = sin(sh_I/2)
662         zf = sin(sh_I) * zs * zs / 0.0164
663         !
664      CASE( 78 )                 !==  formule 78
665         zs = cos(sh_I/2)
666         zf = zs * zs * zs * zs / 0.9154
667         !
668      CASE( 79 )                 !==  formule 79
669         zs = sin(sh_I)
670         zf = zs * zs / 0.1565
671         !
672      CASE( 144 )                !==  formule 144
673         zs = sin(sh_I/2)
674         zf = ( 1-10*zs*zs+15*zs*zs*zs*zs ) * cos(sh_I/2) / 0.5873
675         !
676      CASE( 149 )                !==  formule 149
677         zs = cos(sh_I/2)
678         zf = zs*zs*zs*zs*zs*zs / 0.8758
679         !
680      CASE( 215 )                !==  formule 215
681         zs = cos(sh_I/2)
682         zf = zs*zs*zs*zs / 0.9154 * sh_x1ra
683         !
684      CASE( 227 )                !==  formule 227
685         zs = sin(2*sh_I)
686         zf = sqrt( 0.8965*zs*zs+0.6001*zs*cos (sh_nu)+0.1006 )
687         !
688      CASE ( 235 )               !==  formule 235
689         zs = sin(sh_I)
690         zf = sqrt( 19.0444*zs*zs*zs*zs + 2.7702*zs*zs*cos(2*sh_nu) + .0981 )
691         !
692      END SELECT
693      !
694   END FUNCTION nodal_factort
695
696
697   FUNCTION dayjul( kyr, kmonth, kday )
698      !!----------------------------------------------------------------------
699      !!  *** THIS ROUTINE COMPUTES THE JULIAN DAY (AS A REAL VARIABLE)
700      !!----------------------------------------------------------------------
701      INTEGER,INTENT(in) ::   kyr, kmonth, kday
702      !
703      INTEGER,DIMENSION(12) ::  idayt, idays
704      INTEGER  ::   inc, ji
705      REAL(wp) ::   dayjul, zyq
706      !
707      DATA idayt/0.,31.,59.,90.,120.,151.,181.,212.,243.,273.,304.,334./
708      !!----------------------------------------------------------------------
709      !
710      idays(1) = 0.
711      idays(2) = 31.
712      inc = 0.
713      zyq = MOD( kyr-1900. , 4. )
714      IF( zyq == 0.)   inc = 1.
715      DO ji = 3, 12
716         idays(ji)=idayt(ji)+inc
717      END DO
718      dayjul = idays(kmonth) + kday
719      !
720   END FUNCTION dayjul
721
722
723   SUBROUTINE upd_tide(pdelta)
724      !!----------------------------------------------------------------------
725      !!                 ***  ROUTINE upd_tide  ***
726      !!
727      !! ** Purpose :   provide at each time step the astronomical potential
728      !!
729      !! ** Method  :   computed from pulsation and amplitude of all tide components
730      !!
731      !! ** Action  :   pot_astro   actronomical potential
732      !!----------------------------------------------------------------------     
733      REAL, INTENT(in)              ::   pdelta      ! Temporal offset in seconds
734      INTEGER                       ::   jk          ! Dummy loop index
735      REAL(wp)                      ::   zt, zramp   ! Local scalars
736      REAL(wp), DIMENSION(nb_harmo) ::   zwt         ! Temporary array
737      !!----------------------------------------------------------------------     
738      !
739      zwt(:) = tide_harmonics(:)%omega * pdelta
740      !
741      pot_astro(:,:) = 0._wp          ! update tidal potential (sum of all harmonics)
742      DO jk = 1, nb_harmo   
743         pot_astro(:,:) = pot_astro(:,:) + amp_pot(:,:,jk) * COS( zwt(jk) + phi_pot(:,:,jk) )     
744      END DO
745      !
746      IF( ln_tide_ramp ) THEN         ! linear increase if asked
747         zt = rn_tide_ramp_t + pdelta
748         zramp = MIN(  MAX( zt / (rn_tide_ramp_dt*rday) , 0._wp ) , 1._wp  )
749         pot_astro(:,:) = zramp * pot_astro(:,:)
750      ENDIF
751      !
752   END SUBROUTINE upd_tide
753
754   !!======================================================================
755END MODULE tide_mod
Note: See TracBrowser for help on using the repository browser.