ORCA2 tracer damping hand edits in dtatsd.F90 can be cumulatively applied

[hadcv]

Issue

When running ORCA2 with tracer damping and without temporal interpolation, i.e.

[namelist:namtra_dmp]
ln_tradmp=.true.

[namelist:namtsd]
sn_tem='data_1m_potential_temperature_nomask',-1.0,'votemper',.false.,.true.,'yearly','','',''

the model tends to blow up with near-freezing temperatures in the Alboran Sea.

Cause

The following ORCA2 hand edits in ​dtatsd.F90 seem to be applied on each timestep:

148         !
149         !!gm  This should be removed from the code   ===>>>>  T & S files has to be changed
150         !
151         !                                   !==   ORCA_R2 configuration and T & S damping   ==!
152         IF( cn_cfg == "orca" .OR. cn_cfg == "ORCA" ) THEN
153            IF( nn_cfg == 2 .AND. ln_tsd_dmp ) THEN    ! some hand made alterations
154               !
155               ij0 = 101 + nn_hls       ;   ij1 = 109 + nn_hls                       ! Reduced T & S in the Alboran Sea
156               ii0 = 141 + nn_hls - 1   ;   ii1 = 155 + nn_hls - 1
157               DO jj = mj0(ij0), mj1(ij1)
158                  DO ji = mi0(ii0), mi1(ii1)
159                     sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
160                     sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
161                     sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
162                     !
163                     sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
164                     sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
165                     sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
166                     sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
167                  END DO
168               END DO
169               ij0 =  87 + nn_hls       ;   ij1 =  96 + nn_hls                       ! Reduced temperature in Red Sea
170               ii0 = 148 + nn_hls - 1   ;   ii1 = 160 + nn_hls - 1
171               sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
172               sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
173               sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
174            ENDIF
175         ENDIF
176         !!gm end

I gather that this is because sf_tsd(jp_tem)%fnow is only updated once per record when temporal interpolation is not used.

Solution

Check to see if the record number has changed (implying new data has been read in):

(a) before vs. (b) after

@@ -1 +1 @@
         IF( cn_cfg == "orca" .OR. cn_cfg == "ORCA" ) THEN
            IF( nn_cfg == 2 .AND. ln_tsd_dmp ) THEN    ! some hand made alterations
+              irec_n(jp_tem) = sf_tsd(jp_tem)%nrec(2,sf_tsd(jp_tem)%naa)            ! Determine if there is new data (ln_tint = F)
+              irec_n(jp_sal) = sf_tsd(jp_sal)%nrec(2,sf_tsd(jp_sal)%naa)            ! If not, then do not apply the increments
+              IF( kt == nit000 ) irec_b(:) = -1
               !
               ij0 = 101 + nn_hls       ;   ij1 = 109 + nn_hls                       ! Reduced T & S in the Alboran Sea
               ii0 = 141 + nn_hls - 1   ;   ii1 = 155 + nn_hls - 1
               DO jj = mj0(ij0), mj1(ij1)
                  DO ji = mi0(ii0), mi1(ii1)
+                    IF( sf_tsd(jp_tem)%ln_tint .OR. irec_n(jp_tem) /= irec_b(jp_tem) ) THEN
                        sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
                        sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
                        sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
+                       irec_b(jp_tem) = irec_n(jp_tem)
+                    ENDIF
                     !
+                    IF( sf_tsd(jp_sal)%ln_tint .OR. irec_n(jp_sal) /= irec_b(jp_sal) ) THEN
                        sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
                        sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
                        sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
                        sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
+                       irec_b(jp_sal) = irec_n(jp_sal)
+                    ENDIF
                  END DO
               END DO
               ij0 =  87 + nn_hls       ;   ij1 =  96 + nn_hls                       ! Reduced temperature in Red Sea
               ii0 = 148 + nn_hls - 1   ;   ii1 = 160 + nn_hls - 1
               sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
               sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
               sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
            ENDIF

[hadcv]

In 14185:

Error: Failed to load processor CommitTicketReference

No macro or processor named 'CommitTicketReference' found

[hadcv]

In 14186:

Error: Failed to load processor CommitTicketReference

No macro or processor named 'CommitTicketReference' found