New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago

ORCA2_LIM_PISCES hybrid version update
  • Property svn:keywords set to Id
File size: 14.7 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   !
21   USE in_out_manager ! I/O manager
22   USE prtctl         ! Print control
23   USE iom            ! IOM library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   sbc_ssm        ! routine called by step.F90
29   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
30
31   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
32   
33   !!----------------------------------------------------------------------
34   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
35   !! $Id$
36   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE sbc_ssm( kt )
41      !!---------------------------------------------------------------------
42      !!                     ***  ROUTINE sbc_oce  ***
43      !!                     
44      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
45      !!                condition computation
46      !!               
47      !! ** Method  :   compute mean surface velocity (2 components at U and
48      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
49      !!      the periode (kt - nn_fsbc) to kt
50      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
51      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
52      !!---------------------------------------------------------------------
53      INTEGER, INTENT(in) ::   kt   ! ocean time step
54      !
55      INTEGER  ::   ji, jj               ! loop index
56      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
57      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
58      !!---------------------------------------------------------------------
59      !
60      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
61!$OMP PARALLEL DO schedule(static) private(jj, ji)
62      DO jj = 1, jpj
63         DO ji = 1, jpi
64            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
65            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
66         END DO
67      END DO
68      !
69      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
70         !                                                ! ---------------------------------------- !
71!$OMP PARALLEL WORKSHARE
72         ssu_m(:,:) = ub(:,:,1)
73         ssv_m(:,:) = vb(:,:,1)
74!$OMP END PARALLEL WORKSHARE
75         IF( l_useCT )  THEN
76!$OMP PARALLEL WORKSHARE
77           sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
78!$OMP END PARALLEL WORKSHARE
79         ELSE                   
80!$OMP PARALLEL WORKSHARE
81           sst_m(:,:) = zts(:,:,jp_tem)
82!$OMP END PARALLEL WORKSHARE
83         ENDIF
84!$OMP PARALLEL WORKSHARE
85         sss_m(:,:) = zts(:,:,jp_sal)
86!$OMP END PARALLEL WORKSHARE
87         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
88         IF( ln_apr_dyn ) THEN 
89!$OMP PARALLEL WORKSHARE
90           ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
91!$OMP END PARALLEL WORKSHARE
92         ELSE                   
93!$OMP PARALLEL WORKSHARE
94           ssh_m(:,:) = sshn(:,:)
95!$OMP END PARALLEL WORKSHARE
96         ENDIF
97         !
98!$OMP PARALLEL WORKSHARE
99         e3t_m(:,:) = e3t_n(:,:,1)
100         !
101         frq_m(:,:) = fraqsr_1lev(:,:)
102!$OMP END PARALLEL WORKSHARE
103         !
104      ELSE
105         !                                                ! ----------------------------------------------- !
106         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
107            !                                             ! ----------------------------------------------- !
108            IF(lwp) WRITE(numout,*)
109            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
110            zcoef = REAL( nn_fsbc - 1, wp )
111!$OMP PARALLEL WORKSHARE
112            ssu_m(:,:) = zcoef * ub(:,:,1)
113            ssv_m(:,:) = zcoef * vb(:,:,1)
114!$OMP END PARALLEL WORKSHARE
115            IF( l_useCT )  THEN
116!$OMP PARALLEL WORKSHARE
117              sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
118!$OMP END PARALLEL WORKSHARE
119            ELSE                   
120!$OMP PARALLEL WORKSHARE
121              sst_m(:,:) = zcoef * zts(:,:,jp_tem)
122!$OMP END PARALLEL WORKSHARE
123            ENDIF
124!$OMP PARALLEL WORKSHARE
125            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
126!$OMP END PARALLEL WORKSHARE
127            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
128            IF( ln_apr_dyn ) THEN   
129!$OMP PARALLEL WORKSHARE
130              ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
131!$OMP END PARALLEL WORKSHARE
132            ELSE                   
133!$OMP PARALLEL WORKSHARE
134              ssh_m(:,:) = zcoef * sshn(:,:)
135!$OMP END PARALLEL WORKSHARE
136            ENDIF
137            !
138!$OMP PARALLEL WORKSHARE
139            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
140            !
141            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
142!$OMP END PARALLEL WORKSHARE
143            !                                             ! ---------------------------------------- !
144         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
145            !                                             ! ---------------------------------------- !
146!$OMP PARALLEL WORKSHARE
147            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
148            ssv_m(:,:) = 0._wp
149            sst_m(:,:) = 0._wp
150            sss_m(:,:) = 0._wp
151            ssh_m(:,:) = 0._wp
152            e3t_m(:,:) = 0._wp
153            frq_m(:,:) = 0._wp
154!$OMP END PARALLEL WORKSHARE
155         ENDIF
156         !                                                ! ---------------------------------------- !
157         !                                                !        Cumulate at each time step        !
158         !                                                ! ---------------------------------------- !
159!$OMP PARALLEL WORKSHARE
160         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
161         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
162!$OMP END PARALLEL WORKSHARE
163         IF( l_useCT )  THEN   
164!$OMP PARALLEL WORKSHARE
165           sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
166!$OMP END PARALLEL WORKSHARE
167         ELSE                   
168!$OMP PARALLEL WORKSHARE
169           sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
170!$OMP END PARALLEL WORKSHARE
171         ENDIF
172!$OMP PARALLEL WORKSHARE
173         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
174!$OMP END PARALLEL WORKSHARE
175         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
176         IF( ln_apr_dyn ) THEN   
177!$OMP PARALLEL WORKSHARE
178           ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
179!$OMP END PARALLEL WORKSHARE
180         ELSE                   
181!$OMP PARALLEL WORKSHARE
182           ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
183!$OMP END PARALLEL WORKSHARE
184         ENDIF
185         !
186!$OMP PARALLEL WORKSHARE
187         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
188         !
189         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
190!$OMP END PARALLEL WORKSHARE
191
192         !                                                ! ---------------------------------------- !
193         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
194            !                                             ! ---------------------------------------- !
195            zcoef = 1. / REAL( nn_fsbc, wp )
196!$OMP PARALLEL WORKSHARE
197            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celcius]
198            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
199            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
200            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
201            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
202            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
203            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
204!$OMP END PARALLEL WORKSHARE
205            !
206         ENDIF
207         !                                                ! ---------------------------------------- !
208         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
209            !                                             ! ---------------------------------------- !
210            IF(lwp) WRITE(numout,*)
211            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
212               &                    'at it= ', kt,' date= ', ndastp
213            IF(lwp) WRITE(numout,*) '~~~~~~~'
214            zf_sbc = REAL( nn_fsbc, wp )
215            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
216            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
217            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
218            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
219            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
220            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
221            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m  )
222            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m  )
223            !
224         ENDIF
225         !
226      ENDIF
227      !
228      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
229         CALL iom_put( 'ssu_m', ssu_m )
230         CALL iom_put( 'ssv_m', ssv_m )
231         CALL iom_put( 'sst_m', sst_m )
232         CALL iom_put( 'sss_m', sss_m )
233         CALL iom_put( 'ssh_m', ssh_m )
234         CALL iom_put( 'e3t_m', e3t_m )
235         CALL iom_put( 'frq_m', frq_m )
236      ENDIF
237      !
238   END SUBROUTINE sbc_ssm
239
240
241   SUBROUTINE sbc_ssm_init
242      !!----------------------------------------------------------------------
243      !!                  ***  ROUTINE sbc_ssm_init  ***
244      !!
245      !! ** Purpose :   Initialisation of the sbc data
246      !!
247      !! ** Action  : - read parameters
248      !!----------------------------------------------------------------------
249      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
250      !!----------------------------------------------------------------------
251      !
252      IF( nn_fsbc == 1 ) THEN
253         !
254         IF(lwp) WRITE(numout,*)
255         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
256         IF(lwp) WRITE(numout,*) '~~~~~~~ '
257         !
258      ELSE
259         !               
260         IF(lwp) WRITE(numout,*)
261         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
262         IF(lwp) WRITE(numout,*) '~~~~~~~ '
263         !
264         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
265            l_ssm_mean = .TRUE.
266            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )    ! sbc frequency of previous run
267            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )    ! sea surface mean velocity    (U-point)
268            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )    !   "         "    velocity    (V-point)
269            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )    !   "         "    temperature (T-point)
270            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )    !   "         "    salinity    (T-point)
271            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )    !   "         "    height      (T-point)
272            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m  )    ! 1st level thickness          (T-point)
273            ! fraction of solar net radiation absorbed in 1st T level
274            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
275               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m  )
276            ELSE
277!$OMP PARALLEL WORKSHARE
278               frq_m(:,:) = 1._wp   ! default definition
279!$OMP END PARALLEL WORKSHARE
280            ENDIF
281            !
282            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
283               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
284                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
285               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
286!$OMP PARALLEL WORKSHARE
287               ssu_m(:,:) = zcoef * ssu_m(:,:) 
288               ssv_m(:,:) = zcoef * ssv_m(:,:)
289               sst_m(:,:) = zcoef * sst_m(:,:)
290               sss_m(:,:) = zcoef * sss_m(:,:)
291               ssh_m(:,:) = zcoef * ssh_m(:,:)
292               e3t_m(:,:) = zcoef * e3t_m(:,:)
293               frq_m(:,:) = zcoef * frq_m(:,:)
294!$OMP END PARALLEL WORKSHARE
295            ELSE
296               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
297            ENDIF
298         ENDIF
299      ENDIF
300      !
301      IF( .NOT. l_ssm_mean ) THEN   ! default initialisation. needed by lim_istate
302         !
303         IF(lwp) WRITE(numout,*) '          default initialisation of ss?_m arrays'
304!$OMP PARALLEL WORKSHARE
305         ssu_m(:,:) = ub(:,:,1)
306         ssv_m(:,:) = vb(:,:,1)
307!$OMP END PARALLEL WORKSHARE
308         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
309         ELSE                    ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
310         ENDIF
311!$OMP PARALLEL WORKSHARE
312         sss_m(:,:) = tsn  (:,:,1,jp_sal)
313         ssh_m(:,:) = sshn (:,:)
314         e3t_m(:,:) = e3t_n(:,:,1)
315         frq_m(:,:) = 1._wp
316!$OMP END PARALLEL WORKSHARE
317         !
318      ENDIF
319      !
320   END SUBROUTINE sbc_ssm_init
321
322   !!======================================================================
323END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.